I know you have taken this part of the code from the demo-code of the RFID-library
Well it is a rather bad suited base for developping code.
I will teach you fishing to find out what is happening.
I'm using three macros that reduce the effort for adding debug-output to the code
these 3 macros are similar to each other but have functional variants
the macro "dbg" prints to the serial monitor on each and every call
the macro "dbgi" (do you see the "i" at the end ?) prints to the serial monitor only once every "x" milliseconds which can be specified in as the third parameter
print once every interval
so dbgi can be used at places where your code runs thriugh thousands of times per second but the printing happends only once every 500 milliseconds or once every 2 seconds or whatver interval you find useful
the macro "dbgc" (do you see the "c" at the end ?) prints to the serial monitor only once if integer variable specified has changed its value
print once on every change
These macros print the variable-name and the variable-value
The fixed text as the first parameter can be used to identify the exact position inside the code that has done the printing if you put a different fixed text into each call.
This helps a lot to see what is really going on in your code
This compiles but as I don't have your hardware you have to do the real test yourself
// MACRO-START * MACRO-START * MACRO-START * MACRO-START * MACRO-START * MACRO-START *
https://forum.arduino.cc/t/comfortable-serial-debug-output-short-to-write-fixed-text-name-and-content-of-any-variable-code-example/888298
#define dbg(myFixedText, variableName) \
Serial.print( F(#myFixedText " " #variableName"=") ); \
Serial.println(variableName);
// usage: dbg("1:my fixed text",myVariable);
// myVariable can be any variable or expression that is defined in scope
#define dbgi(myFixedText, variableName,timeInterval) \
do { \
static unsigned long intervalStartTime; \
if ( millis() - intervalStartTime >= timeInterval ){ \
intervalStartTime = millis(); \
Serial.print( F(#myFixedText " " #variableName"=") ); \
Serial.println(variableName); \
} \
} while (false);
// usage: dbgi("2:my fixed text",myVariable,1000);
// myVariable can be any variable or expression that is defined in scope
// third parameter is the time in milliseconds that must pass by until the next time a
// Serial.print is executed
// end of macros dbg and dbgi
// print only once when value has changed
#define dbgc(myFixedText, variableName) \
do { \
static long lastState; \
if ( lastState != variableName ){ \
Serial.print( F(#myFixedText " " #variableName" changed from ") ); \
Serial.print(lastState); \
Serial.print( F(" to ") ); \
Serial.println(variableName); \
lastState = variableName; \
} \
} while (false);
// MACRO-END * MACRO-END * MACRO-END * MACRO-END * MACRO-END * MACRO-END * MACRO-END *
#include <Servo.h> // including the servo library
#include <SPI.h>
#include <MFRC522.h>
#include <LiquidCrystal_I2C.h>
#define NSS_pin 10
#define RST_pin 6 //usually pin 9 but changed to pin 6
MFRC522 rfid(NSS_pin, RST_pin); //Instance of the class
// Create LCD object : Use 0x27 If 0x3F Doesn't work
LiquidCrystal_I2C lcd(0x3F, 16, 2);
byte newID [4];
byte userID[4] = {0xFC, 0x6D, 0x39, 0x4A};
int rfidState = 0;
int redRGB = 3; // pin for red rgb
int greenRGB = 5; //pin for green rgb
int redFlash = 0;
int greenFlash = 0;
// INITIALISE SERVO PINS
Servo myservo; // create servo object to control a servo
int servoPin = 6; // pin for servo
int pos = 0; //position in degrees for servo
int increment = 10; //angle goes up or down by increment
int servoDelay = 20; // interval between every sweep
int servoState = 0; //state of servo
//millis time variables;
unsigned long previousBlink = 0; //time for flash
unsigned long previousTime = 0; // time for servo
int flashTime = 200; // flash for RGB 5Hz
const int interval = 2000; // wait time till door closes
void printWelcomeMessage() {
dbg("print Welcome to the LCD",0);
}
void setup() {
Serial.begin (9600);
SPI.begin(); //initiate SPI bus
rfid.PCD_Init(); //initiate the library MFRC522
// Setup LCD with backlight and initialize
lcd.init();
lcd.backlight();
printWelcomeMessage();
myservo.attach(servoPin); // attaches the servo on pin 9 to the servo object
myservo.write (pos); //changed 0 to pos
}
void loop() {
dbgi("0: top of loop",0,2000);
//don't run the loop if card is not detected
if (! rfid.PICC_IsNewCardPresent())
return;
dbgi("1: card is present",1,2000);
//check if NUID has been detected
if (! rfid.PICC_ReadCardSerial())
return;
dbgi("2: rfid.PICC_ReadCardSerial() is true",2,2000);
/////// body of the RFID code ////////
//Store userID in newID array
for (byte i = 0; i < 4; i++) {
newID[i] = rfid.uid.uidByte[i];
}
dbgi("3:newID assigned",newID[0],1000);
//check if ID matches the database
if (accessDoor(userID, newID) == true && servoState == 0) {
Serial.println ("Access Granted");
servoState = 1;
previousTime = millis();
}
servo();
if (accessDoor(userID, newID) == false ) {
Serial.println("Access Denied");
}
/////// to only print once //////////
//Halt PICC
rfid.PICC_HaltA();
//Stop encryption on PCD
rfid.PCD_StopCrypto1();
}
bool accessDoor (byte accessCode[], byte newCode[]) {
for (byte i = 0; i < 4; i++) {
if (newCode[i] != accessCode[i]) {
return false;
}
}
return true;
}
void flashing_green() {
dbgi("A: flashing green",greenFlash,500);
if (millis() - previousBlink >= flashTime) {
if (greenFlash == 0) { // if light is off
greenFlash = 255; // turn light on
}
else {
greenFlash = 0; // or else turn off
}
lights (0, greenFlash);
previousBlink = millis();
//Serial.println("flashing green");
}
}
void flashing_red() {
dbgi("B: flashing red",redFlash,500);
if (millis() - previousBlink >= flashTime) {
if (redFlash == 0) { // if light is off
redFlash = 255; // turn light on
}
else {
redFlash = 0; // or else turn off
}
lights (redFlash, 0);
previousBlink = millis();
//Serial.println("flashing red");
}
}
void lights(int red, int green) {
analogWrite (redRGB, red);
analogWrite (greenRGB, green);
}
void servo() {
dbgc("S:",servoState);
switch (servoState) {
case 0:
lights(255, 0);
Serial.println("waiting for tag");
break;
case 1:
flashing_green();
//Serial.println ("flashing green");
if (millis() - previousTime >= servoDelay) {
pos += increment;
myservo.write(pos);
Serial.println(pos);
//Serial.println ("case 1");
previousTime = millis();
if (pos > 80) {
servoState = 2;
}
}
break;
case 2:
lights(0, 255); // light is green to enter
//Serial.println ("green light on");
dbgi("G:green light on",0,500);
if (millis() - previousTime >= interval) { //if 2secs have passed, go to state 3
previousTime = millis();
servoState = 3;
}
break;
case 3:
flashing_red();
//Serial.println("flashing red, closing");
dbgi("flashing red, closing",pos,500);
if (millis() - previousTime >= servoDelay) {
pos -= increment;
myservo.write(pos);
Serial.println(pos);
previousTime = millis();
if (pos == 0) {
lights (0, 0);
Serial.println ("door closed");
previousTime = millis();
servoState = 0;
}
}
break;
}
}
best regards Stefan
please ignore the lcd commands as Im still working on it.