HELP SENDING STRINGS TO SUBFUNTCIONS

dapa2014 · November 23, 2014, 1:50pm

HI EVERYONE,
i need some help in a project (i'm working on arduino uno r3 and macosx).

In the code that follows, which is used to send morse messages (see sendmsg function), i would like to take analogue readings of some pins and make the program transmit the value of these integer variables.
The function sendmsg() should be used to send a string which corresponds to an analog reading of a sensor.
however this sendmsg() function accepts text in the form of "text", but i can't make it accept strings which correspond to analogue reading values.
thanks and 73

THE CODE FOLLOWS::::

struct t_mtab { char c, pat; } ;
struct t_mtab morsetab[] = {
  	{'.', 106},
	{',', 115},
	{'?', 76},
	{'/', 41},
	{'A', 6},
	{'B', 17},
	{'C', 21},
	{'D', 9},
	{'E', 2},
	{'F', 20},
	{'G', 11},
	{'H', 16},
	{'I', 4},
	{'J', 30},
	{'K', 13},
	{'L', 18},
	{'M', 7},
	{'N', 5},
	{'O', 15},
	{'P', 22},
	{'Q', 27},
	{'R', 10},
	{'S', 8},
	{'T', 3},
	{'U', 12},
	{'V', 24},
	{'W', 14},
	{'X', 25},
	{'Y', 29},
	{'Z', 19},
	{'1', 62},
	{'2', 60},
	{'3', 56},
	{'4', 48},
	{'5', 32},
	{'6', 33},
	{'7', 35},
	{'8', 39},
	{'9', 47},
	{'0', 63}
} ;

#define N_MORSE  (sizeof(morsetab)/sizeof(morsetab[0]))
#define SPEED  (14)
#define DOTLEN  (1200/SPEED)
#define DASHLEN  (3*(1200/SPEED))

void
dash()
{
  digitalWrite(0, HIGH) ;
  delay(DASHLEN);
  digitalWrite(0, LOW) ;
  delay(DOTLEN) ;
}

void
dit()
{
  digitalWrite(0, HIGH) ;
  delay(DOTLEN);
  digitalWrite(0, LOW) ;
  delay(DOTLEN);
}

void
send(char c)
{
  int i ;
  if (c == ' ') {
    
    delay(7*DOTLEN) ;
    return ;
  }
  for (i=0; i<N_MORSE; i++) {
    if (morsetab[i].c == c) {
      unsigned char p = morsetab[i].pat ;
     

      while (p != 1) {
          if (p & 1)
            dash() ;
          else
            dit() ;
          p = p / 2 ;
      }
      delay(2*DOTLEN) ;
      return ;
    }
  }
  
}

void
sendmsg(char *str)
{
  while (*str)
    send(*str++) ;
 
}

void setup() {
   pinMode(0, OUTPUT);

}

void loop() {
  sendmsg("MESSAGE") ;
  delay(1500) ;
}

system · November 23, 2014, 2:06pm

but i can't make it accept strings which correspond to analogue reading values.

I can't see such a string

KenF · November 23, 2014, 2:09pm

Well this is the only bit that's going to run.
So the rest of your code is redundant.

void setup() {
   pinMode(0, OUTPUT);

}

void loop() {
  sendmsg("MESSAGE") ;
  delay(1500) ;
}

Well ok you call a small function to send "message"

dapa2014 · November 23, 2014, 2:21pm

the sendmsg() recalls other functions (send(), dot and dash etc.) to move cursor in strings and isolate single characters to be sent.
the problem is that i would like to insert into sendmsg() some variables corresponding to anlogue readings, as it seems to accept only text into quotation marks.
thanks

KenF · November 23, 2014, 2:27pm

OK
But this bit ensures that the last bit never gets sent.

      while (p != 1) {

Edit scrap this. I see you're using a leading 1 bit to mark the end of the string.

KenF · November 23, 2014, 2:37pm

So to achieve your objective, you just need something like this in your code somewhere.

char analogString[5];
sprintf ( analogString, "%d",analogRead(pin) );
sendmsg( analogString );

dapa2014 · November 23, 2014, 2:48pm

yes, it should work . i'll let you know there was even an issue with cahr * conversion thanks!!

econjack · November 23, 2014, 3:10pm

You can make your N_MORSE macro a little more flexible:

#define ARRAY_SIZE(x)  (sizeof(x)/sizeof(x[0]))

and then just call it with:

  for (i = 0; i < ARRAY_SIZE(morsetab); i++) {

You can also simplify your dash length macro to:

#define DASHLEN  (3*DOTLEN)

dapa2014 · November 23, 2014, 3:10pm

here is the final product

const int dPin = 2; 
const int aiPin = 3; 
const int aiiPin = 4; 
int d = 0;

struct t_mtab { char c, pat; } ;
struct t_mtab morsetab[] = {
              	{'.', 106},
              	{',', 115},
              	{'?', 76},
              	{'/', 41},
                {'*', 53},
                {'+', 42},
                {'=', 49},
              	{'A', 6},
              	{'B', 17},
              	{'C', 21},
              	{'D', 9},
              	{'E', 2},
              	{'F', 20},
              	{'G', 11},
              	{'H', 16},
              	{'I', 4},
              	{'J', 30},
              	{'K', 13},
              	{'L', 18},
              	{'M', 7},
              	{'N', 5},
              	{'O', 15},
              	{'P', 22},
              	{'Q', 27},
              	{'R', 10},
              	{'S', 8},
              	{'T', 3},
              	{'U', 12},
              	{'V', 24},
              	{'W', 14},
              	{'X', 25},
              	{'Y', 29},
              	{'Z', 19},
              	{'1', 62},
              	{'2', 60},
              	{'3', 56},
              	{'4', 48},
              	{'5', 32},
              	{'6', 33},
              	{'7', 35},
              	{'8', 39},
              	{'9', 47},
              	{'0', 63}
} ;

            #define N_MORSE  (sizeof(morsetab)/sizeof(morsetab[0]))
            #define SPEED  (14)
            #define DOTLEN  (1200/SPEED)
            #define DASHLEN  (3*(1200/SPEED))

void
dash()
{
digitalWrite(0, HIGH) ;
delay(DASHLEN);
digitalWrite(0, LOW) ;
delay(DOTLEN) ;
}

void
dit()
{
digitalWrite(0, HIGH) ;
delay(DOTLEN);
digitalWrite(0, LOW) ;
delay(DOTLEN);
}

void
send(char c)
{
int i ;
if (c == ' ') {
delay(7*DOTLEN) ;
return ;
}
for (i=0; i<N_MORSE; i++) {
if (morsetab[i].c == c) {
unsigned char p = morsetab[i].pat ;
while (p != 1) {
if (p & 1)
dash() ;
else
dit() ;
p = p / 2 ;
}
delay(2*DOTLEN) ;
return ;
}
}
}
void
sendmsg(char *str)
{
while (*str)
send(*str++) ;
}
void setup() {
 pinMode(0, OUTPUT);
 pinMode(2,INPUT);
 pinMode(3,INPUT);
 pinMode(4,INPUT);
}
void loop() {
  
  sendmsg ("=");
    
char analogiString[5];
sprintf ( analogiString, "%d",analogRead(aiPin) );

char analogiiString[5];
sprintf ( analogiiString, "%d",analogRead(aiiPin) );
 
                      sendmsg("* * * RYRYRYRYRYRY " ) ;
                      sendmsg("1." ) ;
                      sendmsg( analogiString ); 
                      sendmsg(" , 2." ) ;
                      sendmsg( analogiiString );
            
                    d = digitalRead(dPin);
                    if (d == HIGH) {     
                    sendmsg (" , 3.TRUE ");
                     } 
                    else {
                     sendmsg (", 3.FALSE ");
                    }  
                       sendmsg ("+");
                                     
                     delay(5000) ;  
}





[code/]

KenF · November 23, 2014, 3:16pm

So did it work?

dapa2014 · November 23, 2014, 3:59pm

yes it worked perfectly thanks!

Topic		Replies	Views
Understanding serial communication with another software Programming	39	473	September 20, 2025
I need help designing a function that can take a String[1] type argument and convert it to LED pulses of specific length depending on the character Programming	11	301	November 4, 2023
GSM/GPRS Modul SMS senden Deutsch	5	1706	January 23, 2020
COMBINIG STRINGS TO BE SENT TO A SUBFUNCTION Programming	4	1082	November 24, 2014
Brauche Hilfe, bitte! Deutsch	10	253	February 23, 2024

HELP SENDING STRINGS TO SUBFUNTCIONS

Related topics