HC-05 - Bluetooth Chip + Arduino Micro not working with Standard Firmata?

Projects Networking, Protocols, and Devices
1

Hello Guys,

Can someone help me get my HC-05 with Arduino Micro + Firmata Running?

So I uploaded that code to the Arduino:

#define ROBOT_NAME "MOVEE"

// If you haven't configured your device before use this
#define BLUETOOTH_SPEED 38400 //This is the default baudrate that HC-05 uses
// If you are modifying your existing configuration, use this:
// #define BLUETOOTH_SPEED 57600

#include <SoftwareSerial.h>

// Swap RX/TX connections on bluetooth chip
//   Pin 10 --> Bluetooth TX
//   Pin 11 --> Bluetooth RX
SoftwareSerial mySerial(10, 11); // RX, TX

/*
  The posible baudrates are:
    AT+UART=1200,0,0 -------1200
    AT+UART=2400,0,0 -------2400
    AT+UART=4800,0,0 -------4800
    AT+UART=9600,0,0 -------9600 - Default for hc-06
    AT+UART=19200,0,0 ------19200
    AT+UART=38400,0,0 ------38400
    AT+UART=57600,0,0 ------57600 - Johnny-five speed
    AT+UART=115200,0,0 -----115200
    AT+UART=230400,0,0 -----230400
    AT+UART=460800,0,0 -----460800
    AT+UART=921600,0,0 -----921600
    AT+UART=1382400,0,0 ----1382400
*/

void setup() {
  pinMode(9, OUTPUT);  // this pin will pull the HC-05 pin 34 (key pin) HIGH to switch module to AT mode
  digitalWrite(9, HIGH);
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for Leonardo only
  }
  Serial.println("Starting config");
  mySerial.begin(BLUETOOTH_SPEED);
  delay(1000);

  // Should respond with OK
  mySerial.print("AT\r\n");
  waitForResponse();

  // Should respond with its version
  mySerial.print("AT+VERSION\r\n");
  waitForResponse();

  // Set pin to 0000
  mySerial.print("AT+PSWD=0000\r\n");
  waitForResponse();

  // Set the name to ROBOT_NAME
  String rnc = String("AT+NAME=") + String(ROBOT_NAME) + String("\r\n"); 
  mySerial.print(rnc);
  waitForResponse();

  // Set baudrate to 57600
  mySerial.print("AT+UART=57600,0,0\r\n");
  waitForResponse();

  Serial.println("Done!");
}

void waitForResponse() {
    delay(1000);
    while (mySerial.available()) {
      Serial.write(mySerial.read());
    }
    Serial.write("\n");
}

void loop() {}

As a response I got:

Starting config
OK
OK[VERSION]
OK
OK
OK
Done!

The Name of the chip got changed (MOVEE) also the baud rate to 57600 i assume because it said ok?.

So next I connected the RX pin of HC-05 to the Arduino Micro TX and HC-05 TX to Arduino Micro RX.

Next I uploaded the StandardFirmata Example to my Arduino Micro.

After that I connected my Mac to the HC-05 Chip via Bluetooth.

Now I downloaded the Firmata Test Program from here : (Main Page - Firmata)

Under Ports I see the name of my Bluetooth Chip, but if I select that Port no pins what so ever are shown in the Firmata Test Program, it is just empty (see screenshot)

Also the HC-05 is blinking pattern is: 1.5 Seconds Pause BLINK BLINK 1.5 Seconds Pause BLINK BLINK ....

On the bottom of the Firmata Test Program it says: TX:3 RX:0 but I have no idea what that means?

So does someone know where my problem is?

2

Ok I figured the problem:

Instead of

Firmata.begin(57600);

we have to use with Arduino Micros:

Serial1.begin(57600);
Firmata.begin(Serial1);