Thanks to Henning Pohl, since 1.6.6, we have the Serial plotter, now even as multiple plotter. This is very useful not only for development but also in the operational phase.
And it is understood that you cannot have both the Serial Monitor and the Serial Plotter. But in many cases, I wanted to display some data while the Plotter was in operation. So I came up with the idea of misusing the plotter to draw the figures in a 7-segment-mode. As there are the segments a, d and g one on top of the other, I need to draw 3 lines and oscillate them a bit in order to get thicker lines.
(But make sure to always print the same amount of data before sending a println. Otherwise some date will overtake the others.)
Maybe, one fine day Henning will come up with a proper solution for this problem.
void setup() {
Serial.begin(9600);
Serial.println(__FILE__);
}
const int u = 100;
const int w0 = 5;
const int w1 = 20;
const int h1 = u/4;
const int h2 = 2*u;
const int p0 = 0;
const int p1 = 1*u;
const int p2 = 3*u;
const int p3 = 5*u;
const int p4 = 7*u;
const int p5 = 9*u;
int i = 0;
void loop() {
for (int j = 0; j < 100; j++) {
Serial.print(random(200)); Serial.print(" ");
Serial.print(300+random(200)); Serial.print(" ");
Serial.print(600+random(200));
Serial.println();
}
//draw(10); // space
String si = String(i);
for (byte b = 0; b < si.length(); b++)
draw(si.charAt(b)-'0');
//draw(10); // space
i++;
}
const byte seg7[] = { B00111111, // 0
B00000110, // 1
B01011011,
B01001111,
B01100110,
B01101101,
B01111101,
B00000111,
B01111111,
B01101111, // 9
B00000000}; // blank
// masks:
const byte MA = B00000001;
const byte MB = B00000010;
const byte MC = B00000100;
const byte MD = B00001000;
const byte ME = B00010000;
const byte MF = B00100000;
const byte MG = B01000000;
void draw(byte b) {
for (byte w = 0; w < 10; w++) Serial.println("0 0 0");
byte s = seg7[b];
// segments e + f:
for (byte w = 0; w < w0; w++) {
drawSeg( s & ME, p2-h2);
drawSeg( s & MF, p4-h2);
Serial.println(p0);
drawSeg( s & ME, p2+h2);
drawSeg( s & MF, p4+h2);
Serial.println(p0);
}
// segments d + g + a:
for (byte w = 0; w < w1; w++) {
drawSeg( s & MD, p1-h1);
drawSeg( s & MG, p3-h1);
drawSeg( s & MA, p5-h1);
Serial.println();
drawSeg( s & MD, p1+h1);
drawSeg( s & MG, p3+h1);
drawSeg( s & MA, p5+h1);
Serial.println();
}
// segments c + b:
for (byte w = 0; w < w0; w++) {
drawSeg( s & MC, p2-h2);
drawSeg( s & MB, p4-h2);
Serial.println(p0);
drawSeg( s & MC, p2+h2);
drawSeg( s & MB, p4+h2);
Serial.println(p0);
}
for (byte w = 0; w < 10; w++) Serial.println("0 0 0");
}
void drawSeg(boolean p, int q) {
if (p) Serial.print(q); else Serial.print(p0);
Serial.print("\t");
}