# Interrupt, usare sia FALLING sia CHANGE + tempi micros

**URL:** <https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571>\
**Category:** Software\
**Created:** [August 2, 2025, 10:24am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571 "2025-08-02T10:24:02Z")\
**Posts on this page:** 20\
**Page:** 1

<div class="post-metadata">

**Author:** ![thedrifter](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/thedrifter/32/218430_2.png) [@thedrifter](https://forum.arduino.cc/u/thedrifter)\
**Post date:** [August 2, 2025, 10:24am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/1 "2025-08-02T10:24:02Z")

</div>

Ciao,  
ho usato poche volte gli interrupt, prima di fare vorrei capire se è possibile.  
Utilizzo arduino nano, 2 sensori hall in ingresso che attiveranno i 2 interrupt (non saranno mai sovrapposti).  
La prima cosa che devo fare è vedere il cambio di stato da HI a LOW, quindi FALLING; se possibile poi vorrei anche vedere il successivo cambio da LOW a HI.  
Nel setup del programma faccio questo:

```arduino
attachInterrupt(0, sens1_low, FALLING);
attachInterrupt(1, sens2_low, FALLING);

```

dovrei aggiungere anche questo?

```arduino
attachInterrupt(0, sens1_ch, CHANGE);
attachInterrupt(1, sens2_ch, CHANGE);

```

Grazie per i suggerimenti 🙂

---

<div class="post-metadata">

**Author:** ![J-M-L](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/j-m-l/32/766245_2.png) [@J-M-L](https://forum.arduino.cc/u/J-M-L)\
**Post date:** [August 2, 2025, 11:10am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/2 "2025-08-02T11:10:29Z")

</div>

No, attachInterrupt permette un solo tipo di attivazione per pin alla volta.

La soluzione è probabilmente usare solo CHANGE e, nell'interrupt, rileggere lo stato. Se leggete HIGH, significa che c'è stata una transizione da LOW a HIGH, se leggete LOW, era la transizione opposta.

---

<div class="post-metadata">

**Author:** ![thedrifter](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/thedrifter/32/218430_2.png) [@thedrifter](https://forum.arduino.cc/u/thedrifter)\
**Post date:** [August 2, 2025, 11:55am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/3 "2025-08-02T11:55:54Z")

</div>

proverò allora a fare come hai suggerito, ho tempi un po' stretti, ma provo per vedere cosa succede 🙂  
Grazie

---

<div class="post-metadata">

**Author:** ![thedrifter](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/thedrifter/32/218430_2.png) [@thedrifter](https://forum.arduino.cc/u/thedrifter)\
**Post date:** [August 6, 2025, 1:27pm UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/4 "2025-08-06T13:27:13Z")

</div>

Ciao,  
ho fatto alcune prove, sostanzialmente il programma funziona, noto però una differenza di tempo sullo stato on dell'uscita impulso, alcune volte è più lungo, alcune più stretto, ecco lo sketch:

```arduino
#define hall1 2 // pin ingresso sensore hall 1
#define hall2 3 // pin ingresso sensore hall 2

#define bob1 6 // pin uscita bobina 1
#define bob2 7 // pin uscita bobina 2
#define imp 9 // pin uscita impulsi
#define rele 11 // pin uscita relè

volatile byte giri = 0; // var incrementata da impulsi interrupt

volatile unsigned long t_bobine = 0;
volatile unsigned long t_impulso = 0;

bool rele_off = false; // per sapere se staccare il relè

void setup()
{
  pinMode(hall1, INPUT); // imposta il pin come ingresso
  pinMode(hall2, INPUT);
  pinMode(bob1, OUTPUT); // imposta il pin come uscita
  pinMode(bob2, OUTPUT);
  pinMode(imp, OUTPUT);
  pinMode(rele, OUTPUT);

  digitalWrite(bob1, HIGH); // a riposo, alto perchè c'è tr
  digitalWrite(bob2, HIGH); // a riposo
  digitalWrite(imp, LOW); // porto basso l'impulso
  digitalWrite(rele, HIGH); // eccito il relè

  attachInterrupt(0, sens1, CHANGE); //int pin 2, quando cambia stato
  attachInterrupt(1, sens2, CHANGE); //int pin 3, quando cambia stato
}

void loop()
{

  if (micros() - t_bobine >= 2200) // se passati 2200 uS
  {
    digitalWrite(bob1, HIGH); // disattivo bobine
    digitalWrite(bob2, HIGH);
  }

  if (micros() - t_impulso >= 1000) // se passati 1000 uS
  {
    digitalWrite(imp, LOW); // disattivo impulso per giri
  }

  if (giri >= 15 && rele_off == false)
  { // se supreo 15 giri motore e se non già fatto
    digitalWrite(rele, LOW); // disattivo il relè
    rele_off = true; // flag per non rifare
  }
}

// **************************************************************************************
// **********************funzione per interrupt da sensore 1***************************
void sens1() //Funzione che viene eseguita dall'interrupt
{
  if (digitalRead(hall1) == LOW && rele_off == false); // se hall1 basso
  { // e se non ho finito il tempo di avvio
    digitalWrite(bob1, LOW); // attivo la bobina
    giri++; // incremento variabile giri
    t_bobine = micros(); // azzero tempo
  }
  digitalWrite(imp, HIGH); // impulso per giri
  t_impulso = micros(); // azzero tempo
}
// **************************************************************************************
// **********************funzione per interrupt da sensore 2***************************
void sens2() //Funzione che viene eseguita dall'interrupt
{
  if (digitalRead(hall2) == LOW && rele_off == false); // se hall2 basso
  { // e se non ho finito il tempo di avvio
    digitalWrite(bob2, LOW); // attivo la bobina
    t_bobine = micros(); // azzero tempo
  }
  digitalWrite(imp, HIGH); // impulso per giri
  t_impulso = micros(); // azzero tempo
}
// **************************************************************************************

```

millis() non incrementa nella ISR, ma micros() dovrebbe incrementare, cosa che comunque non dovrebbe essere rilevante per come ho fatto il programma, appena rientro nel loop dopo la ISR dovrei iniziare a contare il tempo, come mai quindi non è sempre lo stesso come dovrebbe essere regolato dall'if nel loop?

Grazie 🙂

---

<div class="post-metadata">

**Author:** ![J-M-L](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/j-m-l/32/766245_2.png) [@J-M-L](https://forum.arduino.cc/u/J-M-L)\
**Post date:** [August 6, 2025, 8:11pm UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/5 "2025-08-06T20:11:17Z")

</div>

Quante interruzioni al secondo avete su questi sensori?

> [@thedrifter](#):
>
> `if (digitalRead(hall1) == LOW && rele_off == false);`

➜ Attenzione al punto e virgola dopo l’if che lo rende inefficace!

---

<div class="post-metadata">

**Author:** ![Salvorhardin](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/salvorhardin/32/469189_2.png) [@Salvorhardin](https://forum.arduino.cc/u/Salvorhardin)\
**Post date:** [August 7, 2025, 4:50am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/6 "2025-08-07T04:50:12Z")

</div>

Curiosità:

Ma è un qualcosa che ha a che fare con avviamento e accensione di un motore Otto?  
Con anche un principio di anticipo?

---

<div class="post-metadata">

**Author:** ![thedrifter](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/thedrifter/32/218430_2.png) [@thedrifter](https://forum.arduino.cc/u/thedrifter)\
**Post date:** [August 7, 2025, 6:21am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/7 "2025-08-07T06:21:00Z")

</div>

Ciao,

dopo ore che controllo il programma, non mi ero accorto del punto e virgola… Grazie, è proprio vero che certe cose non si notano nemmeno se sono evidenti 🫣

Questi sensori mi lavorano a una frequenza di circa 70 Hz, per entrambi, quindi circa 35 Hz per un solo sensore (lavorano in sequenza). Al massimo però possono arrivare a 250 Hz, sempre per entrambi, quindi 125 Hz per singolo sensore.

Per Salvorhardin, sì, è un comando accensione per motore otto, ma solo ad anticipo fisso, il tempo di 2200 uS è per caricare la bobina 😀

Riprovo il tutto con gli if corretti, grazie 😉

---

<div class="post-metadata">

**Author:** ![J-M-L](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/j-m-l/32/766245_2.png) [@J-M-L](https://forum.arduino.cc/u/J-M-L)\
**Post date:** [August 7, 2025, 7:51am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/8 "2025-08-07T07:51:36Z")

</div>

Idealmente bisognerebbe anche avere delle sezioni critiche nel loop in cui si duplicano le variabili volatili usate nelle interruzioni, per evitare accessi concorrenti se un’interruzione avviene mentre si sta elaborando la variabile nel loop.

Se si usassero anche dei bool nei vari if, si eviterebbe di reimpostare continuamente i pin al loro valore predefinito quando il tempo è scaduto

(Da dichiarare anche come volatile e da gestire nella sezione critica)

---

<div class="post-metadata">

**Author:** ![thedrifter](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/thedrifter/32/218430_2.png) [@thedrifter](https://forum.arduino.cc/u/thedrifter)\
**Post date:** [August 7, 2025, 9:43am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/9 "2025-08-07T09:43:38Z")

</div>

Rieccomi,

ho sistemato un po’ il programma, avevo già in mente l’inserimento dei flag per non reimpostare continuamente i pin uscita; però il problema del cambio casuale del tempo di on dell’uscita impulsi resta, ecco il codice aggiornato:

```arduino
#define hall1 2 // pin ingresso sensore hall 1
#define hall2 3 // pin ingresso sensore hall 2

#define bob1 6 // pin uscita bobina 1
#define bob2 7 // pin uscita bobina 2
#define imp 9 // pin uscita impulsi
#define rele 11 // pin uscita relè

volatile byte giri = 0; // var incrementata da impulsi interrupt

volatile unsigned long t_bobine = 0;
volatile unsigned long t_impulso = 0;

volatile bool rele_off = false; // per sapere se staccare il relè
volatile bool bob_off = false; // per sapere se già fatto
volatile bool imp_off = false; // per sapere se già fatto

void setup()
{
  pinMode(hall1, INPUT); // imposta il pin come ingresso
  pinMode(hall2, INPUT);
  pinMode(bob1, OUTPUT); // imposta il pin come uscita
  pinMode(bob2, OUTPUT);
  pinMode(imp, OUTPUT);
  pinMode(rele, OUTPUT);

  digitalWrite(bob1, HIGH); // a riposo, alto perchè c'è tr
  digitalWrite(bob2, HIGH); // a riposo
  digitalWrite(imp, LOW); // porto basso l'impulso
  digitalWrite(rele, HIGH); // eccito il relè

  attachInterrupt(0, sens1, CHANGE); //int pin 2, quando cambia stato
  attachInterrupt(1, sens2, CHANGE); //int pin 3, quando cambia stato
}

void loop()
{

  if (micros() - t_bobine >= 2200 && bob_off == false)
  { // se passati 2200 uS e se non già fatto
    digitalWrite(bob1, HIGH); // disattivo bobine
    digitalWrite(bob2, HIGH);
    bob_off = true; // flag per non rifare
  }

  if (micros() - t_impulso >= 1000 && imp_off == false)
  { // se passati 1000 uS e se non già fatto
    digitalWrite(imp, LOW); // disattivo impulso per giri
    imp_off = true; // flag per non rifare
  }

  if (giri >= 15 && rele_off == false)
  { // se supreo 15 giri motore e se non già fatto
    digitalWrite(rele, LOW); // disattivo il relè
    rele_off = true; // flag per non rifare
  }
}

// **************************************************************************************
// **********************funzione per interrupt da sensore 1***************************
void sens1() //Funzione che viene eseguita dall'interrupt
{
  if (digitalRead(hall1) == LOW && rele_off == false) // se hall1 basso
  { // e se non ho finito il tempo di avvio
    giri++; // incremento variabile giri
    bob_off = false; // flag per if nel loop
    digitalWrite(bob1, LOW); // attivo la bobina
    t_bobine = micros(); // azzero tempo
  }
  digitalWrite(imp, HIGH); // impulso per giri
  imp_off = false; // flag per if nel loop
  t_impulso = micros(); // azzero tempo
}
// **************************************************************************************
// **********************funzione per interrupt da sensore 2***************************
void sens2() //Funzione che viene eseguita dall'interrupt
{
  if (digitalRead(hall2) == LOW && rele_off == false) // se hall2 basso
  { // e se non ho finito il tempo di avvio
    bob_off = false; // flag per if nel loop
    digitalWrite(bob2, LOW); // attivo la bobina
    t_bobine = micros(); // azzero tempo
  }
  digitalWrite(imp, HIGH); // impulso per giri
  imp_off = false; // flag per if nel loop
  t_impulso = micros(); // azzero tempo
}
// **************************************************************************************

```

Il discorso del probabile intervento della ISR mentre nel loop sto lavorando una variabile, dovrebbe essere improbabile per questi tempi, nel caso dovrei disattivare l'interrupt mentre eseguo la parte che interessa le variabili?

---

<div class="post-metadata">

**Author:** ![J-M-L](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/j-m-l/32/766245_2.png) [@J-M-L](https://forum.arduino.cc/u/J-M-L)\
**Post date:** [August 7, 2025, 6:48pm UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/10 "2025-08-07T18:48:48Z")

</div>

Ecco un codice modificato a partire dal vostro. L'ho scritto direttamente qui, quindi non è testato — va verificato che faccia esattamente la stessa cosa.

```arduino
#define hall1 2
#define hall2 3

#define bob1 6
#define bob2 7
#define imp 9
#define rele 11

volatile byte giri = 0;
volatile unsigned long tempoBobine = 0;
volatile unsigned long tempoImpulso = 0;
volatile bool releAttivo = true;
volatile bool bobinaAttiva = true;
volatile bool impulsoAttivo = true;

void setup()
{
  pinMode(hall1, INPUT);
  pinMode(hall2, INPUT);
  pinMode(bob1, OUTPUT);
  pinMode(bob2, OUTPUT);
  pinMode(imp, OUTPUT);
  pinMode(rele, OUTPUT);

  digitalWrite(bob1, HIGH);
  digitalWrite(bob2, HIGH);
  digitalWrite(imp, LOW);
  digitalWrite(rele, HIGH);

  attachInterrupt(digitalPinToInterrupt(hall1), sensore1, CHANGE);
  attachInterrupt(digitalPinToInterrupt(hall2), sensore2, CHANGE);
}

void loop()
{
  unsigned long adesso = micros();

  unsigned long tempoBobineLocale;
  unsigned long tempoImpulsoLocale;
  byte giriLocali;
  bool releAttivoLocale;
  bool bobinaAttivaLocale;
  bool impulsoAttivoLocale;

  noInterrupts();
  tempoBobineLocale = tempoBobine;
  tempoImpulsoLocale = tempoImpulso;
  giriLocali = giri;
  releAttivoLocale = releAttivo;
  bobinaAttivaLocale = bobinaAttiva;
  impulsoAttivoLocale = impulsoAttivo;
  interrupts();

  if (bobinaAttivaLocale && adesso - tempoBobineLocale >= 2200)
  {
    digitalWrite(bob1, HIGH);
    digitalWrite(bob2, HIGH);
    noInterrupts();
    bobinaAttiva = false;
    interrupts();
  }

  if (impulsoAttivoLocale && adesso - tempoImpulsoLocale >= 1000)
  {
    digitalWrite(imp, LOW);
    noInterrupts();
    impulsoAttivo = false;
    interrupts();
  }

  if (releAttivoLocale && giriLocali >= 15)
  {
    digitalWrite(rele, LOW);
    noInterrupts();
    releAttivo = false;
    interrupts();
  }
}

void sensore1()
{
  giri++;
  bobinaAttiva = true;
  digitalWrite(bob1, LOW);
  tempoBobine = tempoImpulso = micros();

  digitalWrite(imp, HIGH);
  impulsoAttivo = true;
}

void sensore2()
{
  bobinaAttiva = true;
  digitalWrite(bob2, LOW);
  tempoBobine = tempoImpulso = micros();

  digitalWrite(imp, HIGH);
  impulsoAttivo = true;
}

```

PS:  
Usare un tipo formale invece di un #define è generalmente meglio oggigiorno. Le macro si tengono soprattutto per la compilazione condizionale, se possibile.

`#define hall1 2` ➜ `constexpr byte hall1 = 2;`

---

<div class="post-metadata">

**Author:** ![thedrifter](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/thedrifter/32/218430_2.png) [@thedrifter](https://forum.arduino.cc/u/thedrifter)\
**Post date:** [August 7, 2025, 7:29pm UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/11 "2025-08-07T19:29:10Z")

</div>

Ciao,

puoi darmi anche del tu, siamo tutti a divertirci 😀

Non era necessario prendessi l’impegno di scrivere il codice, ho capito cos’hai voluto fare… Purtroppo però il comportamento è il solito, ora voglio vedere se riesco a capire qualcosa con l’oscilloscopio, se c’è qualche correlazione con i tempi…

Non ho invece capito cosa vuoi dire con l’ultima frase 😅 provo a fare una ricerca in rete per capire cosa intendi 😉

---

<div class="post-metadata">

**Author:** ![Salvorhardin](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/salvorhardin/32/469189_2.png) [@Salvorhardin](https://forum.arduino.cc/u/Salvorhardin)\
**Post date:** [August 7, 2025, 8:35pm UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/12 "2025-08-07T20:35:01Z")

</div>

Giusto

@J-M-L , mi domando anch'io perché parli in seconda persona plurale  
Si tratta di una cosa desueta e da alcuni mal considerata (ricorda il ventennio)

È una traduzione automatica?

---

<div class="post-metadata">

**Author:** ![J-M-L](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/j-m-l/32/766245_2.png) [@J-M-L](https://forum.arduino.cc/u/J-M-L)\
**Post date:** [August 8, 2025, 4:53am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/13 "2025-08-08T04:53:32Z")

</div>

Dico “voi” in francese perché è la forma di cortesia, e appartengo a una generazione in cui era naturale farlo. Cerco di scrivere in italiano, ma sto ancora imparando, quindi passo poi le mie frasi in un correttore.

Cercherò di passare a “lei”, non ci vedete alcuna adesione agli anni ’30… (Mi sono informato, non conoscevo questo aspetto).

---

<div class="post-metadata">

**Author:** ![J-M-L](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/j-m-l/32/766245_2.png) [@J-M-L](https://forum.arduino.cc/u/J-M-L)\
**Post date:** [August 8, 2025, 5:01am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/14 "2025-08-08T05:01:18Z")

</div>

> [@thedrifter](#):
>
> Non ho invece capito cosa vuoi dire con l’ultima frase

> [@J-M-L](#):
>
> ```arduino
> #define hall1 2
> #define hall2 3
> 
> #define bob1 6
> #define bob2 7
> #define imp 9
> #define rele 11
> 
> ```

➜

```arduino
constexpr byte hall1 = 2;
constexpr byte hall2 = 3;
constexpr byte bob1 = 6;
constexpr byte bob2 = 7;
constexpr byte imp = 9;
constexpr byte rele = 11;

```

constexpr è meglio di #define perché è una costante tipizzata, verificata a compilazione, con rispetto della portata, il che migliora sicurezza e debug. È un po’ come la differenza tra “voi” e “lei”, #define è roba dell’ultimo millennio. (Si usava questo in C quando i compilatori non erano così avanzati come oggi.)

---

<div class="post-metadata">

**Author:** ![gpb01](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/gpb01/32/830685_2.png) [@gpb01](https://forum.arduino.cc/u/gpb01)\
**Post date:** [August 8, 2025, 7:06am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/15 "2025-08-08T07:06:27Z")

</div>

> [@Salvorhardin](#):
>
> mi domando anch'io perché parli in seconda persona plurale

J-M-L **NON** è di lingua madre Italiana e quindi usa una forma che è più simile a quella della SUA lingua madre … 🙂

Guglielmo

---

<div class="post-metadata">

**Author:** ![Salvorhardin](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/salvorhardin/32/469189_2.png) [@Salvorhardin](https://forum.arduino.cc/u/Salvorhardin)\
**Post date:** [August 8, 2025, 10:32am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/16 "2025-08-08T10:32:43Z")

</div>

Grazie

Ma allora ti meriti i complimenti, se scrivi così bene senza che l'italiano sia la tua lingua madre

Bravo

---

<div class="post-metadata">

**Author:** ![Salvorhardin](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/salvorhardin/32/469189_2.png) [@Salvorhardin](https://forum.arduino.cc/u/Salvorhardin)\
**Post date:** [August 8, 2025, 10:36am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/17 "2025-08-08T10:36:13Z")

</div>

> [@J-M-L](#):
>
> #define è roba dell’ultimo millennio

È vero  
Però in C (e non C++) senza le "function like macro" perdi un intero mondo di possibilità

---

<div class="post-metadata">

**Author:** ![Salvorhardin](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/salvorhardin/32/469189_2.png) [@Salvorhardin](https://forum.arduino.cc/u/Salvorhardin)\
**Post date:** [August 8, 2025, 10:40am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/18 "2025-08-08T10:40:16Z")

</div>

> [@gpb01](#):
>
> **NON** è di lingua madre Italiana e quindi usa una forma

Questo lo sapevo, o meglio lo avevo capito,  
Mi domandavo solo la "dinamica" della cosa

---

<div class="post-metadata">

**Author:** ![gpb01](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/gpb01/32/830685_2.png) [@gpb01](https://forum.arduino.cc/u/gpb01)\
**Post date:** [August 8, 2025, 11:11am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/19 "2025-08-08T11:11:26Z")

</div>

> [@Salvorhardin](#):
>
> Mi domandavo solo la "dinamica" della cosa

In francese il Voi è la forma normale, come noi usiamo il Lei 😉

Guglielmo

---

<div class="post-metadata">

**Author:** ![thedrifter](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/thedrifter/32/218430_2.png) [@thedrifter](https://forum.arduino.cc/u/thedrifter)\
**Post date:** [August 8, 2025, 11:22am UTC](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571/21 "2025-08-08T11:22:53Z")

</div>

> [@Salvorhardin](#):
>
> Ma allora ti meriti i complimenti, se scrivi così bene senza che l'italiano sia la tua lingua madre

Volevo dire la stessa cosa, complimenti per come scrivi in italiano 😉

[Next page](https://forum.arduino.cc/t/interrupt-usare-sia-falling-sia-change-tempi-micros/1399571.md?page=2)