Help me,

I am working on a project using water flow sensor to measure the liters passing through it, and if it reaches a certain limit, it turns on buzzer and LED. Also, I am using LCD to display the liters on it.
Also, I am using keypad to determine the limit of liters that the LED and buzzer is started working forward.

My code is working properly without adding the keypad code. When I added it the LCD did not show something clear.

Here is the code,

#include <LiquidCrystal.h>
#include <Keypad.h>

const byte ROWS = 4; // Four rows
const byte COLS = 4; // Three columns

char keys[ROWS][COLS] = { // Define the Keymap
  {'1','2','3','A'},
  {'4','5','6','B'},
  {'7','8','9','C'},
  {'*','0','#','D'}
};

byte rowPins[ROWS] = { 2, 3, 4, 5 };// Connect keypad ROW0, ROW1, ROW2 and ROW3 to these Arduino pins.

byte colPins[COLS] = { 6, 7, 8 ,9}; // Connect keypad COL0, COL1 and COL2 to these Arduino pins.


Keypad kpd = Keypad( makeKeymap(keys), rowPins, colPins, ROWS, COLS );// Create the Keypad
// initialize the library with the numbers of the interface pins
LiquidCrystal lcd(12, 11, 10, 9, 8, 7);

byte statusLed    = 13;
byte sensorInterrupt = 0;  // 0 = digital pin 2
byte sensorPin       = 2;

// The hall-effect flow sensor outputs approximately 4.5 pulses per second per
// litre/minute of flow.
float calibrationFactor = 4.5;

volatile byte pulseCount;  

float flowRate;
unsigned int flowMilliLitres;
unsigned long totalMilliLitres;
unsigned long Usercheck;
unsigned long oldTime;

int LED = 15;
int buzzer = 14;

void setup()
{
  Serial.begin(9600);
  // set up the LCD's number of columns and rows: 
  lcd.begin(16, 2);
  // Print a message to the LCD.
  lcd.print("Hello Everyone!");
  delay(2000);
  lcd.clear();
  // Initialize a serial connection for reporting values to the host
  // Set up the status LED line as an output
  pinMode(statusLed, OUTPUT);
  digitalWrite(statusLed, HIGH);  // We have an active-low LED attached
  pinMode(LED,OUTPUT);
  pinMode(buzzer,OUTPUT);
  pinMode(sensorPin, INPUT);
  digitalWrite(sensorPin, HIGH);
  digitalWrite(LED,HIGH);
  digitalWrite(buzzer,HIGH);
  delay(2000);

  pulseCount        = 0;
  flowRate          = 0.0;
  flowMilliLitres   = 0;
  totalMilliLitres  = 0;
  oldTime           = 0;

  // The Hall-effect sensor is connected to pin 2 which uses interrupt 0.
  // Configured to trigger on a FALLING state change (transition from HIGH
  // state to LOW state)
  attachInterrupt(sensorInterrupt, pulseCounter, FALLING);
 
}

/**
 * Main program loop
 */
void loop()
{
   if((millis() - oldTime) > 1000)    // Only process counters once per second
  { 
    // Disable the interrupt while calculating flow rate and sending the value to
    // the host
    detachInterrupt(sensorInterrupt);
        
    // Because this loop may not complete in exactly 1 second intervals we calculate
    // the number of milliseconds that have passed since the last execution and use
    // that to scale the output. We also apply the calibrationFactor to scale the output
    // based on the number of pulses per second per units of measure (litres/minute in
    // this case) coming from the sensor.
    flowRate = ((1000.0 / (millis() - oldTime)) * pulseCount) / calibrationFactor;
    
    // Note the time this processing pass was executed. Note that because we've
    // disabled interrupts the millis() function won't actually be incrementing right
    // at this point, but it will still return the value it was set to just before
    // interrupts went away.
    oldTime = millis();
    
    // Divide the flow rate in litres/minute by 60 to determine how many litres have
    // passed through the sensor in this 1 second interval, then multiply by 1000 to
    // convert to millilitres.
    flowMilliLitres = (flowRate / 60) * 1000;
    
    // Add the millilitres passed in this second to the cumulative total
    totalMilliLitres += flowMilliLitres;
    
   char key = kpd.getKey();
   if (key) {  
    switch(key) {
      case '1':
        Usercheck=1000;
        break;
      case '2':
        Usercheck=2000;
        break;
      case '3':
        Usercheck=3000;
        break;
      case '4':
        Usercheck=4000;
        break;    
      case '5':
        Usercheck=5000;
        break;      
      case '6':
        Usercheck=6000;
        break;    
      case '7':
        Usercheck=7000;
        break;     
      case '8':
        Usercheck=8000;
        break;
      case '9':
        Usercheck=9000;
        break;
      default:
      Serial.println(key);
    }
    }
    if (totalMilliLitres > Usercheck)
    {
      digitalWrite(LED,HIGH);
      digitalWrite(buzzer,HIGH);    
      delay (500);
    }
    else {
      digitalWrite(LED,LOW);
      digitalWrite(buzzer,LOW);
      }
    unsigned int frac;
    
    // Print the cumulative total of litres flowed since starting 
    lcd.setCursor(0,0);
    lcd.print("Total Volume:");
    lcd.setCursor(0, 1);
    //Print a message to second line of LCD
    lcd.print(totalMilliLitres);
    lcd.print("mL");
    

    // Reset the pulse counter so we can start incrementing again
    pulseCount = 0;
    
    // Enable the interrupt again now that we've finished sending output
    attachInterrupt(sensorInterrupt, pulseCounter, FALLING);
  }
}

/*
Insterrupt Service Routine
 */
void pulseCounter()
{
  // Increment the pulse counter
  pulseCount++;
}
byte rowPins[ROWS] = { 2, 3, 4, 5 };// Connect keypad ROW0, ROW1, ROW2 and ROW3 to these Arduino pins.

byte colPins[COLS] = { 6, 7, 8 ,9}; // Connect keypad COL0, COL1 and COL2 to these Arduino pins.

Those are the pins that you told the library for the keypad you were using for the keypad.

LiquidCrystal lcd(12, 11, 10, 9, 8, 7);

And those are the pins you told the LiquidCrystal library that you were using for the LCD.

How did you manage to run this code without realizing that you'd hooked two things to the same pins on several occasions? The keypad and the LCD need their own pins. They can't share any.

In your other code, you wait WAY too long with your interrupt turned off. You’re going to miss pulses.

Write it so you detach the interrupt, make a copy of your volatile variable in some local variable, and then re-enable the interrupt immediately. You want to keep that running.

Also this:

switch(key) {
      case '1':
        Usercheck=1000;
        break;
      case '2':
        Usercheck=2000;
        break;
      case '3':
        Usercheck=3000;
        break;
      case '4':
        Usercheck=4000;
        break;    
      case '5':
        Usercheck=5000;
        break;      
      case '6':
        Usercheck=6000;
        break;    
      case '7':
        Usercheck=7000;
        break;     
      case '8':
        Usercheck=8000;
        break;
      case '9':
        Usercheck=9000;
        break;

Could be:

Usercheck = (key - '0') * 1000;

Oops! silly mistake,

And you are right about the interrupt issue, I will work on it.

Thank you. :slight_smile: