Increment a menu from an analog read

Hello to all,
I have one question which is bugging me from some time.
I have found this menu on the internet and I want to increment it from a value which is read from an analog input or from a fixed one, does not matter. For example on the motor voltage parameter i want to start from 230 for example not from 0.
I cannot wrap my head around this and I did not find any solution to this.
Thank you in advance!

#include <LiquidCrystal.h>
LiquidCrystal lcd(6, 7, 5, 4, 3, 2);

//Input & Button Logic
const int numOfInputs = 4;
const int inputPins[numOfInputs] = {8,9,10,11};
int inputState[numOfInputs];
int lastInputState[numOfInputs] = {LOW,LOW,LOW,LOW};
bool inputFlags[numOfInputs] = {LOW,LOW,LOW,LOW};
long lastDebounceTime[numOfInputs] = {0,0,0,0};
long debounceDelay = 5;

//LCD Menu Logic
const int numOfScreens = 10;
int currentScreen = 0;
String screens[numOfScreens][2] = {{"Motor Voltage","Volts"}, {"Motor Current", "Amps"}, 
{"Motor Rated HP","HP"},{"Overload Temp.","degC"}, {"Accel Time", "Secs"}, {"Restart Time","Mins"},
{"Analog Out. Curr.","mA"},{"Input Temp.","degC"}, {"Run Time", "Hours"}, {"Start Times","times"}};
int parameters[numOfScreens];

void setup() {
  for(int i = 0; i < numOfInputs; i++) {
    pinMode(inputPins[i], INPUT);
    digitalWrite(inputPins[i], HIGH); // pull-up 20k
  }
  //Serial.begin(9600);
  lcd.begin(16, 2);
}

void loop() {
  setInputFlags();
  resolveInputFlags();
}

void setInputFlags() {
  for(int i = 0; i < numOfInputs; i++) {
    int reading = digitalRead(inputPins[i]);
    if (reading != lastInputState[i]) {
      lastDebounceTime[i] = millis();
    }
    if ((millis() - lastDebounceTime[i]) > debounceDelay) {
      if (reading != inputState[i]) {
        inputState[i] = reading;
        if (inputState[i] == HIGH) {
          inputFlags[i] = HIGH;
        }
      }
    }
    lastInputState[i] = reading;
  }
}

void resolveInputFlags() {
  for(int i = 0; i < numOfInputs; i++) {
    if(inputFlags[i] == HIGH) {
      inputAction(i);
      inputFlags[i] = LOW;
      printScreen();
    }
  }
}

void inputAction(int input) {
  if(input == 0) {
    if (currentScreen == 0) {
      currentScreen = numOfScreens-1;
    }else{
      currentScreen--;
    }
  }else if(input == 1) {
    if (currentScreen == numOfScreens-1) {
      currentScreen = 0;
    }else{
      currentScreen++;
    }
  }else if(input == 2) {
    parameterChange(0);
  }else if(input == 3) {
    parameterChange(1);
  }
}

void parameterChange(int key) {
  if(key == 0) {
    parameters[currentScreen]++;
  }else if(key == 1) {
    parameters[currentScreen]--;
  }
}

void printScreen() {
  lcd.clear();
  lcd.print(screens[currentScreen][0]);
  lcd.setCursor(0,1);
  lcd.print(parameters[currentScreen]);
  lcd.print(" ");
  lcd.print(screens[currentScreen][1]);
}

For example on the motor voltage parameter i want to start from 230 for example not from 0.

It sounds like you need to read the analogue input and translate it to a value between 0 and 9 in order to use it as an index to the screens array.

If that is what you want then consider using the map() function
map() function

byte menuIndex = (analogRead(analoguePin),0, 1023, 0, 9);

Than you very much for the response but maybe I did not explain myself very good.
I want to start incrementing the parameter on one screen from the array, does not matter which not from 0 but from 230 for example.
So it will be "Motor Voltage 230" and if I press the buttons increment to 231 or decrement to 229.
Thanks is advance!

I want to start incrementing the parameter on one screen from the array, does not matter which not from 0 but from 230 for example.

So set the initial value of the parameter to 230 instead of zero. Where in your code is the initial value of the parameters set ?

It looks like it is here

int parameters[numOfScreens];

If so then give each of the levels of the parameters array a starting value

Could you please explain me a little better how can I achieve this?
Thanks!

vlad00000:
Could you please explain me a little better how can I achieve this?
Thanks!

The same way that other arrays are defined

int parameters[numOfScreens] = {230, 123, 456, 321, 654, 999, 101, 102, 111, 222};

Thank you very much for all the help.
It worked!
Thanks again!