Error on compile when trying to use a new library

Hi everyone!

After a few years without coding Arduino I want to control a servo motor using a bluetooth PS3 controller, but, I'm facing an issue after I install the library PS3BT.h and try to compile an example.

~> Error on screenshot attached, due to the limit of characters on the post, I'll reply with the full error message.

EDIT: What's the best way to post the error message here? I'm still getting the 9000 characters limit when trying to paste it here.
EDIT 2: Full error message here and on file attached: Error message - Google Docs

Follows the code:

/*
 Example sketch for the PS3 Bluetooth library - developed by Kristian Lauszus
 For more information visit my blog: http://blog.tkjelectronics.dk/ or 
 send me an e-mail:  kristianl@tkjelectronics.com
 */

#include <PS3BT.h>
USB Usb;
BTD Btd(&Usb); // You have to create the Bluetooth Dongle instance like so
/* You can create the instance of the class in two ways */
PS3BT PS3(&Btd); // This will just create the instance
//PS3BT PS3(&Btd,0x00,0x15,0x83,0x3D,0x0A,0x57); // This will also store the bluetooth address - this can be obtained from the dongle when running the sketch

boolean printTemperature;
boolean printAngle;

void setup() {
  Serial.begin(115200);
  if (Usb.Init() == -1) {
    Serial.print(F("\r\nOSC did not start"));
    while(1); //halt
  }
  Serial.print(F("\r\nPS3 Bluetooth Library Started"));
}
void loop() {
  Usb.Task();

  if(PS3.PS3Connected || PS3.PS3NavigationConnected) {
    if(PS3.getAnalogHat(LeftHatX) > 137 || PS3.getAnalogHat(LeftHatX) < 117 || PS3.getAnalogHat(LeftHatY) > 137 || PS3.getAnalogHat(LeftHatY) < 117 || PS3.getAnalogHat(RightHatX) > 137 || PS3.getAnalogHat(RightHatX) < 117 || PS3.getAnalogHat(RightHatY) > 137 || PS3.getAnalogHat(RightHatY) < 117) {
      Serial.print(F("\r\nLeftHatX: ")); 
      Serial.print(PS3.getAnalogHat(LeftHatX));
      Serial.print(F("\tLeftHatY: ")); 
      Serial.print(PS3.getAnalogHat(LeftHatY));
      Serial.print(F("\tRightHatX: ")); 
      Serial.print(PS3.getAnalogHat(RightHatX));
      Serial.print(F("\tRightHatY: ")); 
      Serial.print(PS3.getAnalogHat(RightHatY));
    }

    //Analog button values can be read from almost all buttons
    if(PS3.getAnalogButton(L2_ANALOG) > 0 || PS3.getAnalogButton(R2_ANALOG) > 0) {
      Serial.print(F("\r\nL2: ")); 
      Serial.print(PS3.getAnalogButton(L2_ANALOG));
      Serial.print(F("\tR2: ")); 
      Serial.print(PS3.getAnalogButton(R2_ANALOG));
    }
    if(PS3.getButtonClick(PS)) {
      Serial.print(F("\r\nPS"));
      PS3.disconnect();
    } 
    else {
      if(PS3.getButtonClick(TRIANGLE))
        Serial.print(F("\r\nTraingle"));
      if(PS3.getButtonClick(CIRCLE))
        Serial.print(F("\r\nCircle"));
      if(PS3.getButtonClick(CROSS))
        Serial.print(F("\r\nCross"));
      if(PS3.getButtonClick(SQUARE))
        Serial.print(F("\r\nSquare"));

      if(PS3.getButtonClick(UP)) {
        Serial.print(F("\r\nUp"));          
        if(PS3.PS3Connected) {
          PS3.setAllOff();
          PS3.setLedOn(LED4);
        }
      } 
      if(PS3.getButtonClick(RIGHT)) {
        Serial.print(F("\r\nRight"));
        if(PS3.PS3Connected) {
          PS3.setAllOff();
          PS3.setLedOn(LED1); 
        }         
      } 
      if(PS3.getButtonClick(DOWN)) {
        Serial.print(F("\r\nDown"));
        if(PS3.PS3Connected) {
          PS3.setAllOff();
          PS3.setLedOn(LED2);          
        }
      } 
      if(PS3.getButtonClick(LEFT)) {          
        Serial.print(F("\r\nLeft"));          
        if(PS3.PS3Connected) {
          PS3.setAllOff();         
          PS3.setLedOn(LED3);            
        }         
      } 

      if(PS3.getButtonClick(L1))
        Serial.print(F("\r\nL1"));  
      if(PS3.getButtonClick(L3))
        Serial.print(F("\r\nL3")); 
      if(PS3.getButtonClick(R1))
        Serial.print(F("\r\nR1"));             
      if(PS3.getButtonClick(R3))
        Serial.print(F("\r\nR3"));

      if(PS3.getButtonClick(SELECT)) {
        Serial.print(F("\r\nSelect - ")); 
        Serial.print(PS3.getStatusString());        
      } 
      if(PS3.getButtonClick(START)) {
        Serial.print(F("\r\nStart"));              
        printAngle = !printAngle;
      }                           
    }
    if(printAngle) {
      Serial.print(F("\r\nPitch: "));               
      Serial.print(PS3.getAngle(Pitch));                  
      Serial.print(F("\tRoll: ")); 
      Serial.print(PS3.getAngle(Roll));
    }
  }
  else if(PS3.PS3MoveConnected) {
    if(PS3.getAnalogButton(T_ANALOG) > 0) {
      Serial.print(F("\r\nT: ")); 
      Serial.print(PS3.getAnalogButton(T_ANALOG)); 
    } 
    if(PS3.getButtonClick(PS)) {
      Serial.print(F("\r\nPS"));
      PS3.disconnect();
    } 
    else {
      if(PS3.getButtonClick(SELECT)) {
        Serial.print(F("\r\nSelect"));
        printTemperature = !printTemperature;
      } 
      if(PS3.getButtonClick(START)) {
        Serial.print(F("\r\nStart"));
        printAngle = !printAngle;                          
      } 
      if(PS3.getButtonClick(TRIANGLE)) {            
        Serial.print(F("\r\nTriangle"));
        PS3.moveSetBulb(Red);
      } 
      if(PS3.getButtonClick(CIRCLE)) {
        Serial.print(F("\r\nCircle"));
        PS3.moveSetBulb(Green);
      } 
      if(PS3.getButtonClick(SQUARE)) {
        Serial.print(F("\r\nSquare"));
        PS3.moveSetBulb(Blue);
      } 
      if(PS3.getButtonClick(CROSS)) {
        Serial.print(F("\r\nCross"));
        PS3.moveSetBulb(Yellow);
      } 
      if(PS3.getButtonClick(MOVE)) {     
        PS3.moveSetBulb(Off);                        
        Serial.print(F("\r\nMove"));
        Serial.print(F(" - ")); 
        Serial.print(PS3.getStatusString());
      }
    }
    if(printAngle) {
      Serial.print(F("\r\nPitch: "));               
      Serial.print(PS3.getAngle(Pitch));                  
      Serial.print(F("\tRoll: ")); 
      Serial.print(PS3.getAngle(Roll));
    }
    else if(printTemperature) {
      Serial.print(F("\r\nTemperature: "));
      Serial.print(PS3.getTemperature());
    }
  }
}

