ESP: IP einer Web Seite rausfinden?

[spunky1a]

Hallo,

wie kann man die IP Adresse einer Web Seite rausfinden?

www.google.de -> 123.45.67.89

MfG.

[Rentner]

Hallo,
wenn Du verbunden bist ginge das mit

Serial.println(client.remoteIP());

oder wie meinst DU das

[noiasca]

eher ein DNS lookup mit

hostByName

@spunky1a für welchen ESP genau?

edit:
das funktioniert am ESP32:

/*
   Resolve the IP by server hostname
   localy (MDNS) and external 
   Sketch for ESP32
   by noiasca
   
*/

#include <WiFi.h>
#include <ESPmDNS.h>
#include <WiFiClient.h>

//#include "credentials.h"
const char* ssid = STASSID;
const char* password = STAPSK;

void searchMDNS() {
  const char * serverHostname = "esp113Wasser";     //only use host name and remove .local
  IPAddress serverIp = MDNS.queryHost(serverHostname);
  Serial.print("IP address of server: ");
  Serial.println(serverIp.toString());
}

void searchWWW() {
  const char * serverHostname = "www.google.de";
  IPAddress serverIp;
  WiFi.hostByName(serverHostname, serverIp);
  Serial.print("IP address of server: ");
  Serial.println(serverIp.toString());
}

void setup() {
  Serial.begin(115200);
  delay(200);
  // Connect to WiFi network
  WiFi.begin(ssid, password);
  Serial.println("");

  // Wait for connection
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  if (!MDNS.begin("esp32"))
    Serial.println("Error setting up MDNS responder!");
  else
    Serial.println("mDNS responder started");
  searchMDNS();
  searchWWW();
}

void loop() {
}