Is there a keypad membrane with 4 arrows?

Looked around as I wanted to get a keypad membrane with 4 buttons and I'd like to have arrows so I can stick the membrane on the outside of the project box. The clear box (an old iPod store case) will be able to show LCD but I didn't want to cut hole for buttons if I can find buttons.

All I found were buttons 1-4 and it doesn't look like it'd be easy to wipe the number off. I found one place that had 4 arrows membrane panel but I am not shelling out $20 for that! I could also go with blank ones but I have the drawing skill of an average kindergartner so I'd need to print something out to apply on the blank membrane.

It does not matter if the buttons were arranged in 1x4 or in cross style.

Any idea? Preferably one that ships to USA and doesn't cost a lot (under $10 shipped)

Have you considered an IR remote?

|446x500

Changing my sketch from keypad to remote may not be difficult but 1600 lines of code, lots of variables, there may not be much memory left to add a library. I'd have to check in the morning to see what my sketch uses, and what the library requires.

I wrote a library here for both remotes show. http://forum.arduino.cc/index.php?topic=317625.0

Here is the sketch example for the 17 button remote.
About 2,000 bytes (no tone or Serial) for the library and this sketch:

eBay Remotes

//*****************************************************************************
//17 button IR remote
//NEC - IR code
//By: LarryD 
//
//This sketch demonstrates interfacing to a 17 button IR remote. http://goo.gl/Jk79FM
//These are commonly available on eBay for $2 USD.
//The remote usually comes with a controller. 
//It is an all in one IR detector/amplifier similar to TSOP38238, yours may vary
//**Always confirm the detector/amplifier you have is wired as per YOUR data sheet**
//Remove the detector from the controller for this discussion and wire it to +5V and GND.
//Datasheet for the IR detector: https://www.sparkfun.com/datasheets/Sensors/Infrared/tsop382.pdf
//For wiring, see:               https://learn.sparkfun.com/tutorials/ir-control-kit-hookup-guide
//Interrupt 0 (pin D2) is used to achieve fast receive response.
//See also:                      http://forum.arduino.cc/index.php?topic=289446.msg
//

//**************************************

#include <IRremoteNEC.h>
//We must use an interrupt pin, 2 or 3 on an UNO, Ethernet or ATmega1284
//connect this pin to the IR Receiver Module
//#define interruptPin 3  

#define interruptPin 2 

//confirm the correct interrupt pin has been selected
#if interruptPin != 2 && interruptPin != 3
#error interruptPin must be 2 or 3!
#endif
IRremoteNEC myRemote(interruptPin); //create the object using this pin

//**************************************

#define tonePin 7            //Piezo speaker is connected to this pin

//*****************************************************************************
//17 button Keypad
const byte buttonCode[18] = {
  0x46,0x44,0x40,
  0x43,0x15,0x00, //0X00 is not defined
  0x16,0x19,0x0D,
  0x0C,0x18,0x5E,
  0x08,0x1C,0x5A,
  0x42,0x52,0x4A
}; //END of buttonCode Array

const byte ASCIIcode[18] = {
  // ^    <   New line  
  0x5E,0x3C,0x0A,
  // >    v  nul 
  0x3E,0x76,0x00,
  // 1    2    3 
  0x31,0x32,0x33,
  // 4    5    6 
  0x34,0x35,0x36,
  // 7    8    9 
  0x37,0x38,0x39,
  // *    0    # 
  0x2A,0x30,0x23
}; //END of ASCIIcode Array 

//*****************************************************************************

void setup(void) 
{
  Serial.begin(115200);

  myRemote.beginIR();

} 
//************************** E N D   s e t u p ( ) *****************************

void loop(void) 
{
  //**************************************
  //Check if we have received a valid IR code yet. 
  if(myRemote.getIRflag())
  {
    byte byteRX = myRemote.checkCode();
    //If we get a verified button code, convert it to an ASCII code.
    if(byteRX) 
    {          
      //Scan through the buttonCode Array.
      //NOTE: IR remote repeat codes are not returned.
      for (int i = 0; i < 18; i++) 
      {
        if (buttonCode[i] == byteRX)
        {
          tone(tonePin,3400,100);
          Serial.print(char(ASCIIcode[i])); //get the ASCII code

          //We found it, no need to continue looking.
          break;
        } 
      }
    } // END of if(byteRX)

    //Get ready for the next falling edge.
    myRemote.resetIRflag(); 

  } // END of if(myRemote.getIRflag())
  //**************************************

  // Other loop stuff goes here

}
//************************** E N D   l o o p ( ) *****************************






//=============================================================================
//                             END OF CODE
//=============================================================================

b3d5b9ed12b9f97d4eb06a3956b1faeda1b34fa4.png

I'll try it, I'd need to order the remote and IR receiver.

wilykat: I'll try it, I'd need to order the remote and IR receiver.

Available cheaply as a kit on eBay.

Here they are on eBay. http://www.ebay.com/sch/i.html?_from=R40&_trksid=p2047675.m570.l1313.TR0.TRC0.H0.TRS0&_nkw=HX1838+Infrared+IR+Wireless+Remote+Control+&_sacat=0