HELP PLEASE! DS3231 RTC clock won´t work (and I need it to work asap for a college project)

Projects Programming
3

First thing you should be doing is running the "standard" I2C Scanner. It will scan all I2C addresses and report if anything was found.
Results:

  1. Reports an I2C device at the address of you DS3231 = good it is at least talking
  2. Does not report any I2C devices (or at least not a device as should be the DS3231 address) = BAD check wiring, move every wire to verify the connections are good. Continue to run the scanner until your device is found.

Then, Run the example from you library for the DS3231.

// I2C Scanner

#include <Wire.h>

void setup() {
  Wire.begin();

  Serial.begin(9600);
  while (!Serial);             // Leonardo: wait for serial monitor
  Serial.println("\nI2C Scanner");
}

void loop() {
  byte error, address;
  int nDevices;

  Serial.println("Scanning...");

  nDevices = 0;
  for (address = 1; address < 127; address++ )
  {
    // The i2c_scanner uses the return value of
    // the Write.endTransmisstion to see if
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();

    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address < 16)
        Serial.print("0");
      Serial.print(address, HEX);
      Serial.println("  !");

      nDevices++;
    }
    else if (error == 4)
    {
      Serial.print("Unknown error at address 0x");
      if (address < 16)
        Serial.print("0");
      Serial.println(address, HEX);
    }
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");

  delay(5000);           // wait 5 seconds for next scan
}