Heart rate sensor and buzzer not working.

jonathangfuchs · December 11, 2015, 7:33pm

Hi everybody,
Ive got a problem: I want to make a piezo buzzer go off as soon as my "Pulse Aensor Amped" does not record any pulse. I used the code below and inserted a tone and delay, if the QS does not detect anything. I had errors compiling it due to a "vector". This error message was displayed:

core.a(Tone.cpp.o): In function `__vector_7':
/Applications/Arduino.app/Contents/Resources/Java/hardware/arduino/cores/arduino/Tone.cpp:535: multiple definition of `__vector_7'
PulseSensorAmped_Arduino_1dot4.cpp.o:/Applications/Interrupt.ino:27: first defined here

This is the code I used:

/*  Pulse Sensor Amped 1.4    by Joel Murphy and Yury Gitman   http://www.pulsesensor.com

----------------------  Notes ----------------------  ---------------------- 
This code:
1) Blinks an LED to User's Live Heartbeat   PIN 13
2) Fades an LED to User's Live HeartBeat
3) Determines BPM
4) Prints All of the Above to Serial

Read Me:
https://github.com/WorldFamousElectronics/PulseSensor_Amped_Arduino/blob/master/README.md   
 ----------------------       ----------------------  ----------------------
*/

//  Variables
int pulsePin = 0;                 // Pulse Sensor purple wire connected to analog pin 0
int blinkPin = 13;                // pin to blink led at each beat
int fadePin = 5;                  // pin to do fancy classy fading blink at each beat
int fadeRate = 0;                 // used to fade LED on with PWM on fadePin

// Volatile Variables, used in the interrupt service routine!
volatile int BPM;                   // int that holds raw Analog in 0. updated every 2mS
volatile int Signal;                // holds the incoming raw data
volatile int IBI = 600;             // int that holds the time interval between beats! Must be seeded! 
volatile boolean Pulse = false;     // "True" when User's live heartbeat is detected. "False" when not a "live beat". 
volatile boolean QS = false;        // becomes true when Arduoino finds a beat.

// Regards Serial OutPut  -- Set This Up to your needs
static boolean serialVisual = false;   // Set to 'false' by Default.  Re-set to 'true' to see Arduino Serial Monitor ASCII Visual Pulse 


void setup(){
  pinMode(blinkPin,OUTPUT);         // pin that will blink to your heartbeat!
  pinMode(fadePin,OUTPUT);          // pin that will fade to your heartbeat!
  Serial.begin(115200);             // we agree to talk fast!
  interruptSetup();                 // sets up to read Pulse Sensor signal every 2mS 
   // IF YOU ARE POWERING The Pulse Sensor AT VOLTAGE LESS THAN THE BOARD VOLTAGE, 
   // UN-COMMENT THE NEXT LINE AND APPLY THAT VOLTAGE TO THE A-REF PIN
//   analogReference(EXTERNAL);   
}


//  Where the Magic Happens
void loop(){
  
    serialOutput() ;       
    
  if (QS == true){     // A Heartbeat Was Found
                       // BPM and IBI have been Determined
                       // Quantified Self "QS" true when arduino finds a heartbeat
        digitalWrite(blinkPin,HIGH);     // Blink LED, we got a beat. 
        fadeRate = 255;         // Makes the LED Fade Effect Happen
                                // Set 'fadeRate' Variable to 255 to fade LED with pulse
        serialOutputWhenBeatHappens();   // A Beat Happened, Output that to serial.     
        QS = false;                      // reset the Quantified Self flag for next time    
  }
  else {
  
   tone(8,2000,10);
    delay(10);
    tone(8,2000,10);
    delay(10);
    tone(8,2000,10);
    delay(10);
    
    }
      ledFadeToBeat();                      // Makes the LED Fade Effect Happen 
  delay(20);                             //  take a break
    
}





void ledFadeToBeat(){
    fadeRate -= 15;                         //  set LED fade value
    fadeRate = constrain(fadeRate,0,255);   //  keep LED fade value from going into negative numbers!
    analogWrite(fadePin,fadeRate);          //  fade LED
  }

I would appreciate if you could help me with this as I need to finish it soon as it is a school project.
Thanks a lot in advance!
Jon

UKHeliBob · December 11, 2015, 7:37pm

This is the code I used:

But not all of it.

jonathangfuchs · December 12, 2015, 6:30pm

It is all of the main code. There are 2 other codes that open, which are called Interrupt and AllSerial Handling

UKHeliBob · December 12, 2015, 7:41pm

What if the problem is in or is caused by the sections that you have not posted ? Part of the error message refers to Interrupt.ino

Please post all of the code.

jonathangfuchs · December 13, 2015, 1:13pm

AllSerialHandling Code

//////////
/////////  All Serial Handling Code, 
/////////  It's Changeable with the 'serialVisual' variable
/////////  Set it to 'true' or 'false' when it's declared at start of code.  
/////////

void serialOutput(){   // Decide How To Output Serial. 
 if (serialVisual == true){  
     arduinoSerialMonitorVisual('-', Signal);   // goes to function that makes Serial Monitor Visualizer
 } else{
      sendDataToSerial('S', Signal);     // goes to sendDataToSerial function
 }        
}


//  Decides How To OutPut BPM and IBI Data
void serialOutputWhenBeatHappens(){    
 if (serialVisual == true){            //  Code to Make the Serial Monitor Visualizer Work
    Serial.print("*** Heart-Beat Happened *** ");  //ASCII Art Madness
    Serial.print("BPM: ");
    Serial.print(BPM);
    Serial.print("  ");
 } else{
        sendDataToSerial('B',BPM);   // send heart rate with a 'B' prefix
        sendDataToSerial('Q',IBI);   // send time between beats with a 'Q' prefix
 }   
}



//  Sends Data to Pulse Sensor Processing App, Native Mac App, or Third-party Serial Readers. 
void sendDataToSerial(char symbol, int data ){
    Serial.print(symbol);

    Serial.println(data);                
  }


//  Code to Make the Serial Monitor Visualizer Work
void arduinoSerialMonitorVisual(char symbol, int data ){    
  const int sensorMin = 0;      // sensor minimum, discovered through experiment
const int sensorMax = 1024;    // sensor maximum, discovered through experiment

  int sensorReading = data;
  // map the sensor range to a range of 12 options:
  int range = map(sensorReading, sensorMin, sensorMax, 0, 11);

  // do something different depending on the 
  // range value:
  switch (range) {
  case 0:     
    Serial.println("");     /////ASCII Art Madness
    break;
  case 1:   
    Serial.println("---");
    break;
  case 2:    
    Serial.println("------");
    break;
  case 3:    
    Serial.println("---------");
    break;
  case 4:   
    Serial.println("------------");
    break;
  case 5:   
    Serial.println("--------------|-");
    break;
  case 6:   
    Serial.println("--------------|---");
    break;
  case 7:   
    Serial.println("--------------|-------");
    break;
  case 8:  
    Serial.println("--------------|----------");
    break;
  case 9:    
    Serial.println("--------------|----------------");
    break;
  case 10:   
    Serial.println("--------------|-------------------");
    break;
  case 11:   
    Serial.println("--------------|-----------------------");
    break;
  
  } 
}

Interrupt Code:

volatile int rate[10];                    // array to hold last ten IBI values
volatile unsigned long sampleCounter = 0;          // used to determine pulse timing
volatile unsigned long lastBeatTime = 0;           // used to find IBI
volatile int P =512;                      // used to find peak in pulse wave, seeded
volatile int T = 512;                     // used to find trough in pulse wave, seeded
volatile int thresh = 525;                // used to find instant moment of heart beat, seeded
volatile int amp = 100;                   // used to hold amplitude of pulse waveform, seeded
volatile boolean firstBeat = true;        // used to seed rate array so we startup with reasonable BPM
volatile boolean secondBeat = false;      // used to seed rate array so we startup with reasonable BPM


void interruptSetup(){     
  // Initializes Timer2 to throw an interrupt every 2mS.
  TCCR2A = 0x02;     // DISABLE PWM ON DIGITAL PINS 3 AND 11, AND GO INTO CTC MODE
  TCCR2B = 0x06;     // DON'T FORCE COMPARE, 256 PRESCALER 
  OCR2A = 0X7C;      // SET THE TOP OF THE COUNT TO 124 FOR 500Hz SAMPLE RATE
  TIMSK2 = 0x02;     // ENABLE INTERRUPT ON MATCH BETWEEN TIMER2 AND OCR2A
  sei();             // MAKE SURE GLOBAL INTERRUPTS ARE ENABLED      
} 


