Function with array as parameter

Using Arduino Programming Questions
1

Hi, i am using some functions that use an array as a parameter, but I want to give that array to a function inside the function. Will it work if I do it like in the code below(functions stuurLed, verwijderLed and stuurNaarChip) because if I use the "[]" behind the name it won't compilate.

/****************************************************************
 * Simple test of ht16k33 library turning on and off LEDs
 */


#include <Wire.h>

// Define the class
byte adres = 0x70;


byte displayRam[16] = {
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000
};

/****************************************************************/
void setup() {
  Serial.begin(57600);
  Serial.println(F("ht16k33 light test v0.01"));
  Serial.println();
  Wire.begin();
  
  Wire.beginTransmission(adres);
  Wire.write(0b00100001);
  Wire.endTransmission();

  Wire.beginTransmission(adres);
  Wire.write(0b10000001);
  Wire.endTransmission();

  Wire.beginTransmission(adres);
  Wire.write(0b10100000);
  Wire.endTransmission();

  Wire.beginTransmission(adres);
  Wire.write(0b11101111);
  Wire.endTransmission();
  
  }

void stuurLed(int rij, int kolom, byte ram[]){
  bitSet(ram[kolom],rij);
  stuurNaarChip(ram);
}

void verwijderLed(int rij, int kolom,byte ram[]){
  bitClear(ram[kolom],rij);
  stuurNaarChip(ram);
}

void stuurNaarChip(byte ram[]){
  Wire.beginTransmission(adres);
  Wire.write(0b00000000);
  for (int i=0; i<(sizeof(ram)-1);i++){
    Wire.write(ram[i]); 
  }
  Wire.endTransmission();
}

/****************************************************************/
void loop() {

  stuurNaarChip(displayRam);
  delay(5000);
  stuurLed(0,0,displayRam);
  delay(5000);
  verwijderLed(0,0,displayRam);
  delay(5000);

} // loop
2

It compiles for me but doesn't do what you want. Passing byte ram[] is the same as passing a pointer (byte *ram). You need to pass the length of the array was well.

/****************************************************************
   Simple test of ht16k33 library turning on and off LEDs
*/


#include <Wire.h>

// Define the class
byte adres = 0x70;


byte displayRam[16] = {
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000,
  0b00000000
};

const int ramSize = sizeof(displayRam) / sizeof(displayRam[0]);

/****************************************************************/
void setup() {
  Serial.begin(57600);
  Serial.println(F("ht16k33 light test v0.01"));
  Serial.println();
  Wire.begin();

  Wire.beginTransmission(adres);
  Wire.write(0b00100001);
  Wire.endTransmission();

  Wire.beginTransmission(adres);
  Wire.write(0b10000001);
  Wire.endTransmission();

  Wire.beginTransmission(adres);
  Wire.write(0b10100000);
  Wire.endTransmission();

  Wire.beginTransmission(adres);
  Wire.write(0b11101111);
  Wire.endTransmission();

}

void stuurLed(int rij, int kolom, byte ram[], int sz) {
  bitSet(ram[kolom], rij);
  stuurNaarChip(ram, sz);
}

void verwijderLed(int rij, int kolom, byte ram[], int sz) {
  bitClear(ram[kolom], rij);
  stuurNaarChip(ram, sz);
}

void stuurNaarChip(byte ram[], int sz) {
  Wire.beginTransmission(adres);
  Wire.write(0b00000000);
  for (int i = 0; i < sz; i++) {
    Wire.write(ram[i]);
  }
  Wire.endTransmission();
}

/****************************************************************/
void loop() {

  stuurNaarChip(displayRam, ramSize);
  delay(5000);
  stuurLed(0, 0, displayRam, ramSize);
  delay(5000);
  verwijderLed(0, 0, displayRam, ramSize);
  delay(5000);

} // loop