How to send array via nrf24l01+ using mirf library

Hi,
I have been searching the web for 2 days now, and still can’t find a way to send a array via the nrf24l01+ to another arduino and have that arduino print in the array’s contents into the serial monitor. And by array I mean this:

int values[] = {255, 255};

How on earth can I do this? I have completely no idea.
Thnaks!

The send() method takes the address where the data is stored as the first argument. The name of an array is the address where the data is stored. Seems pretty simple to me to send an array.

Where IS your code?

Yes, I can send it, but how do I handle the data on the receiving end? it’ll print in the first number, (12) but not the second, instead printing in 0.

Transmitting:

#include <SPI.h>
#include <Mirf.h>
#include <nRF24L01.h>
#include <MirfHardwareSpiDriver.h>

void setup() {
   Serial.begin(9600);
   Serial.println("Please wait, configuring...");
   Mirf.spi = &MirfHardwareSpi;
   Mirf.csnPin = 7; 
   Mirf.cePin = 8;
   Mirf.init(); 
   Mirf.setRADDR((byte *)"client");
   Mirf.payload = sizeof(int);
   Mirf.config();
   Serial.println("Configuraiton complete");
}

void loop() {
  int values[] = {12, 13};
  Serial.println("Sending data");
  Mirf.setTADDR((byte *)"server");
  Mirf.send((byte *)&values);
  Serial.println("Data sent");
  delay(1000);
}

receiving:

#include <SPI.h>
#include <Mirf.h>
#include <nRF24L01.h>
#include <MirfHardwareSpiDriver.h>
 
void setup(){
   Serial.begin(9600);
   Serial.println("Please wait, configuring...");
   Mirf.spi = &MirfHardwareSpi;
   Mirf.csnPin = 7;
   Mirf.cePin = 8;
   Mirf.init(); 
   Mirf.setRADDR((byte *)"server");
   Mirf.payload = sizeof(int);
   Mirf.config();
   Serial.println("Configuration complete");
   Serial.println("Awaiting data");
}

void loop() {
  int values[] = {0, 0};
  if (Mirf.dataReady()) {
    Serial.println("Got packet");
    Mirf.getData((byte *) &values);
    Serial.println(values[0]);
    Serial.println(values[1]);
  }
}
   Mirf.payload = sizeof(int);

You are going to have a hard time fitting two ints into that space.

  Mirf.send((byte *)&values);

This sends the number of bytes defined by the stupidly-named payload member.

    Mirf.getData((byte *) &values);

This returns the number of bytes defined by the stupidly-named payload member.