Thanks!

Error message.txt (18.9 KB)

All that I see on the screenshot are warnings. Warnings will not prevent compilation. Please include the entire error message. It is easy to do. There is a button (lower right of the IDE window) called "copy error message". Copy the error and paste into a post in code tags. If it is too large to paste into a post, save it to a .txt file and attach the file.

What Arduino board are you using?

groundFungus:
All that I see on the screenshot are warnings. Warnings will not prevent compilation. Please include the entire error message. It is easy to do. There is a button (lower right of the IDE window) called "copy error message". Copy the error and paste into a post in code tags. If it is too large to paste into a post, save it to a .txt file and attach the file.

What Arduino board are you using?

Thanks for the fast response! Just uploaded the full error message on a txt and drive file! And it's an Arduino Uno

Where did you get the USB_Host_Shield library. It looks like you have an older version. I suggest that you delete the library from your sketchbook\library folder and reinstall the library. Be sure to use the library manager to install the library. That will ensure that you have the latest version. In library manager, enter "usb_host_shield" in the search box.

The version that you have (older version?):

const char *ReportDescParserBase::usagePageTitles1[] PROGMEM =

The same line in the newer version:

const char * const ReportDescParserBase::usagePageTitles1[] PROGMEM = {

|
Note the extra const /.

See this forum post that I found with a search for "must be const in order to be put into read-only section by means of 'attribute((progmem))'"

groundFungus:
Where did you get the USB_Host_Shield library. It looks like you have an older version. I suggest that you delete the library from your sketchbook\library folder and reinstall the library. Be sure to use the library manager to install the library. That will ensure that you have the latest version. In library manager, enter "usb_host_shield" in the search box.

The version that you have (older version?):

const char *ReportDescParserBase::usagePageTitles1[] PROGMEM =

The same line in the newer version:

const char * const ReportDescParserBase::usagePageTitles1[] PROGMEM = {

|
Note the extra const /.

Thank you very much for your help @groundFungus ! Before you replied I've already downgraded my Arduino IDE to the version 1.0.6 and solved the problem!
Is there any disadvantage if I keep on using the one old library I have with the 1.0.6 Arduino IDE just for this project?
Thanks!