# Fusionner 2 code arduino

**URL:** <https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570>\
**Category:** Français\
**Created:** [January 29, 2024, 9:38pm UTC](https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570 "2024-01-29T21:38:35Z")\
**Posts on this page:** 14\
**Page:** 1

<div class="post-metadata">

**Author:** ![sam\_292](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/sam_292/32/976496_2.png) [@sam\_292](https://forum.arduino.cc/u/sam_292)\
**Post date:** [January 29, 2024, 9:38pm UTC](https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570/1 "2024-01-29T21:38:35Z")

</div>

Bonjour,  
je suis en STI2D je réalise un projet avec un aéroglisseur piloter a distance grâce a des NRF.  
J'ai 2 fonction sur mon code, la première est de contrôler un servo moteur grâce a un joystick et la deuxième et de contrôler un moteur bushless avec un potentiomètre.  
J'ai donc réaliser le codes suivant qui fonctionne chacun en test unitaire sois (potentiomètre/moteur brusless) sois (joystick/servo-moteur) sans effectuer de modification au code. Mon problème est que je n'arrive pas a faire fonctionner mais 2 fonction sur le meme code en dédoublant chaque fonction pour avoir une seul carte émettrice et une seul carte réceptrice. Voici le code sachant que le codes est le même sur la carte émettrice et réceptrice ainsi que pour chaque fonction.

Code (potentiomètre/moteur brusless) et (joystick/servo-moteur) :

```arduino
#include <SPI.h>
#include <RF24.h>
#include <Servo.h>

#define pinCE 7 // On associe la broche "CE" du NRF24L01 à la sortie digitale D7 de l'arduino
#define pinCSN 8 // On associe la broche "CSN" du NRF24L01 à la sortie digitale D8 de l'arduino
#define pinSERVO 9 // On associe la broche "SIGNAL" du SERVO à la sortie digitale D9 de l'arduino
#define pinPOT A0 // On associe le point milieu du potentiomètre à l'entrée analogique A0 de l'arduino

#define tunnel1 "PIPE1" // On définit un premier "nom de tunnel" (5 caractères), pour pouvoir envoyer des données à l'autre NRF24
#define tunnel2 "PIPE2" // On définit un second "nom de tunnel" (5 caractères), pour pouvoir recevoir des données de l'autre NRF24

RF24 radio(pinCE, pinCSN); // Instanciation du NRF24L01
Servo servomoteur; // Instanciation d'un objet pour contrôler le servomoteur

const byte adresses[][6] = {tunnel1, tunnel2}; // Tableau des adresses de tunnel, au format "byte array"

int valeurPotLocal; // Variable contenant la valeur du potentiomètre
int valeurAngleServoLocal; // Variable contenant la valeur de l'angle du servomoteur
int valeurAngleServoDistant; // Variable contenant la valeur de l'angle du servomoteur

void setup() {
  pinMode(pinPOT, INPUT); // Déclaration de la pin "pinPOT" en entrée
  servomoteur.attach(pinSERVO); // Liaison de la pin "pinSERVO" au servomoteur branché sur l'arduino
  
  radio.begin(); // Initialisation du module NRF24
  radio.openWritingPipe(adresses[0]); // Ouverture du "tunnel1" en ÉCRITURE
  radio.openReadingPipe(1, adresses[1]); // Ouverture du "tunnel2" en LECTURE
  radio.setPALevel(RF24_PA_MIN); // Sélection d'un niveau "MINIMAL" pour communiquer (pas besoin d'une forte puissance, pour nos essais)

  servomoteur.write(90); // Rotation du servomoteur pour le mettre en position médiane
  delay(2000); // puis démarrage du programme
}

void loop() {
  // ********ENVOI********
  radio.stopListening(); // On commence par arrêter le mode écoute, pour pouvoir émettre les données
  valeurPotLocal = analogRead(pinPOT); // On lit la valeur du potentiomètre (résultat retourné entre 0 et 1023)
  valeurAngleServoDistant = map(valeurPotLocal, 0, 1023, 0, 180); // On converti la valeur [0..1023] en [0..180] (pour correspondre à l'angle d'un servo)
  valeurAngleServoDistant = 2*(int)(valeurAngleServoDistant/2); // Léger arrondi, pour limiter les "tremblements" du servomoteur
  radio.write(&valeurAngleServoDistant, sizeof(valeurAngleServoDistant)); // … et on envoi cette valeur à l'autre arduino, via le NRF24
  delay(5); // avec une petite pause, avant de passer à la suite

  // ********RÉCEPTION********
  radio.startListening(); // On commence par arrêter le mode envoi, pour pouvoir réceptionner des données
  if(radio.available()) { // On regarde si une donnée a été reçue
    while (radio.available()) { // Si une donné est en attente de lecture, on va la lire
      radio.read(&valeurAngleServoLocal, sizeof(valeurAngleServoLocal)); // Lecture des données reçues, une par une
      servomoteur.write(valeurAngleServoLocal); // … et ajustement de l'angle du servomoteur à chaque fois
    }
    delay(20); // avec une petite pause, avant de reboucler
  }
  delay(5);
}

```

J'aimerais donc savoir si quelqu'un a une idée de comment m'y prendre pour faire fonctionner les 2 fonctions sur un seul code.  
Si jamais vous ne comprenez pas mon explication n'hésitez pas a me demander je ferrais au mieux pour vous réexpliquez.  
Merci d'avance.

---

<div class="post-metadata">

**Author:** ![68tjs](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/68tjs/32/927374_2.png) [@68tjs](https://forum.arduino.cc/u/68tjs)\
**Post date:** [January 30, 2024, 12:19am UTC](https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570/2 "2024-01-30T00:19:52Z")

</div>

Bonsoir,

Ce sujet a déjà été traité des dizaines de fois.  
La première chose à faire est de bien comprendre le rôle des fonctions setup() et loop().  
setup() ne s'exécute qu'une seule fois, elle est faite pour les configurations.  
loop() s'appelle ainsi parce qu'elle est placée dans une boucle infinie dont elle ne peut sortir

```arduino
while (1==1)
{
 loop() ;
}

```

Une fois cette étape franchie, tu utilises le moteur de recherche de ce forum (en haut et à droite de l'écran) et tu y entres "fusionner deux codes"

 ![image](https://europe1.discourse-cdn.com/arduino/original/4X/0/3/0/030a3e909a940e00f3fcf3daf3e7977f5dd6e9a6.png)

Les premiers résultats sont en français.

Tu lis, tu cherches à appliquer.  
Si tu as encore des incompréhensions, poste le code fusionné, indiques ce qui ne va pas.  
Comme tes questions seront plus précises, les réponses seront plus utiles.

---

<div class="post-metadata">

**Author:** ![J-M-L](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/j-m-l/32/766245_2.png) [@J-M-L](https://forum.arduino.cc/u/J-M-L)\
**Post date:** [January 30, 2024, 7:35am UTC](https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570/3 "2024-01-30T07:35:15Z")

</div>

si vous allez dans [la liste des tutos](https://forum.arduino.cc/t/liste-de-tutos-ecrits-par-des-membres-du-forum/865488) vous en trouverez deux qui pourraient être utiles

- [Exemple de communication sans fil nRF24L01+ (dans les 2 sens)](https://forum.arduino.cc/t/exemple-de-communication-sans-fil-nrf24l01/461905).
- [Autre Exemple de communication sans fil nRF24L01+ avec échange de structure](https://forum.arduino.cc/t/autre-exemple-de-communication-sans-fil-nrf24l01-avec-echange-de-structure/500173)

---

<div class="post-metadata">

**Author:** ![jpbbricole](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/jpbbricole/32/606025_2.png) [@jpbbricole](https://forum.arduino.cc/u/jpbbricole)\
**Post date:** [January 30, 2024, 10:18am UTC](https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570/4 "2024-01-30T10:18:23Z")

</div>

Bonjour sam\_292

> [@sam\_292](#):
>
> Mon problème est que je n'arrive pas a faire fonctionner mais 2 fonction sur le meme code en dédoublant chaque fonction

Une solution, [la structure de données](https://www.locoduino.org/spip.php?article107).  
Ainsi tu y regroupes les données du joystick et celle du potentiomètre:

```arduino
//------------------------------------- Structure de données
struct valeursDef // Structure de données du servo et du moteur
{
	int moteurSpeed; // Valeur de vitesse du moteur
	int angleServo; // Valeur angle du servo
};
valeursDef valeursFct; // Valeurs de sfonctione

```

données que tu tien à jour ainsi:

```arduino
	valeursFct.angleServo = valeurAngleServoDistant; // Mise de la valeur du servo dans la structure valeursFct
	valeursFct.moteurSpeed = 126; // Valeur bidon, à calculr

```

Que tu envoies ainsi:

```arduino
	radio.write(&valeursFct, sizeof(valeursFct)); // … et on envoi cette structure qui contient toutes les valeurs, via le NRF24

```

et que tu reçois ainsi:  
` radio.read(&valeursFct, sizeof(valeursFct)); // Lecture toutes des données reçues, en même temps`  
Pour faire marcher le servo:

```arduino
			servomoteur.write(valeursFct.angleServo); // … et ajustement de l'angle du servomoteur à chaque fois

```

Tu peux, ainsi, transmettre d'autres données via cette structure, il suffit juste d'y ajouter la décalartion d cette nouvelle valeur de fonction.

Cordialement  
jpbbricole

---

<div class="post-metadata">

**Author:** ![J-M-L](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/j-m-l/32/766245_2.png) [@J-M-L](https://forum.arduino.cc/u/J-M-L)\
**Post date:** [January 30, 2024, 10:38am UTC](https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570/5 "2024-01-30T10:38:27Z")

</div>

> [@jpbbricole](#):
>
> ```arduino
> int moteurSpeed; // Valeur de vitesse du moteur
> int angleServo; // Valeur angle du servo
> 
> ```

il vaut mieux prendre l'habitude d'utiliser les types de dimension fixe quand on fait de la communication binaire. un `int16_t` par exemple ou un `int32_t` pour le cas où l'émetteur et le récepteur n'auraient pas la même architecture (un int sur UNO c'est 2 octets alors que c'est 4 octets sur un ESP32 ou un MKR ➜ ce que l'on reçoit ne correspondrait pas)

pour éviter aussi que le compilateur prenne des libertés avec le padding ou l'alignement c'est aussi important d'utiliser l'attribut packed au moins

un truc comme cela est plus robuste

```arduino
struct __attribute__ ((packed)) Message {
  int16_t moteurSpeed; // Valeur de vitesse du moteur
  int16_t angleServo; // Valeur angle du servo
};

```

---

<div class="post-metadata">

**Author:** ![pandaroux007](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/pandaroux007/32/906297_2.png) [@pandaroux007](https://forum.arduino.cc/u/pandaroux007)\
**Post date:** [January 30, 2024, 3:55pm UTC](https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570/6 "2024-01-30T15:55:18Z")

</div>

Bonjour @J-M-L  
Bien que ce ne soit pas mon sujet, j'aime bien suivre ceux des autres, on apprend toujours des trucs. Je ne suis pas sûr de comprendre le code que vous avez fourni en exemple. Pourriez vous l'expliquer ?

Merci d'avance et désolé @sam_292 pour cette petite intrusion 🤗  
Cordialement  
Pandaroux007

---

<div class="post-metadata">

**Author:** ![J-M-L](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/j-m-l/32/766245_2.png) [@J-M-L](https://forum.arduino.cc/u/J-M-L)\
**Post date:** [January 30, 2024, 4:21pm UTC](https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570/7 "2024-01-30T16:21:04Z")

</div>

> [@pandaroux007](#):
>
> e ne suis pas sûr de comprendre le code que vous avez fourni en exemple

Vous voulez dire ce code là ?

```arduino
struct __attribute__ ((packed)) Message {
  int16_t moteurSpeed; // Valeur de vitesse du moteur
  int16_t angleServo; // Valeur angle du servo
};

```

---

<div class="post-metadata">

**Author:** ![terwal](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/terwal/32/1098571_2.png) [@terwal](https://forum.arduino.cc/u/terwal)\
**Post date:** [January 31, 2024, 8:44am UTC](https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570/8 "2024-01-31T08:44:45Z")

</div>

> [@sam\_292](#):
>
> Mon problème est que je n'arrive pas a faire fonctionner mais 2 fonction sur le meme code en dédoublant chaque fonction pour avoir une seul carte émettrice et une seul carte réceptrice. Voici le code sachant que le codes est le même sur la carte émettrice et réceptrice ainsi que pour chaque fonction.

Si le code est le même, tu n'a pas une carte émettrice et l'autre réceptrice.  
Mais deux carte qui émettent et reçoivent en même temps.  
Ton projet n'est pas de faire une carte émettrice avec un potentiomètre et un joystick qui envoi ses informations à une carte réceptrice qui pilote un servomoteur et un moteur brushless en fonction des données reçues?

---

<div class="post-metadata">

**Author:** ![pandaroux007](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/pandaroux007/32/906297_2.png) [@pandaroux007](https://forum.arduino.cc/u/pandaroux007)\
**Post date:** [January 31, 2024, 2:03pm UTC](https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570/9 "2024-01-31T14:03:19Z")

</div>

Oui, c'est celui-ci.

---

<div class="post-metadata">

**Author:** ![J-M-L](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/j-m-l/32/766245_2.png) [@J-M-L](https://forum.arduino.cc/u/J-M-L)\
**Post date:** [January 31, 2024, 3:31pm UTC](https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570/10 "2024-01-31T15:31:22Z")

</div>

je suppose que vous comprenez ce qu'est une structure ?

Dans une structure, le language C++ (ou C) vous garantit que les différents attributs sont rangés dans cet ordre là en mémoire mais il ne vous garantit pas qu'il n'y a pas des octets vides (on appelle cela du padding) entre les attributs.

Par exemple dans certaines architectures, c'est plus rapide de lire une variable dans un registre si son premier octet tombe sur une adresse multiple de 4. si vous déclarez la structure

```arduino
struct {
  bool toto;
  uint32_t titi;
} maStructure;

```

le compilateur pourrait décider de stocker `maStructure` à une adresse multiple de 4, d'allouer 1 octet pour `toto`, laisser 3 octets vides et mettre `titi` ensuite de façon à ce que l'adresse de `titi` soit aussi sur une adresse multiple de 4. dans ce cas la taille de la structure serait de 8 octets (1 pour `toto`, 3 octets vides et 4 pour `titi`)

Quand on rajoute ` __attribute__ ((packed)) ` on dit au compilateur GCC (c'est spécifique, pas dans la norme) que l'on ne veut pas que le compilateur essaye de faire des optimisations d'alignement des données en mémoire. On lui demande que la structure occupe le moins d'octets possibles et donc la structure précedente n'aurait que 5 octets (1 pour `toto` et 4 pour `titi`).

c'est important car les optimisations de vitesse d'accès dépendent du code que vous avez et du compilateur. Si d'un côté le compilateur a fait du padding, votre structure fait 8 octets, et si de l'autre côté (réception) il n'y a pas de padding, la structure fait 5 octets.

Quand vous allez envoyer les 8 octets il seront reçus et mis dans une structure de 5 octets et vous aurez les mauvaises valeurs.

c'est pour cela que l'on rajoute ` __attribute__ ((packed)) ` pour ce genre de communication.

---

<div class="post-metadata">

**Author:** ![pandaroux007](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/pandaroux007/32/906297_2.png) [@pandaroux007](https://forum.arduino.cc/u/pandaroux007)\
**Post date:** [January 31, 2024, 3:36pm UTC](https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570/11 "2024-01-31T15:36:56Z")

</div>

Bonjour @J-M-L  
Oui, je sais ce qu'est une structure.  
Merci pour votre explication ! C'est très clair !

Cordialement  
Pandaroux007

---

<div class="post-metadata">

**Author:** ![sam\_292](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/sam_292/32/976496_2.png) [@sam\_292](https://forum.arduino.cc/u/sam_292)\
**Post date:** [February 1, 2024, 8:07pm UTC](https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570/12 "2024-02-01T20:07:14Z")

</div>

Si c'est ça le moteur et le servo moteur sont contrôler en fonction des donner envoyer par la carte émettrice.

---

<div class="post-metadata">

**Author:** ![terwal](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/terwal/32/1098571_2.png) [@terwal](https://forum.arduino.cc/u/terwal)\
**Post date:** [February 1, 2024, 10:01pm UTC](https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570/13 "2024-02-01T22:01:58Z")

</div>

Donc tu as deux programmes différents à faire ?  
Comment compte tu avec le même programme gérer différemment des deux cartes?

---

<div class="post-metadata">

**Author:** ![system](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/system/32/1140315_2.png) [@system](https://forum.arduino.cc/u/system)\
**Post date:** [July 30, 2024, 10:01pm UTC](https://forum.arduino.cc/t/fusionner-2-code-arduino/1217570/14 "2024-07-30T22:01:59Z")

</div>

Closed on July 30, 2024, 10:01pm UTC

This topic was automatically closed 180 days after the last reply. New replies are no longer allowed.
