Getting random readings from HX711 + load cell

I'm fairly experienced with arduino but I've never used a load cell or a load cell amp.

I'm using this guide to try to get a reading from a loadcell, just to test the setup.
https://learn.sparkfun.com/tutorials/load-cell-amplifier-hx711-breakout-hookup-guide

I have two different 20KG load cells and HX711's, both soldered the same :

Red to E+

Black to E-

Green to A+

White to A-

They're both wired this way, but on A2 and A3 instead of A0 and A1

Putting pressure on the load cell seems to not change anything on the results shown, and there seems to be a lot of random noise.
Both load cells produce similar results.
It seems that disconnecting and reconnecting the Vcc cable for the HX711, or the Data and Clock cable doesn't change anything on the readings, still getting random noise either way.
The jumper cables are all soldered, except the ones connecting to the arduino Uno that are only soldered on the HX711, and put in the female connectors of the Uno.

I've tried all troubleshooting steps mentionned in the 10 or so relevants posts on my first google page for hx711 + arduino troubleshooting, getting a bit desperate :frowning:

EDIT : If it's any help, the HX711 is drawing 4.5 mA on Vcc.

Any help is appreciated !

When i start the serial monitor, i get these readings :

HX711 calibration sketch
Remove all weight from scale
After readings begin, place known weight on scale
Press + or a to increase calibration factor
Press - or z to decrease calibration factor
Zero factor: -1
Reading: -115.3 lbs calibration_factor: -7050.00
Reading: -115.8 lbs calibration_factor: -7050.00
Reading: -115.3 lbs calibration_factor: -7050.00
Reading: -115.3 lbs calibration_factor: -7050.00
Reading: -115.3 lbs calibration_factor: -7050.00
Reading: -115.3 lbs calibration_factor: -7050.00
Reading: -115.3 lbs calibration_factor: -7050.00
Reading: -115.3 lbs calibration_factor: -7050.00

or these one's, it's pretty random

Reading: 7.3 lbs calibration_factor: -7050.00
Reading: -67.0 lbs calibration_factor: -7050.00
Reading: 7.3 lbs calibration_factor: -7050.00
Reading: -67.0 lbs calibration_factor: -7050.00
Reading: 7.3 lbs calibration_factor: -7050.00
Reading: -67.0 lbs calibration_factor: -7050.00
Reading: 7.3 lbs calibration_factor: -7050.00
Reading: -67.0 lbs calibration_factor: -7050.00
Reading: 7.3 lbs calibration_factor: -7050.00
Reading: -141.4 lbs calibration_factor: -7050.00
Reading: 7.3 lbs calibration_factor: -7050.00
Reading: 7.3 lbs calibration_factor: -7050.00

I've tried swapping A2/A3 but without any luck.

That's my code (example code from the sparkfun tutorial) :

/*
 Example using the SparkFun HX711 breakout board with a scale
 By: Nathan Seidle
 SparkFun Electronics
 Date: November 19th, 2014
 License: This code is public domain but you buy me a beer if you use this and we meet someday (Beerware license).

 This is the calibration sketch. Use it to determine the calibration_factor that the main example uses. It also
 outputs the zero_factor useful for projects that have a permanent mass on the scale in between power cycles.

 Setup your scale and start the sketch WITHOUT a weight on the scale
 Once readings are displayed place the weight on the scale
 Press +/- or a/z to adjust the calibration_factor until the output readings match the known weight
 Use this calibration_factor on the example sketch

 This example assumes pounds (lbs). If you prefer kilograms, change the Serial.print(" lbs"); line to kg. The
 calibration factor will be significantly different but it will be linearly related to lbs (1 lbs = 0.453592 kg).

 Your calibration factor may be very positive or very negative. It all depends on the setup of your scale system
 and the direction the sensors deflect from zero state
 This example code uses bogde's excellent library: https://github.com/bogde/HX711
 bogde's library is released under a GNU GENERAL PUBLIC LICENSE
 Arduino pin 2 -> HX711 CLK
 3 -> DOUT
 5V -> VCC
 GND -> GND

 Most any pin on the Arduino Uno will be compatible with DOUT/CLK.

 The HX711 board can be powered from 2.7V to 5V so the Arduino 5V power should be fine.

*/

#include "HX711.h"

#define DOUT  3
#define CLK  2

HX711 scale;

float calibration_factor = -7050; //-7050 worked for my 440lb max scale setup

void setup() {
  Serial.begin(9600);
  Serial.println("HX711 calibration sketch");
  Serial.println("Remove all weight from scale");
  Serial.println("After readings begin, place known weight on scale");
  Serial.println("Press + or a to increase calibration factor");
  Serial.println("Press - or z to decrease calibration factor");

  scale.begin(DOUT, CLK);
  scale.set_scale();
  scale.tare(); //Reset the scale to 0

  long zero_factor = scale.read_average(); //Get a baseline reading
  Serial.print("Zero factor: "); //This can be used to remove the need to tare the scale. Useful in permanent scale projects.
  Serial.println(zero_factor);
}

void loop() {

  scale.set_scale(calibration_factor); //Adjust to this calibration factor

  Serial.print("Reading: ");
  Serial.print(scale.get_units(), 1);
  Serial.print(" lbs"); //Change this to kg and re-adjust the calibration factor if you follow SI units like a sane person
  Serial.print(" calibration_factor: ");
  Serial.print(calibration_factor);
  Serial.println();

  if(Serial.available())
  {
    char temp = Serial.read();
    if(temp == '+' || temp == 'a')
      calibration_factor += 10;
    else if(temp == '-' || temp == 'z')
      calibration_factor -= 10;
  }
}

That's my code (example code from the sparkfun tutorial) :

That code uses D2/D3 and not A2/A3 to read the scale value. If you want to use A2/A3 you have to modify the lines

#define DOUT  3
#define CLK  2

to

#define DOUT  A3
#define CLK  A2

Thanks, I just figured it out five hours ago, idk why most schematics use analog ports >:(
Solved !

The chip is I2C so you'd normally connect to the I2C bus lines (which on the Uno happen also to be A4 and A5).

[ Ah, someone's corrected me, its not I2C, but there are circuits out there connecting them to SDA and SCL pins on the Arduino (presumably to be pin-compatible with other, I2C, ADCs)... ]