Ethernet Shield 2 with poe su Arduino UNO si blocca sull'inizializzazione!

Salve,
ho appena acquistato un arduino UNO e una ethernet shield 2 with poe. Li ho uniti ed ho provato lo sketch https://www.arduino.cc/en/Tutorial/WebServer
Ho provato a settare anche il piedino 4 ad HIGH… ma il programma si blocca alla funzione server.begin()!
ecco il codice:

/*
  Web Server

 A simple web server that shows the value of the analog input pins.
 using an Arduino Wiznet Ethernet shield.

 Circuit:
 * Ethernet shield attached to pins 10, 11, 12, 13
 * Analog inputs attached to pins A0 through A5 (optional)

 created 18 Dec 2009
 by David A. Mellis
 modified 9 Apr 2012
 by Tom Igoe
 modified 02 Sept 2015
 by Arturo Guadalupi

 */

#include <SPI.h>
#include <Ethernet.h>

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = {
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED
};
IPAddress ip(192, 168, 1, 177);

// Initialize the Ethernet server library
// with the IP address and port you want to use
// (port 80 is default for HTTP):
EthernetServer server(80);

void setup() {
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }
   Serial.println("E' stato avviato monitor seriale!");

Serial.print("Setto il pin 4 ad HIGH...");
  pinMode(4, OUTPUT);
digitalWrite(4, HIGH);
Serial.println("...fatto.");
  // start the Ethernet connection and the server:
  Serial.println("Start di Ethernet.begin...");
  Ethernet.begin(mac, ip);
  
  Serial.println("eseguo server.begin...");
  server.begin();
  Serial.print("server is at ");
  Serial.println(Ethernet.localIP());
}


void loop() {
  // listen for incoming clients
  EthernetClient client = server.available();
  if (client) {
    Serial.println("new client");
    // an http request ends with a blank line
    boolean currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        Serial.write(c);
        // if you've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so you can send a reply
        if (c == '\n' && currentLineIsBlank) {
          // send a standard http response header
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connection: close");  // the connection will be closed after completion of the response
          client.println("Refresh: 5");  // refresh the page automatically every 5 sec
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
          // output the value of each analog input pin
          for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
            int sensorReading = analogRead(analogChannel);
            client.print("analog input ");
            client.print(analogChannel);
            client.print(" is ");
            client.print(sensorReading);
            client.println("
");
          }
          client.println("</html>");
          break;
        }
        if (c == '\n') {
          // you're starting a new line
          currentLineIsBlank = true;
        } else if (c != '\r') {
          // you've gotten a character on the current line
          currentLineIsBlank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(1);
    // close the connection:
    client.stop();
    Serial.println("client disconnected");
  }
}

e questo è l’output del monitor seriale:

E' stato avviato monitor seriale!
Setto il pin 4 ad HIGH......fatto.
Start di Ethernet.begin...
eseguo server.begin...

Si blocca e non va più avanti! cosa può essere? Le due schede le ho comprate per originali… forse sbaglio qualcosa?
grazie e saluti.

… semplicemente perché la Ethernet Shield 2 … vuole un altra librerie e non la Ethernet.h !

Devi correggere, dovunque appare la riga #include <Ethernet.h> con la riga #include <Ethernet2.h>

Guglielmo

Infatti.... nel frattempo mi era venuto il dubbio e...... voilet! sostituendo la libreria tutto ha cominciato a funzionare! grazie mille!