error message with servo and folder

Hi,
i try to use the folder for my program and for learning i try with a simple program but i have an error message
myservo was not declared in this scope.
i have tested to put servo.h and the variable myservo in the different folder and i have always the same message
for the other variable the programm is correct.
if i put myservo and servo .h and the void rotServo() in the servo_base and remove rotation.cpp and .h the program is ok
thank for your help
see below the program

servo_base

[code]
// progamme servo
#include "variable.h"
#include "rotation.h"

void setup() {
  Serial.begin(9600);                       
  while(!Serial){;} 
  myservo.attach(pin_servo);  // attache le servo au pin spécifié sur l'objet myservo
  
}

void loop() {
  rotServo();
}

[/code]

rotation.cpp

[code]

#include<arduino.h>
#include"variable.h"
#include"rotation.h"

#include <Servo.h>
Servo myservo;  // création de l'objet myservo 

void rotServo(){
   for (pos = angle_initial; pos <= angle_final; pos += increment) { // Déplace le servo de 0 à 180 degréespar pas de 1 degrée 
    myservo.write(pos);              // Demande au servo de se déplacer à cette position angulaire
    delay(30);                       // Attend 30ms entre chaque changement de position
    if (angle_actuel) {
        Serial.println(myservo.read());
    }
  }
  for (pos = angle_final; pos >= angle_initial; pos -= increment) { // Fait le chemin inverse
    myservo.write(pos);              
    delay(30);   
    if (angle_actuel) {
        Serial.println(myservo.read());
    }
  }
 
}

[/code]

rotation.h

[code]

#ifndef ROTATION_H
#define ROTATION_H



void rotServo();

#endif

[/code]

variable.cpp

[code]
#include <arduino.h>
#include"variable.h"

int pin_servo = 3;       // Pin 3 sur lequel est branché le servo sur l'Arduino 
int pos = 0;             // variable permettant de conserver la position du servo
int angle_initial = 0;   //angle initial
int angle_final = 180;   //angle final
int increment = 5;       //incrément entre chaque position
bool angle_actuel = false;//Envoi sur le port série la position courante du servomoteur

[/code]

variable.h

[code]
#ifndef VARIABLE_H
#define VARIABLE_H


extern int pin_servo;       // Pin 3 sur lequel est branché le servo sur l'Arduino 

extern int pos;             // variable permettant de conserver la position du servo
extern int angle_initial;   //angle initial
extern int angle_final;     //angle final
extern int increment;       //incrément entre chaque position
extern bool angle_actuel;   //Envoi sur le port série la position courante du servomoteur

#endif

[/code]

You should declare myservo as extern in rotation.h so that it’s known in the main sketch

#ifndef ROTATION_H
#define ROTATION_H
#include <Servo.h>
extern Servo myservo;  // déclaration de l'objet myservo 
void rotServo();
#endif

(typed here on my mobile so mind typos)

I’m not sure there is a lot of value in creating all those extra files…

Thanks J-L-M
this programm is just for understanding the process, in my final program i will manage 8 Servos and some butons and SD cards.It was more simples for the explantion to simplify my code .