// THIS IS THE TIMER 2 INTERRUPT SERVICE ROUTINE. 
// Timer 2 makes sure that we take a reading every 2 miliseconds
ISR(TIMER2_COMPA_vect){                         // triggered when Timer2 counts to 124
  cli();                                      // disable interrupts while we do this
  Signal = analogRead(pulsePin);              // read the Pulse Sensor 
  sampleCounter += 2;                         // keep track of the time in mS with this variable
  int N = sampleCounter - lastBeatTime;       // monitor the time since the last beat to avoid noise

    //  find the peak and trough of the pulse wave
  if(Signal < thresh && N > (IBI/5)*3){       // avoid dichrotic noise by waiting 3/5 of last IBI
    if (Signal < T){                        // T is the trough
      T = Signal;                         // keep track of lowest point in pulse wave 
    }
  }

  if(Signal > thresh && Signal > P){          // thresh condition helps avoid noise
    P = Signal;                             // P is the peak
  }                                        // keep track of highest point in pulse wave

  //  NOW IT'S TIME TO LOOK FOR THE HEART BEAT
  // signal surges up in value every time there is a pulse
  if (N > 250){                                   // avoid high frequency noise
    if ( (Signal > thresh) && (Pulse == false) && (N > (IBI/5)*3) ){        
      Pulse = true;                               // set the Pulse flag when we think there is a pulse
//      digitalWrite(blinkPin,HIGH);                // turn on pin 13 LED
      IBI = sampleCounter - lastBeatTime;         // measure time between beats in mS
      lastBeatTime = sampleCounter;               // keep track of time for next pulse

      if(secondBeat){                        // if this is the second beat, if secondBeat == TRUE
        secondBeat = false;                  // clear secondBeat flag
        for(int i=0; i<=9; i++){             // seed the running total to get a realisitic BPM at startup
          rate[i] = IBI;                      
        }
      }

      if(firstBeat){                         // if it's the first time we found a beat, if firstBeat == TRUE
        firstBeat = false;                   // clear firstBeat flag
        secondBeat = true;                   // set the second beat flag
        sei();                               // enable interrupts again
        return;                              // IBI value is unreliable so discard it
      }   


      // keep a running total of the last 10 IBI values
      word runningTotal = 0;                  // clear the runningTotal variable    

      for(int i=0; i<=8; i++){                // shift data in the rate array
        rate[i] = rate[i+1];                  // and drop the oldest IBI value 
        runningTotal += rate[i];              // add up the 9 oldest IBI values
      }

      rate[9] = IBI;                          // add the latest IBI to the rate array
      runningTotal += rate[9];                // add the latest IBI to runningTotal
      runningTotal /= 10;                     // average the last 10 IBI values 
      BPM = 60000/runningTotal;               // how many beats can fit into a minute? that's BPM!
      QS = true;                              // set Quantified Self flag 
      // QS FLAG IS NOT CLEARED INSIDE THIS ISR
    }                       
  }

  if (Signal < thresh && Pulse == true){   // when the values are going down, the beat is over
//    digitalWrite(blinkPin,LOW);            // turn off pin 13 LED
    Pulse = false;                         // reset the Pulse flag so we can do it again
    amp = P - T;                           // get amplitude of the pulse wave
    thresh = amp/2 + T;                    // set thresh at 50% of the amplitude
    P = thresh;                            // reset these for next time
    T = thresh;
  }

  if (N > 2500){                           // if 2.5 seconds go by without a beat
    thresh = 512;                          // set thresh default
    P = 512;                               // set P default
    T = 512;                               // set T default
    lastBeatTime = sampleCounter;          // bring the lastBeatTime up to date        
    firstBeat = true;                      // set these to avoid noise
    secondBeat = false;                    // when we get the heartbeat back
  }

  sei();                                   // enable interrupts when youre done!
}// end isr

jonathangfuchs · December 13, 2015, 1:22pm

Here are also the Timer_Interrupt_Notes

