How to send a small pulse from arduino?

I am currently working on a project that lights a LED for 250 miliseconds when a momentary switch is pressed, but I can't get it to work. I want it to light for those 250 miliseconds when the button is pressed, but when I hold it longer it keeps lit up. This is my problem, I hope someone has a solution for this.

I connected pin 2 to a momentary switch with a pulldown resistor as described in the tutorials on arduino.cc and then put in a LED with resistor on pin 8. They are both connected to ground.

void setup(){
  pinMode(8,OUTPUT);//pin of the LED
  pinMode(2,INPUT);//pin of the momentary switch
}
void loop(){
  if (digitalRead(2)==HIGH){
    digitalWrite(8,HIGH);
    delay(250);
    digitalWrite(8,LOW);
  }else{
    digitalWrite(8,LOW);
  }
}

Can't read attached ino files on my cell phone ;) Your code is small enough to be embedded in the post (please use code tags [code] and [/code] around it).

Have a look at the state change detection example; you need to react on a change from non-pressed to pressed, not on the pressed state of the button.

I tried to change the StateChangeCounter code so that it would work for me, but I couldn't figure out how to do this. Do you have any tips for me to use?

NiekS:
I tried to change the StateChangeCounter code so that it would work for me, but I couldn’t figure out how to do this. Do you have any tips for me to use?

post what you tried

int buttonState=0;
int lastButtonState=0;
void setup(){
  pinMode(2,INPUT);
  pinMode(8,OUTPUT);
}
void loop(){
  buttonState=digitalRead(2);
  if(buttonState!=lastButtonState){
    digitalWrite(8,HIGH);
    delay(250);
    digitalWrite(8,LOW);
  }else{
    digitalWrite(8,LOW);
  }
}

You will need to update lastButtonState

Your code is looking at a change in the switch, pushing and releasing. Is this what you needed?

.

LarryD:
You will need to update lastButtonState

Your code is looking at a change in the switch, pushing and releasing.
Is this what you needed?

.

Yes this is almost what I was looking for, thank you very much but now the LED also lits up when I release the momentary switch. Do you know if there’s any way to avoid this?

You will have to check to see if the buttonSate is LOW. If it is, then you can do your toggling. If it is HIGH, you ingnore the change.

Study this as it describes de-bouncing. https://www.arduino.cc/en/tutorial/debounce

.

NiekS: Yes this is almost what I was looking for, thank you very much but now the LED also lits up when I release the momentary switch. Do you know if there's any way to avoid this?

Yes, as already pointed out, use the state change example, included free-of-charge in the Arduino IDE:

/*
  State change detection (edge detection)

 Often, you don't need to know the state of a digital input all the time,
 but you just need to know when the input changes from one state to another.
 For example, you want to know when a button goes from OFF to ON.  This is called
 state change detection, or edge detection.

 This example shows how to detect when a button or button changes from off to on
 and on to off.

 The circuit:
 * pushbutton attached to pin 2 from +5V
 * 10K resistor attached to pin 2 from ground
 * LED attached from pin 13 to ground (or use the built-in LED on
   most Arduino boards)

 created  27 Sep 2005
 modified 30 Aug 2011
 by Tom Igoe

This example code is in the public domain.

 http://www.arduino.cc/en/Tutorial/ButtonStateChange

 */

// this constant won't change:
const int  buttonPin = 2;    // the pin that the pushbutton is attached to
const int ledPin = 13;       // the pin that the LED is attached to

// Variables will change:
int buttonPushCounter = 0;   // counter for the number of button presses
int buttonState = 0;         // current state of the button
int lastButtonState = 0;     // previous state of the button

void setup() {
  // initialize the button pin as a input:
  pinMode(buttonPin, INPUT);
  // initialize the LED as an output:
  pinMode(ledPin, OUTPUT);
  // initialize serial communication:
  Serial.begin(9600);
}


void loop() {
  // read the pushbutton input pin:
  buttonState = digitalRead(buttonPin);

  // compare the buttonState to its previous state
  if (buttonState != lastButtonState) {
    // if the state has changed, increment the counter
    if (buttonState == HIGH) {
      // if the current state is HIGH then the button
      // wend from off to on:
      buttonPushCounter++;
      Serial.println("on");
      Serial.print("number of button pushes:  ");
      Serial.println(buttonPushCounter);
    } else {
      // if the current state is LOW then the button
      // wend from on to off:
      Serial.println("off");
    }
    // Delay a little bit to avoid bouncing
    delay(50);
  }
  // save the current state as the last state,
  //for next time through the loop
  lastButtonState = buttonState;


  // turns on the LED every four button pushes by
  // checking the modulo of the button push counter.
  // the modulo function gives you the remainder of
  // the division of two numbers:
  if (buttonPushCounter % 4 == 0) {
    digitalWrite(ledPin, HIGH);
  } else {
    digitalWrite(ledPin, LOW);
  }

}

Thank you all very much for your help. I can now go on with my project.