# Im confused with new arduino cloud

**URL:** <https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762>\
**Category:** Cloud IoT\
**Created:** [June 9, 2026, 6:39pm UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762 "2026-06-09T18:39:21Z")\
**Posts on this page:** 15\
**Page:** 1

<div class="post-metadata">

**Author:** ![ramava416](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/ramava416/32/1121685_2.png) [@ramava416](https://forum.arduino.cc/u/ramava416)\
**Post date:** [June 9, 2026, 6:39pm UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/1 "2026-06-09T18:39:21Z")

</div>

Hello,im confused with new arduino cloud UI its different with the old one, the tutorial i have is from old arduino i tried to making smarthome with arduino cloud, when im using from dashboard arduino cloud its dosnt work the lamp wont turn on but when im using manual switch button the lamp is turn on. i really need some help here how to turn it on from arduino cloud idk if im doing it wrong. thx

---

<div class="post-metadata">

**Author:** ![xfpd](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/xfpd/32/1120236_2.png) [@xfpd](https://forum.arduino.cc/u/xfpd)\
**Post date:** [June 9, 2026, 7:26pm UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/2 "2026-06-09T19:26:09Z")

</div>

This link is a long read, but it describes the steps to build a cloud project.

> **[How to set-up and build a project using Arduino IoT Cloud](https://www.engineersgarage.com/arduino-iot-cloud-starter-guide/)**
>
> How to build IoT projects in Arduino IoT Cloud.

---

<div class="post-metadata">

**Author:** ![sonofcy](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/sonofcy/32/1283617_2.png) [@sonofcy](https://forum.arduino.cc/u/sonofcy)\
**Post date:** [June 9, 2026, 8:14pm UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/3 "2026-06-09T20:14:05Z")

</div>

We can't see your computer screen or desk. You need to show us stuff like code that is Auto Formatted and posted in a code block, photos of a hand-drawn wiring diagram, NOT the instructions, your actual wires with labels and datasheet links for non-common parts.

---

<div class="post-metadata">

**Author:** ![sonofcy](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/sonofcy/32/1283617_2.png) [@sonofcy](https://forum.arduino.cc/u/sonofcy)\
**Post date:** [June 9, 2026, 8:16pm UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/4 "2026-06-09T20:16:48Z")

</div>

That is an excellent resource!

---

<div class="post-metadata">

**Author:** ![ramava416](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/ramava416/32/1121685_2.png) [@ramava416](https://forum.arduino.cc/u/ramava416)\
**Post date:** [June 10, 2026, 4:27am UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/5 "2026-06-10T04:27:48Z")

</div>

sry about that, this is my arduino cloud setting

 ![image](https://europe1.discourse-cdn.com/arduino/original/4X/e/7/4/e7435fe4fe531eb745674f31e8d936f2ecdeb0d9.png)  
 ![image1](https://europe1.discourse-cdn.com/arduino/original/4X/b/b/8/bb87df538cf8e597d55a22cea3f31091532ee91b.png)  
 ![image2](https://europe1.discourse-cdn.com/arduino/original/4X/7/7/8/7782061afed47538edb5fed3636fa31c1e1bc9fd.png)  
 ![image3](https://europe1.discourse-cdn.com/arduino/original/4X/4/d/0/4d056d4616d3fb9d242d08432a4b7376a28c4792.png)  
 ![image4](https://europe1.discourse-cdn.com/arduino/original/4X/e/a/4/ea4ad9500804bcba83c5b827cccf940836904940.png)

and here the code i used

```arduino
#include <ArduinoIoTCloud.h>
#include <Arduino_ConnectionHandler.h>
#include <ESP8266Wifi.h>

const char DEVICE_LOGIN_NAME[] = ""; //Enter DEVICE ID

const char SSID[] = ""; //Enter WiFi SSID (name)
const char PASS[] = ""; //Enter WiFi password
const char DEVICE_KEY[] = ""; //Enter Secret device password (Secret Key)

// define the GPIO connected with Relays and switches
#define RelayPin1 5 //D1
#define RelayPin2 4 //D2
#define RelayPin3 14 //D5
#define RelayPin4 12 //D6

#define SwitchPin1 D4 //D4
#define SwitchPin2 0 //D3 
#define SwitchPin3 13 //D7
#define SwitchPin4 3 //RX

#define wifiLed 16 //D0

int toggleState_1 = 0; //Define integer to remember the toggle state for relay 1
int toggleState_2 = 0; //Define integer to remember the toggle state for relay 2
int toggleState_3 = 0; //Define integer to remember the toggle state for relay 3
int toggleState_4 = 0; //Define integer to remember the toggle state for relay 4

void onSwitch1Change();
void onSwitch2Change();
void onSwitch3Change();
void onSwitch4Change();

CloudSwitch switch1;
CloudSwitch switch2;
CloudSwitch switch3;
CloudSwitch switch4;

void initProperties(){

  ArduinoCloud.setBoardId(DEVICE_LOGIN_NAME);
  ArduinoCloud.setSecretDeviceKey(DEVICE_KEY);

  ArduinoCloud.addProperty(switch1, READWRITE, ON_CHANGE, onSwitch1Change);
  ArduinoCloud.addProperty(switch2, READWRITE, ON_CHANGE, onSwitch2Change);
  ArduinoCloud.addProperty(switch3, READWRITE, ON_CHANGE, onSwitch3Change);
  ArduinoCloud.addProperty(switch4, READWRITE, ON_CHANGE, onSwitch4Change);

}

WiFiConnectionHandler ArduinoIoTPreferredConnection(SSID, PASS);

const int debounceDelay = 200; // Debounce delay in milliseconds
unsigned long lastDebounceTime1 = 0;
unsigned long lastDebounceTime2 = 0;
unsigned long lastDebounceTime3 = 0;
unsigned long lastDebounceTime4 = 0;

// Track the previous state of each switch to handle edge detection
bool previousSwitchState1 = HIGH;
bool previousSwitchState2 = HIGH;
bool previousSwitchState3 = HIGH;
bool previousSwitchState4 = HIGH;

void manual_control() {
  unsigned long currentMillis = millis();

  // Manual Switch Control
  // Check each switch pin and toggle the corresponding relay if the switch is pressed (LOW state)
  
  // Check if Switch 1 is pressed
  if (digitalRead(SwitchPin1) == LOW && previousSwitchState1 == HIGH) {
    if (currentMillis - lastDebounceTime1 >= debounceDelay) {
      toggleState_1 = !toggleState_1;
      digitalWrite(RelayPin1, !toggleState_1);
      switch1 = toggleState_1; // Toggle Relay 1
      lastDebounceTime1 = currentMillis; // Update the last debounce time
    }
  }
  previousSwitchState1 = digitalRead(SwitchPin1);

  // Check if Switch 2 is pressed
  if (digitalRead(SwitchPin2) == LOW && previousSwitchState2 == HIGH) {
    if (currentMillis - lastDebounceTime2 >= debounceDelay) {
      toggleState_2 = !toggleState_2;
      digitalWrite(RelayPin2, !toggleState_2);
      switch2 = toggleState_2; // Toggle Relay 2
      lastDebounceTime2 = currentMillis; // Update the last debounce time
    }
  }
  previousSwitchState2 = digitalRead(SwitchPin2);

  // Check if Switch 3 is pressed
  if (digitalRead(SwitchPin3) == LOW && previousSwitchState3 == HIGH) {
    if (currentMillis - lastDebounceTime3 >= debounceDelay) {
      toggleState_3 = !toggleState_3;
      digitalWrite(RelayPin3, !toggleState_3);
      switch3 = toggleState_3; // Toggle Relay 3
      lastDebounceTime3 = currentMillis; // Update the last debounce time
    }
  }
  previousSwitchState3 = digitalRead(SwitchPin3);

  // Check if Switch 4 is pressed
  if (digitalRead(SwitchPin4) == LOW && previousSwitchState4 == HIGH) {
    if (currentMillis - lastDebounceTime4 >= debounceDelay) {
      toggleState_4 = !toggleState_4;
      digitalWrite(RelayPin4, !toggleState_4);
      switch4 = toggleState_4; // Toggle Relay 4
      lastDebounceTime4 = currentMillis; // Update the last debounce time
    }
  }
  previousSwitchState4 = digitalRead(SwitchPin4);
}

void setup() {
  // Initialize serial and wait for port to open:
  Serial.begin(9600);
  // This delay gives the chance to wait for a Serial Monitor without blocking if none is found
  delay(1500);

  // Defined in thingProperties.h
  initProperties();

  // Connect to Arduino IoT Cloud
  ArduinoCloud.begin(ArduinoIoTPreferredConnection);

  setDebugMessageLevel(2);
  ArduinoCloud.printDebugInfo();

  pinMode(RelayPin1, OUTPUT);
  pinMode(RelayPin2, OUTPUT);
  pinMode(RelayPin3, OUTPUT);
  pinMode(RelayPin4, OUTPUT);

  pinMode(wifiLed, OUTPUT);

  pinMode(SwitchPin1, INPUT_PULLUP);
  pinMode(SwitchPin2, INPUT_PULLUP);
  pinMode(SwitchPin3, INPUT_PULLUP);
  pinMode(SwitchPin4, INPUT_PULLUP);

  //During Starting all Relays should TURN OFF
  digitalWrite(RelayPin1, HIGH);
  digitalWrite(RelayPin2, HIGH);
  digitalWrite(RelayPin3, HIGH);
  digitalWrite(RelayPin4, HIGH);

  digitalWrite(wifiLed, HIGH); //Turn OFF WiFi LED
}

void loop() {
  ArduinoCloud.update();
  
  manual_control(); //Control relays manually

  if (WiFi.status() != WL_CONNECTED)
  {
    digitalWrite(wifiLed, HIGH); //Turn OFF WiFi LED
    //Serial.println("NO WIFI");
  }
  else{
    digitalWrite(wifiLed, LOW); //Turn ON WiFi LED
    //Serial.println("YES WIFI");
  }
}

void onSwitch1Change() {
  if (switch1 == 1)
  {
    digitalWrite(RelayPin1, LOW);
    Serial.println("Device1 ON");
    toggleState_1 = 1;
  }
  else
  {
    digitalWrite(RelayPin1, HIGH);
    Serial.println("Device1 OFF");
    toggleState_1 = 0;
  }
}

void onSwitch2Change() {
  if (switch2 == 1)
  {
    digitalWrite(RelayPin2, LOW);
    Serial.println("Device2 ON");
    toggleState_2 = 1;
  }
  else
  {
    digitalWrite(RelayPin2, HIGH);
    Serial.println("Device2 OFF");
    toggleState_2 = 0;
  }
}

void onSwitch3Change() {
  if (switch3 == 1)
  {
    digitalWrite(RelayPin3, LOW);
    Serial.println("Device2 ON");
    toggleState_3 = 1;
  }
  else
  {
    digitalWrite(RelayPin3, HIGH);
    Serial.println("Device3 OFF");
    toggleState_3 = 0;
  }
}

void onSwitch4Change() {
  if (switch4 == 1)
  {
    digitalWrite(RelayPin4, LOW);
    Serial.println("Device4 ON");
    toggleState_4 = 1;
  }
  else
  {
    digitalWrite(RelayPin4, HIGH);
    Serial.println("Device4 OFF");
    toggleState_4 = 0;
  }
}

```

i deleted the ID number and my wifi information from the code i send here but in the code my ESP have the wifi connected

---

<div class="post-metadata">

**Author:** ![xfpd](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/xfpd/32/1120236_2.png) [@xfpd](https://forum.arduino.cc/u/xfpd)\
**Post date:** [June 10, 2026, 4:35am UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/6 "2026-06-10T04:35:07Z")

</div>

> [@ramava416](#):
>
> ```arduino
> // define the GPIO connected with Relays and switches
> #define RelayPin1 5 //D1
> #define RelayPin2 4 //D2
> #define RelayPin3 14 //D5
> #define RelayPin4 12 //D6
> 
> #define SwitchPin1 D4 //D4
> #define SwitchPin2 0 //D3 
> #define SwitchPin3 13 //D7
> #define SwitchPin4 3 //RX
> 
> #define wifiLed 16 //D0
> 
> ```

Show your wiring.

> [@ramava416](#):
>
> lamp wont turn on

Do you mean the WiFi LED?

```arduino
void loop() {
  ArduinoCloud.update();

  manual_control(); //Control relays manually

  if (WiFi.status() != WL_CONNECTED)
  {
    digitalWrite(wifiLed, HIGH); //Turn OFF WiFi LED
    //Serial.println("NO WIFI");
  }
  else {
    digitalWrite(wifiLed, LOW); //Turn ON WiFi LED
    //Serial.println("YES WIFI");
  }
}

```

---

<div class="post-metadata">

**Author:** ![ptillisch](https://avatars.discourse-cdn.com/v4/letter/p/ad7895/32.png) [@ptillisch](https://forum.arduino.cc/u/ptillisch)\
**Post date:** [June 10, 2026, 4:58am UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/7 "2026-06-10T04:58:30Z")

</div>

Hi @ramava416. From the screenshot you shared in [**post #5**](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/5), I see the status of your Device is "offline":

 ![image](https://europe1.discourse-cdn.com/arduino/original/4X/e/8/b/e8b27b6749288b201fe0633a5d13c4dc79f691c0.png)

This means the Device is not communicating with the Arduino Cloud server. The board will only react to changes you make via the Dashboard if it is in an "online" state.

Was your board powered and running the Thing sketch at the time you took that screenshot? If not, please check the status again when the board is powered.

If the Device has an "offline" status even when the board is powered and running the Thing sketch, you must focus on finding the problem that is causing the Device to not be able to communicate with the Arduino Cloud server. We can guide you in investigating and solving the problem.

---

<div class="post-metadata">

**Author:** ![ramava416](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/ramava416/32/1121685_2.png) [@ramava416](https://forum.arduino.cc/u/ramava416)\
**Post date:** [June 10, 2026, 5:27am UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/9 "2026-06-10T05:27:52Z")

</div>

oh sry when i toke this SS i was not turn on the ESP but when its turn on the status was showing online but still when i tried to turn on the switch button from dashboard nothing happened to the lamp, same in google home too i still dont know what the problem

---

<div class="post-metadata">

**Author:** ![ptillisch](https://avatars.discourse-cdn.com/v4/letter/p/ad7895/32.png) [@ptillisch](https://forum.arduino.cc/u/ptillisch)\
**Post date:** [June 10, 2026, 7:09am UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/10 "2026-06-10T07:09:12Z")

</div>

Thanks for the clarification.

> [@ramava416](#):
>
> when i tried to turn on the switch button from dashboard nothing happened to the lamp

Please perform the following investigative procedure:

1. Open the "Things" page on the Arduino Cloud website:  
[https://app.arduino.cc/things](https://app.arduino.cc/things)
2. Select your Thing from the list on that page.  
The Thing page will open.
3. The Thing page contains a list of Variables. The current value of each Variable is shown there.

Does the value of the Variable shown on the Thing page reflect what you expect from the position of the switch on the Dashboard?

If you change the position of the switch on the dashboard, do you see the value of the Variable shown on the Thing page change accordingly?

---

<div class="post-metadata">

**Author:** ![ramava416](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/ramava416/32/1121685_2.png) [@ramava416](https://forum.arduino.cc/u/ramava416)\
**Post date:** [June 10, 2026, 8:14am UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/11 "2026-06-10T08:14:09Z")

</div>

yes the value is changed when i turn on or off the switch in dashboard

 ![image](https://europe1.discourse-cdn.com/arduino/original/4X/d/d/f/ddfea42616b51ce8803dae96d845bcfc67e33a06.png)  
 ![image](https://europe1.discourse-cdn.com/arduino/original/4X/c/c/0/cc05c9d1754609220041386a8aea6288f3780378.png)

---

<div class="post-metadata">

**Author:** ![ramava416](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/ramava416/32/1121685_2.png) [@ramava416](https://forum.arduino.cc/u/ramava416)\
**Post date:** [June 10, 2026, 8:30am UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/12 "2026-06-10T08:30:39Z")

</div>

i was uploading my code from arduino ide so its fine right not from the arduino cloud sketch, and here from the yt tutorial is old arduino cloud right because right now so different

 ![image](https://europe1.discourse-cdn.com/arduino/original/4X/b/6/1/b6114c8a914f1d4be23deef0068003ff6eb5c817.jpeg)  
here the yt link for the tutorial [https://youtu.be/K09vSRz3Ugk?si=s8W784030zbfoDM2](https://youtu.be/K09vSRz3Ugk?si=s8W784030zbfoDM2)  
maybe you can help me with the new arduino cloud ver to make that

---

<div class="post-metadata">

**Author:** ![ptillisch](https://avatars.discourse-cdn.com/v4/letter/p/ad7895/32.png) [@ptillisch](https://forum.arduino.cc/u/ptillisch)\
**Post date:** [June 11, 2026, 12:08pm UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/13 "2026-06-11T12:08:00Z")

</div>

Please try this experiment:

1. Connect the board that is running the Thing sketch to your computer with a USB cable.
2. Open the [Arduino IDE **Serial Monitor**](https://docs.arduino.cc/software/ide-v2/tutorials/ide-v2-serial-monitor).  
**ⓘ** Alternatively, you can use the [Arduino Cloud Editor **Serial Monitor**](https://docs.arduino.cc/arduino-cloud/guides/editor/#serial-monitor) if you prefer.
3. Make sure " **9600**" is selected from the baud rate menu near the top right corner of the Serial Monitor panel in the Arduino IDE window.
4. Change the position of one of the switches in the Dashboard.

The expected result is that you would see a message printed in Serial Monitor something like:

```plaintext
Device1 ON

```

or:

```plaintext
Device1 OFF

```

This is due to the debugging code that was included in the sketch:

> [@ramava416](#):
>
> ```cpp
> void onSwitch1Change() {
> if (switch1 == 1)
> {
> digitalWrite(RelayPin1, LOW);
> Serial.println("Device1 ON");
> toggleState_1 = 1;
> }
> else
> {
> digitalWrite(RelayPin1, HIGH);
> Serial.println("Device1 OFF");
> toggleState_1 = 0;
> }
> }
> 
> ```

(note the `Serial.println` calls)

Do you see the expected messages in Serial Monitor?

> [@ramava416](#):
>
> i was uploading my code from arduino ide

It is fine to use Arduino IDE to develop and upload Thing sketches. However, it is essential that the sketch code matches against the configuration of the Thing.

When you create a Thing on Arduino Cloud, it also generates the skeleton of the Thing sketch, which reflects the Thing configuration. So when you start from that generated code, you are less likely to end up with a sketch that does not match the Thing configuration.

However, the fact that Arduino Cloud does recognize your Device as having an "online" status indicates that the board is able to communicate with the Arduino Cloud server. Additionally, I don't see any mismatch between the configuration of the Variables shown in the screenshot and the sketch code you shared.

---

<div class="post-metadata">

**Author:** ![ramava416](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/ramava416/32/1121685_2.png) [@ramava416](https://forum.arduino.cc/u/ramava416)\
**Post date:** [June 11, 2026, 1:30pm UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/15 "2026-06-11T13:30:06Z")

</div>

i tried it and i dont see the messages, its only show connected to arduino cloud  
 ![image](https://europe1.discourse-cdn.com/arduino/original/4X/6/9/d/69d310b0bbe2822d4532919d87cb92094b3ee212.png)

---

<div class="post-metadata">

**Author:** ![ramava416](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/ramava416/32/1121685_2.png) [@ramava416](https://forum.arduino.cc/u/ramava416)\
**Post date:** [June 11, 2026, 1:48pm UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/16 "2026-06-11T13:48:50Z")

</div>

its fixed now, i can turn the lamp from the dashboard i found the problem, its just typo in the declaration in cloud was Switch1 meanwhile in the code its switch1 thats why it dosnt want to respond because its different capital of letter S, im really appreciate your help with my problem and even tho its human error, really tyy for helping me

 ![image](https://europe1.discourse-cdn.com/arduino/original/4X/e/8/3/e83733ad5d16e0b86382a62d0da983003d97ed98.png)  
 ![image](https://europe1.discourse-cdn.com/arduino/original/4X/2/f/d/2fdd09925c04bdf6f0a472ecdfd43019fabe1264.png)

---

<div class="post-metadata">

**Author:** ![ptillisch](https://avatars.discourse-cdn.com/v4/letter/p/ad7895/32.png) [@ptillisch](https://forum.arduino.cc/u/ptillisch)\
**Post date:** [June 11, 2026, 1:51pm UTC](https://forum.arduino.cc/t/im-confused-with-new-arduino-cloud/1447762/17 "2026-06-11T13:51:18Z")

</div>

Ah, I missed that. Great work troubleshooting the cause of the problem! Thanks for taking the time to post an update with your solution.

This does highlight that it is generally a good idea to start from the skeleton sketch code generated by Arduino Cloud. However, I guess that wasn't really an option in this specific case where you were using some existing code from a tutorial.