/*
These notes put together by Joel Murphy for Pulse Sensor Amped, 2015

The code that this section is attached to uses a timer interrupt
to sample the Pulse Sensor with consistent and regular timing.
The code is setup to read Pulse Sensor signal at 500Hz (every 2mS).
The reasoning for this can be found here:

There are issues with using different timers to control the Pulse Sensor sample rate.
Sometimes, user will need to switch timers for access to other code libraries.
Also, some other hardware may have different timer setup requirements. This page
will cover those different needs and reveal the necessary settings. There are two
part of the code that will be discussed. The interruptSetup() routine, and
the interrupt function call. Depending on your needs, or the Arduino variant that you use,
check below for the correct settings.

ARDUINO UNO, Pro 328-5V/16MHZ, Pro-Mini 328-5V/16MHz (or any board with ATmega328P running at 16MHz)

Timer2

Pulse Sensor Arduino UNO uses Timer2 by default.
Use of Timer2 interferes with PWM on pins 3 and 11.
There is also a conflict with the Tone library, so if you want tones, use Timer1 below.

void interruptSetup(){
// Initializes Timer2 to throw an interrupt every 2mS.
TCCR2A = 0x02; // DISABLE PWM ON DIGITAL PINS 3 AND 11, AND GO INTO CTC MODE
TCCR2B = 0x06; // DON'T FORCE COMPARE, 256 PRESCALER
OCR2A = 0X7C; // SET THE TOP OF THE COUNT TO 124 FOR 500Hz SAMPLE RATE
TIMSK2 = 0x02; // ENABLE INTERRUPT ON MATCH BETWEEN TIMER2 AND OCR2A
sei(); // MAKE SURE GLOBAL INTERRUPTS ARE ENABLED
}

use the following interrupt vector with Timer2

ISR(TIMER2_COMPA_vect)

Timer1

Use of Timer1 interferes with PWM on pins 9 and 10.
The Servo library also uses Timer1, so if you want servos, use Timer2 above.

void interruptSetup(){
// Initializes Timer1 to throw an interrupt every 2mS.
TCCR1A = 0x00; // DISABLE OUTPUTS AND PWM ON DIGITAL PINS 9 & 10
TCCR1B = 0x11; // GO INTO 'PHASE AND FREQUENCY CORRECT' MODE, NO PRESCALER
TCCR1C = 0x00; // DON'T FORCE COMPARE
TIMSK1 = 0x01; // ENABLE OVERFLOW INTERRUPT (TOIE1)
ICR1 = 16000; // TRIGGER TIMER INTERRUPT EVERY 2mS
sei(); // MAKE SURE GLOBAL INTERRUPTS ARE ENABLED
}

Use the following ISR vector for the Timer1 setup above

ISR(TIMER1_OVF_vect)

Timer0

DON'T USE TIMER0! Timer0 is used for counting delay(), millis(), and micros().
Messing with Timer0 is highly unadvised!

ARDUINO Fio, Lilypad, ProMini328-3V/8MHz (or any board with ATmega328P running at 8MHz)

Timer2

Pulse Sensor Arduino UNO uses Timer2 by default.
Use of Timer2 interferes with PWM on pins 3 and 11.
There is also a conflict with the Tone library, so if you want tones, use Timer1 below.

void interruptSetup(){
// Initializes Timer2 to throw an interrupt every 2mS.
TCCR2A = 0x02; // DISABLE PWM ON DIGITAL PINS 3 AND 11, AND GO INTO CTC MODE
TCCR2B = 0x05; // DON'T FORCE COMPARE, 128 PRESCALER
OCR2A = 0X7C; // SET THE TOP OF THE COUNT TO 124 FOR 500Hz SAMPLE RATE
TIMSK2 = 0x02; // ENABLE INTERRUPT ON MATCH BETWEEN TIMER2 AND OCR2A
sei(); // MAKE SURE GLOBAL INTERRUPTS ARE ENABLED
}

use the following interrupt vector with Timer2

ISR(TIMER2_COMPA_vect)

Timer1

Use of Timer1 interferes with PWM on pins 9 and 10.
The Servo library also uses Timer1, so if you want servos, use Timer2 above.

void interruptSetup(){
// Initializes Timer1 to throw an interrupt every 2mS.
TCCR1A = 0x00; // DISABLE OUTPUTS AND PWM ON DIGITAL PINS 9 & 10
TCCR1B = 0x11; // GO INTO 'PHASE AND FREQUENCY CORRECT' MODE, NO PRESCALER
TCCR1C = 0x00; // DON'T FORCE COMPARE
TIMSK1 = 0x01; // ENABLE OVERFLOW INTERRUPT (TOIE1)
ICR1 = 8000; // TRIGGER TIMER INTERRUPT EVERY 2mS
sei(); // MAKE SURE GLOBAL INTERRUPTS ARE ENABLED
}

Use the following ISR vector for the Timer1 setup above

ISR(TIMER1_OVF_vect)

Timer0

DON'T USE TIMER0! Timer0 is used for counting delay(), millis(), and micros().
Messing with Timer0 is highly unadvised!

ARDUINO Leonardo (or any board with ATmega32u4 running at 16MHz)

Timer1

Use of Timer1 interferes with PWM on pins 9 and 10.

void interruptSetup(){
TCCR1A = 0x00;
TCCR1B = 0x0C; // prescaler = 256
OCR1A = 0x7C; // count to 124
TIMSK1 = 0x02;
sei();
}

The only other thing you will need is the correct ISR vector in the next step.

ISR(TIMER1_COMPA_vect)

ADAFRUIT Flora, ARDUINO Fio v3 (or any other board with ATmega32u4 running at 8MHz)

Timer1

Use of Timer1 interferes with PWM on pins 9 and 10.

void interruptSetup(){
TCCR1A = 0x00;
TCCR1B = 0x0C; // prescaler = 256
OCR1A = 0x3E; // count to 62
TIMSK1 = 0x02;
sei();
}

The only other thing you will need is the correct ISR vector in the next step.

ISR(TIMER1_COMPA_vect)

ADAFRUIT Gemma (or any other board with ATtiny85 running at 8MHz)

NOTE: Gemma does not do serial communication!
Comment out or remove the Serial code in the Arduino sketch!

Timer1

Use of Timer1 breaks PWM output on pin D1

void interruptSetup(){
TCCR1 = 0x88; // Clear Timer on Compare, Set Prescaler to 128 TEST VALUE
GTCCR &= 0x81; // Disable PWM, don't connect pins to events
OCR1C = 0x7C; // Set the top of the count to 124 TEST VALUE
OCR1A = 0x7C; // Set the timer to interrupt after counting to TEST VALUE
bitSet(TIMSK,6); // Enable interrupt on match between TCNT1 and OCR1A
sei(); // Enable global interrupts
}

The only other thing you will need is the correct ISR vector in the next step.

ISR(TIMER1_COMPA_vect)

*/

