Help to get this hardware spi ledcontrol library to compile

Other Hardware LEDs and Multiplexing
1

Hello, I am trying to get this hardware spi bus version of ledcontrol library to compile. It spits out an error when I try to compile it. I was referencing the LedControl_HW_SPI.h header to get it started. Any guidance from the community would be much appreciated.

LCDemoMatrix:14:1: error: 'lc' does not name a type
lc.begin(11); // use pin 11 for CS

LedControl_HW_SPI lc=LedControl_HW_SPI();
lc.begin(11); // use pin 11 for CS

And the link to the library is LedControl with Hardware support

The full code

//We always have to include the library
#include "LedControl_HW_SPI.h"

/*
 Now we need a LedControl to work with.
 ***** These pin numbers will probably not work with your hardware *****
 pin 12 is connected to the DataIn 
 pin 11 is connected to the CLK 
 pin 10 is connected to LOAD 
 We have only a single MAX72XX.
 */

LedControl_HW_SPI lc=LedControl_HW_SPI();
lc.begin(11); // use pin 11 for CS


/* we always wait a bit between updates of the display */
unsigned long delaytime=100;

void setup() {
  /*
   The MAX72XX is in power-saving mode on startup,
   we have to do a wakeup call
   */
  lc.shutdown(0,false);
  /* Set the brightness to a medium values */
  lc.setIntensity(0,8);
  /* and clear the display */
  lc.clearDisplay(0);
}

/*
 This method will display the characters for the
 word "Arduino" one after the other on the matrix. 
 (you need at least 5x7 leds to see the whole chars)
 */
void writeArduinoOnMatrix() {
  /* here is the data for the characters */
  byte a[5]={B01111110,B10001000,B10001000,B10001000,B01111110};
  byte r[5]={B00111110,B00010000,B00100000,B00100000,B00010000};
  byte d[5]={B00011100,B00100010,B00100010,B00010010,B11111110};
  byte u[5]={B00111100,B00000010,B00000010,B00000100,B00111110};
  byte i[5]={B00000000,B00100010,B10111110,B00000010,B00000000};
  byte n[5]={B00111110,B00010000,B00100000,B00100000,B00011110};
  byte o[5]={B00011100,B00100010,B00100010,B00100010,B00011100};

  /* now display them one by one with a small delay */
  lc.setRow(0,0,a[0]);
  lc.setRow(0,1,a[1]);
  lc.setRow(0,2,a[2]);
  lc.setRow(0,3,a[3]);
  lc.setRow(0,4,a[4]);
  delay(delaytime);
  lc.setRow(0,0,r[0]);
  lc.setRow(0,1,r[1]);
  lc.setRow(0,2,r[2]);
  lc.setRow(0,3,r[3]);
  lc.setRow(0,4,r[4]);
  delay(delaytime);
  lc.setRow(0,0,d[0]);
  lc.setRow(0,1,d[1]);
  lc.setRow(0,2,d[2]);
  lc.setRow(0,3,d[3]);
  lc.setRow(0,4,d[4]);
  delay(delaytime);
  lc.setRow(0,0,u[0]);
  lc.setRow(0,1,u[1]);
  lc.setRow(0,2,u[2]);
  lc.setRow(0,3,u[3]);
  lc.setRow(0,4,u[4]);
  delay(delaytime);
  lc.setRow(0,0,i[0]);
  lc.setRow(0,1,i[1]);
  lc.setRow(0,2,i[2]);
  lc.setRow(0,3,i[3]);
  lc.setRow(0,4,i[4]);
  delay(delaytime);
  lc.setRow(0,0,n[0]);
  lc.setRow(0,1,n[1]);
  lc.setRow(0,2,n[2]);
  lc.setRow(0,3,n[3]);
  lc.setRow(0,4,n[4]);
  delay(delaytime);
  lc.setRow(0,0,o[0]);
  lc.setRow(0,1,o[1]);
  lc.setRow(0,2,o[2]);
  lc.setRow(0,3,o[3]);
  lc.setRow(0,4,o[4]);
  delay(delaytime);
  lc.setRow(0,0,0);
  lc.setRow(0,1,0);
  lc.setRow(0,2,0);
  lc.setRow(0,3,0);
  lc.setRow(0,4,0);
  delay(delaytime);
}

/*
  This function lights up a some Leds in a row.
 The pattern will be repeated on every row.
 The pattern will blink along with the row-number.
 row number 4 (index==3) will blink 4 times etc.
 */
void rows() {
  for(int row=0;row<8;row++) {
    delay(delaytime);
    lc.setRow(0,row,B10100000);
    delay(delaytime);
    lc.setRow(0,row,(byte)0);
    for(int i=0;i<row;i++) {
      delay(delaytime);
      lc.setRow(0,row,B10100000);
      delay(delaytime);
      lc.setRow(0,row,(byte)0);
    }
  }
}

/*
  This function lights up a some Leds in a column.
 The pattern will be repeated on every column.
 The pattern will blink along with the column-number.
 column number 4 (index==3) will blink 4 times etc.
 */
void columns() {
  for(int col=0;col<8;col++) {
    delay(delaytime);
    lc.setColumn(0,col,B10100000);
    delay(delaytime);
    lc.setColumn(0,col,(byte)0);
    for(int i=0;i<col;i++) {
      delay(delaytime);
      lc.setColumn(0,col,B10100000);
      delay(delaytime);
      lc.setColumn(0,col,(byte)0);
    }
  }
}

/* 
 This function will light up every Led on the matrix.
 The led will blink along with the row-number.
 row number 4 (index==3) will blink 4 times etc.
 */
void single() {
  for(int row=0;row<8;row++) {
    for(int col=0;col<8;col++) {
      delay(delaytime);
      lc.setLed(0,row,col,true);
      delay(delaytime);
      for(int i=0;i<col;i++) {
        lc.setLed(0,row,col,false);
        delay(delaytime);
        lc.setLed(0,row,col,true);
        delay(delaytime);
      }
    }
  }
}

void loop() { 
  writeArduinoOnMatrix();
  rows();
  columns();
  single();
}
2

It's strongly suggested that you post your full code.

3 
lc.begin(11); // use pin 11 for CS

Try moving that line into setup().

4

Thank you, I came to that conclusion as well and it worked.

5

Do you understand why? If not, just ask.

6

I would like to hear your explanation. I only came to that conclusion by comparing it to other similar libraries.

7

That line you moved is an executable line of code. They are only allowed inside functions like setup() and loop() and functions called by them. Outside of functions, only declarations are allowed.

There is an exception to that rule. When you declare a new object, the object's class can have an "constructor" method which can contain executable code. (If you are not familliar, a "method" is simply a function that belongs to a particular class/object.) That constructor method gets called, once only, just after an object of the class gets created. It sets up whatever stuff is needed to get the new object ready for use.

Even if no constructor method is defined for a class, one always exists by default, which creates a "vanilla" version of the object. Constructor methods have exactly the same name as the class itself, and the default constructor has no parameters. The library author can create more constructor methods with different parameters, for different "flavours" of the object. Or they can choose to have only the default constructor and instead configure the flavour of the object with other methods, usually ".begin()" methods which take parameters.

Now here's the part I think confused you: the author of the original LEDcontrol library chose to use the former technique of making a constructor method that took parameters (the arduino pins to be used for data/clock etc). So when an object of the original class was declared, the pin numbers were passed to the constructor object, outside of setup()/loop(). But the author of the new library version chose the other technique. Their constructors take no parameters, but a .begin() call is needed instead, in setup(), to configure the pins that will be used.

Hope that made some kind of sense!