HTTP POST request timeout when using iPhone hotspot

I am attempting to make an HTTP POST request to my server. I get the expected response when my MKR1000 is connected to my home wifi network. However, when I connect the MKR1000 to my iPhone 6s hotspot the request always times out.

Arduino MKR1000 code:

#define BLYNK_PRINT Serial

#include <WiFi101.h>
#include <ArduinoHttpClient.h>
#include <BlynkSimpleMKR1000.h>

const int button_pin = 7;

const char ssid[] = "****";
const char pass[] = "****";

const char server[] = "****";
const int port = 80;

WiFiClient wifi;
HttpClient client = HttpClient(wifi, server, port);

const char auth[] = "****";

int status = WL_IDLE_STATUS;

float x;
float y;
float z;

float dx;
float dy;
float dz;

float lng;
float lat;

void setup()
{
  pinMode(button_pin, INPUT);
  pinMode(LED_BUILTIN, OUTPUT);

  Serial.begin(9600);

  digitalWrite(LED_BUILTIN, HIGH);

  while (status != WL_CONNECTED) {
    Serial.print("Connecting to: ");
    Serial.println(ssid);

    status = WiFi.begin(ssid, pass);
  }

  Blynk.begin(auth, ssid, pass);

  digitalWrite(LED_BUILTIN, LOW);
}

void loop()
{
  Blynk.run();
  if (digitalRead(button_pin)) {
    String route = "/";
    String contentType = "application/json";
    String postData = "{\"latitude\":" + String(lat, 6) + ",\"longitude\":" + String(lng, 6) + "}";

    Serial.print("Data: ");
    Serial.println(postData);

    client.post(route, contentType, postData);

    int statusCode = client.responseStatusCode();
    String response = client.responseBody();

    Serial.print("Status code: ");
    Serial.println(statusCode);
    Serial.print("Response: ");
    Serial.println(response);
  }
}

BLYNK_WRITE(V0)
{
  dx = param[0].asFloat() - x;
  dy = param[1].asFloat() - y;
  dz = param[2].asFloat() + 1 - y;

  x = param[0].asFloat();
  y = param[1].asFloat();
  z = param[2].asFloat() + 1;

  Serial.println("acc data updated");
}

BLYNK_WRITE(V1)
{
  lat = param[0].asFloat();
  lng = param[1].asFloat();

  Serial.println("gps data updated");
}

It is important for it to work on my iPhone hotspot because the MKR1000 will not be within range of my home wifi network. Thanks in advance for the help.

I solved the problem. I was attempting to make the request to my server using its local IP address which is only accessible on my home network.