UKHeliBob · December 13, 2015, 1:54pm

The Tone library is using Timer 2

Line 535 of Tone.cpp

ISR(TIMER2_COMPA_vect)

and so are you
Line 198 of your program

ISR(TIMER2_COMPA_vect) {                        // triggered when Timer2 counts to 124

jonathangfuchs · December 14, 2015, 10:19am

UKHeliBob:
The Tone library is using Timer 2

Line 535 of Tone.cpp
ISR(TIMER2_COMPA_vect)
and so are you
Line 198 of your program
ISR(TIMER2_COMPA_vect) {                        // triggered when Timer2 counts to 124

So what do I have to change?

UKHeliBob · December 14, 2015, 10:35am

The use of timers is not something that I know much about but the best bet may be to use Timer 1 in your code or to write your own function to make sounds instead of using the Tone library,

It should be easy to replace

   tone(8,2000,10);
    delay(10);
    tone(8,2000,10);
    delay(10);
    tone(8,2000,10);
    delay(10);

with code to toggle pin 8 on and off for a period and make a noise.

Topic		Replies	Views
Pulse Sensor Amped Buzzer Code Programming Questions	2	1662	May 5, 2021
combining piezo buzzer and pulse sensor for arduino uno Programming Questions	12	7313	May 5, 2021
Creating an alert with a buzzer for a heart rate monitor arduino Programming Questions	27	6059	May 6, 2021
Heart beat sensor with sound output Project Guidance	5	4082	May 5, 2021
There is no response from the buzzer and LED. Please help me Programming Questions	7	468	December 6, 2023

Heart rate sensor and buzzer not working.

Related Topics