Frage zu WS2812b

Frohe Weihnachten und schöne Festtage, wünsche ich allen hier im Forum.

Ich habe eine Frage zu einem Befehl zur steuerung der WS2812b Stribs. Wenn ich den Befehl FastLED.delay(1000 / FRAMES_PER_SECOND); benutze, bremse ich dann den gesammten Controller aus oder bezieht sich der Befahl nur auf die Controller in den LED`s

oder bezieht sich der Befahl nur auf die Controller in den LED`s

Kenne den Befehl nicht, aber eins weiß ich: Die WS2812B Controller bekommen (und wollen auch) nur die PWM Werte. Auf die Controller hat der Befehl also keinen direkten Einfluss.

Ich kenne die aufgezeigte Funktion nicht. Der Controller des WS2812 kennt keine Einstellung für die PWM Frequenz mit denen die LED angesteuert werden. Die Frequenz ist fix und ca 400Hz.

Grüße Uwe

Das ist ein "teilweise" blockierendes Delay. Bedeutet konkret, das Dithering laeuft weiter, wenn angeschaltet.

Gedacht war diese Konstruktion urspruenglich dafuer, bei den WS2812B unter 400 fps zu bleiben, was man mit wenigen LEDs schnell mal ueberschreitet und dann nichts mehr sieht, weil sie das nicht moegen.

Aber der MC wird trotzdem blockiert, waehrend das Delay laeuft. Mit den LED Controllern hat das nichts zu tun.

Und es ist nicht so aufwendig, auf Delays komplett zu verzichten, dann hat man diese Sorgen nicht mehr.

Gruss,

Helmuth

p.s. Falls man etwas periodisch timen moechte, bieten sich auch die Funktionen EVERY_N_MILLIS(ms) und EVERY_N_SECONDS(s) an.

Danke HelmutH, ich habe das Problem bemerkt, da ich mir so einen Bioethernol Kamin umgebaut habe und diesen als Aussen Kamin mit den WS2812b Strip betreibe, was mir auch super gefällt. Ich habe dann eine Software Uhr in den Sketch mit eingebaut die sich über char time[]=TIME; beim Upload die Uhrzeit holt und weiter verarbeitet im Sketch. Da ich möchte das der Kamin Nachmittags um 18 Uhr an geht und Natchts um 2 Uhr aus geht ohne jedesmal den Stecker zu ziehen. Das klappt bei meinen anderen Uhren die ich gebaut habe auch super und die Uhrzeit geht nicht verlohren. Jedoch habe ich festgestellt , das sich bei dm Kamin , was ich annehme die Uhrzeit dir die Verzögerung verstellt, Darum die Frage. Aber dann werde ich nach den Feiertagen den Sketch wohl umschreiben um die verschiebung der Zeit zu verhindern.

http://www.vidup.de/v/AN7yJ/

Ach ja , Als Nachtrag der Sketch:

#include <FastLED.h>

#define LED_PIN     A5
#define COLOR_ORDER GRB
#define CHIPSET     WS2811
#define NUM_LEDS    30

#define BRIGHTNESS  200
#define FRAMES_PER_SECOND 60

CRGB leds[NUM_LEDS];

void setup() {
  delay(3000); // sanity delay
  FastLED.addLeds<CHIPSET, LED_PIN, COLOR_ORDER>(leds, NUM_LEDS).setCorrection( TypicalLEDStrip );
  FastLED.setBrightness( BRIGHTNESS );
}

void loop()
{
  // Add entropy to random number generator; we use a lot of it.
  random16_add_entropy( random());

  Fire2012(); // run simulation frame
  
  FastLED.show(); // display this frame
 [b] FastLED.delay(1000 / FRAMES_PER_SECOND);[/b]
}


// Fire2012 by Mark Kriegsman, July 2012
// as part of "Five Elements" shown here: http://youtu.be/knWiGsmgycY
//// 
// This basic one-dimensional 'fire' simulation works roughly as follows:
// There's a underlying array of 'heat' cells, that model the temperature
// at each point along the line.  Every cycle through the simulation, 
// four steps are performed:
//  1) All cells cool down a little bit, losing heat to the air
//  2) The heat from each cell drifts 'up' and diffuses a little
//  3) Sometimes randomly new 'sparks' of heat are added at the bottom
//  4) The heat from each cell is rendered as a color into the leds array
//     The heat-to-color mapping uses a black-body radiation approximation.
//
// Temperature is in arbitrary units from 0 (cold black) to 255 (white hot).
//
// This simulation scales it self a bit depending on NUM_LEDS; it should look
// "OK" on anywhere from 20 to 100 LEDs without too much tweaking. 
//
// I recommend running this simulation at anywhere from 30-100 frames per second,
// meaning an interframe delay of about 10-35 milliseconds.
//
// Looks best on a high-density LED setup (60+ pixels/meter).
//
//
// There are two main parameters you can play with to control the look and
// feel of your fire: COOLING (used in step 1 above), and SPARKING (used
// in step 3 above).
//
// COOLING: How much does the air cool as it rises?
// Less cooling = taller flames.  More cooling = shorter flames.
// Default 50, suggested range 20-100 
#define COOLING  55

// SPARKING: What chance (out of 255) is there that a new spark will be lit?
// Higher chance = more roaring fire.  Lower chance = more flickery fire.
// Default 120, suggested range 50-200.
#define SPARKING 120


void Fire2012()
{
// Array of temperature readings at each simulation cell
  static byte heat[NUM_LEDS];

  // Step 1.  Cool down every cell a little
    for( int i = 0; i < NUM_LEDS; i++) {
      heat[i] = qsub8( heat[i],  random8(0, ((COOLING * 10) / NUM_LEDS) + 2));
    }
  
    // Step 2.  Heat from each cell drifts 'up' and diffuses a little
    for( int k= NUM_LEDS - 1; k >= 2; k--) {
      heat[k] = (heat[k - 1] + heat[k - 2] + heat[k - 2] ) / 3;
    }
    
    // Step 3.  Randomly ignite new 'sparks' of heat near the bottom
    if( random8() < SPARKING ) {
      int y = random8(7);
      heat[y] = qadd8( heat[y], random8(160,255) );
    }

    // Step 4.  Map from heat cells to LED colors
    for( int j = 0; j < NUM_LEDS; j++) {
        leds[j] = HeatColor( heat[j]);
    }
}