I2C connection between two boards (Beginner)

[adolph_moguchiy1]

I want to connect my esp32 c3 supermini (slave) to esp8266 (master). Slave should display received data on OLED screen, while master should send some data (like string). I connected SDA and SLA pins and ground pins correctly. But when I run test script, it doesn't work: display is black, in serial port (master at 115200 baud) I see message being sent: ..., but there was nothing on slave side. One more question: do I need to use some resistors to stabilize voltage on SDA and SLA pins? Or ESP boards already have them?

Sketch - Master's

#include <Wire.h>
#define SLAVE_ADDR 0x08  // Адрес ESP32-C3

void setup() {
  Wire.begin();  // Инициализация I2C как мастер
  Serial.begin(115200);
}

void loop() {
  int number = 10;  // Число для отправки
  Serial.print("Sending: ");
  Serial.println(number);

  // Отправка числа по I2C
  Wire.beginTransmission(SLAVE_ADDR);
  Wire.write((uint8_t)number);  // Отправка числа как байта
  Wire.endTransmission();

  delay(2000);  // Пауза между отправками
}

Sketch - Slave's

//Slave
#include <Wire.h>
#include <U8g2lib.h>  // Библиотека U8g2 для OLED

#define SLAVE_ADDR 0x08  // Адрес ESP32-C3
#define OLED_SDA 8       // Пин SDA для OLED
#define OLED_SCL 9       // Пин SCL для OLED

// Инициализация OLED (для SSD1306 128x64)
U8G2_SSD1306_128X64_NONAME_F_HW_I2C u8g2(U8G2_R0, /*reset=*/ U8X8_PIN_NONE, OLED_SCL, OLED_SDA);

int receivedNumber = 0;  // Переменная для хранения полученного числа

void setup() {
  Serial.begin(115200);
  
  // Инициализация I2C (slave)
  Wire.begin(SLAVE_ADDR);
  Wire.onReceive(receiveEvent);

  // Инициализация OLED
  u8g2.begin();
  u8g2.setFont(u8g2_font_6x10_tf);  // Выбор шрифта
  u8g2.setCursor(0, 15);            // Начальная позиция текста
  u8g2.clearBuffer();
  u8g2.print("Waiting...");
  u8g2.sendBuffer();
}

void loop() {
  // Основной цикл пуст, все действия в receiveEvent
}

// Обработчик приема данных по I2C
void receiveEvent(int bytesReceived) {
  if (Wire.available()) {
    receivedNumber = Wire.read();  // Чтение числа как байта
    Serial.print("Received: ");
    Serial.println(receivedNumber);

    // Обновление OLED
    u8g2.clearBuffer();
    u8g2.setCursor(0, 15);  // Позиция текста (x, y)
    u8g2.print("Number: ");
    u8g2.print(receivedNumber);  // Вывод числа на экран
    u8g2.sendBuffer();
  }
}

Or how else can these boards be connected?

[adolph_moguchiy1]

Wiring:

Serial monitors
Master's:

Slave's:

[timinelmira]

You can't: both are set to be masters.

For the slave, you need to use another set of pins to communicate on the I2C bus and you need to bit bang the communications.

[adolph_moguchiy1]

I connected
SDA (esp32 c3 sm) - SDA (esp8266)
SCL (esp32 c3 sm) - SCL (esp8266)
GRD (esp32 c3 sm) - GRD (esp8266)

Wire.begin(); //To set master's board
Wire.begin(ADDR);// To set slave's board

I watched a tutorial in yt, and they just connected A4, A5 and Ground pins on two Arduino uno boards respectively.

You mean: I have to change I2C pins on slave's side?

Sorry, If I ask very stupid questions and waste your time :'/

[GolamMostafa]

1. Connect Master's (ESP8266) SDA (D4) and SCL (D3) lines with correspondig SDA (GPIO-4, Fig-1) and SCL (GPIO-5, Fig-1) lines of Slave (ESP32-C3). (I am not sure or forgotten if you need pull-up resistors for the I2C Bus.) You need to include this line: Wire.begin(D4, D3) in the setup() function of Master.

Figure-1:

2. Try by uplaoding the the following sketches without OLED, which are slightly modified versions of yours:
Master Sketch:

#include <Wire.h>
#define SLAVE_ADDR 0x08  // Адрес ESP32-C3

void setup() 
{
  Wire.begin(D4, D3);   // SDA = D4 (GPIO/DPin-2), SCL = D3 (GPIO-0) 
  Serial.begin(115200);
}

void loop() 
{
  byte number = 10;  // Число для отправки
  Serial.print("Sending: ");
  Serial.println(number);

  // Отправка числа по I2C
  Wire.beginTransmission(SLAVE_ADDR);
  Wire.write(number);  // Отправка числа как байта
  Wire.endTransmission();

  delay(2000);  // Пауза между отправками
}

Slave Sketch:

//Slave
#include <Wire.h>

#define SLAVE_ADDR 0x08  // Адрес ESP32-C3
#define OLED_SDA 8       // Пин SDA для OLED
#define OLED_SCL 9       // Пин SCL для OLED
volatile bool flag = false;

byte receivedNumber = 0;  // Переменная для хранения полученного числа

void setup() 
{
  Serial.begin(115200);
  
  // Инициализация I2C (slave)
  Wire.begin(SLAVE_ADDR);
  Wire.onReceive(receiveEvent);
}

void loop() 
{
    if(flag == true) 
    {
        Serial.println(receivedNumber, DEC);
        flag = false;
    }
}

// Обработчик приема данных по I2C
void receiveEvent(int bytesReceived) 
{
    receivedNumber = Wire.read();
     flag = true;
}

3. Check that Slave's Serial Monitor shows 10 at 2-sec interval.
4. If Step-2 is not correct, trouble shoot by deecting the pesence of the Slave.
5. If Step-2 is correct, connect OLED with Slave to display the receiced data.

[jim-p]

@adolph_moguchiy1

You mean: I have to change I2C pins on slave's side?

No.
You wiring and code look to be correct.
However you need pullup resistors.
Connect a10K resistor from SCL to 3.3V and from SDA to 3.3V

As you already know, your wiring is correct

SDA (esp32 c3 sm) - SDA (esp8266)
SCL (esp32 c3 sm) - SCL (esp8266)
GRD (esp32 c3 sm) - GRD (esp8266)

[jim-p]

@timinelmira

For the slave, you need to use another set of pins to communicate on the I2C bus and you need to bit bang the communications.

That is totally wrong

[Brazilino]

Hi! welcome to the Forum.

@adolph_moguchiy1

Or how else can these boards be connected?

Take a look in the ESP-Now protocol. You can connect these 2 boards wirelessly.

[adolph_moguchiy1]

I really appreciate your answer. I2C communication finally worked! I also added 2 pull up resistors 10k each.

These are the correct pin names for my Super Mini and ESP8266:

Everything was fine until I added u8g2.begin(); And I spent almost 1 day to find out the reasons.

1. ESP8266 - Master;
2. ESP32-C3 Supermini - Slave;
3. OLED - Slave;

I tried to achieve control of one slave device (ESP32-C3 Supermini) by another slave device (OLED), but it is not possible cuz only Master can communicate with Slaves.

Masters are designed only to transmit and request data to slaves.
Slaves are designed only to receive and respond to the master.

Nothing about communication between the slave devices.
One slave device could not be master to another slave device.

[GolamMostafa]

Please, post your sketches.

[adolph_moguchiy1]

I decided to use UART communication instead of I2C. I did not change anything in my sketch, so I used the previous published one