Is this coded correctly?

I need some serious help, I know nothing about coding but am trying to use a code someone else made. I've set my board up correctly but cant get this to work. When trying to upload this

/*
  Point Shooter Cyborg Mouse
 Design and Code by Zack Freedman, 2013
 http://zackfreedman.com/projects/pointshooter
 http://voidstarlab.com/diy
 
 Designed for Teensy 3.0
 
 Download i2c_t3 at http://forum.pjrc.com/archive/index.php/t-21680.html
 
 Any original content contained within this source is placed in the public domain.
 WiiChuck.h is public domain, please read its credits too.
 */

#include <math.h>
#include <i2c_t3.h>
#include "WiiChuck.h"

WiiChuck chuck = WiiChuck();

boolean hasOrigin = false;
int pitchOrigin = 0;
int rollOrigin = 0;

void setup() 
{
  pinMode(5, INPUT_PULLUP);
  pinMode(6, INPUT_PULLUP);
  pinMode(7, INPUT_PULLUP);

  //Serial.begin(115200);
  `
  chuck.begin();
  chuck.update();
  
  delay(3000); // So you can program it before it starts acting like a mouse
  
  Mouse.begin();
}


void loop() {
  delay(10);

  if (digitalRead(5) == LOW)
  {
    chuck.update(); 

    if (!hasOrigin)
    {
      for (int i = 0; i < 5; i++)
      {
        pitchOrigin += chuck.readPitch();

        rollOrigin += chuck.readRoll();

        delay(1);
        chuck.update();
      }

      pitchOrigin /= 5;
      rollOrigin /= 5;

/*
      Serial.print("New pitch origin: ");
      Serial.println(pitchOrigin);

      Serial.print("New roll origin: ");
      Serial.println(rollOrigin);
*/

      hasOrigin = true;
    }

    int y = constrain((pitchOrigin - chuck.readPitch()) * 6, -100, 100);
    int x = constrain((chuck.readRoll() - rollOrigin) * 4, -100, 100);

    float magnitude = sqrt(pow(x, 2) + pow(y, 2));
    float direction = atan2(y, x);

    double scale = 0.1; // Increase to make cursor move faster
    int division = 70; // Increase to reduce acceleration effect

    magnitude = scale * (magnitude * magnitude / division);

    x = magnitude * cos(direction);
    y = magnitude * sin(direction);

    /*
    Serial.print(x);
     Serial.print(", ");  
     Serial.println(y);
     */

    Mouse.move(x, y, 0);
  }
  else
  {
    pitchOrigin = 0;
    rollOrigin = 0;

    hasOrigin = false;
  }
  
  if (digitalRead(6) == LOW) Mouse.press(MOUSE_LEFT);
   else Mouse.release(MOUSE_LEFT);
   
   if (digitalRead(7) == LOW) Mouse.press(MOUSE_RIGHT);
   else Mouse.release(MOUSE_RIGHT);
   
}

When I enter that I get: stray '`' in program. I tried deleting it but nothing responds. I'm installing it on a teensy 3.0 the only thing I could of done wrong is install i2c_t3 wrong maybe? I have it and the other file included under my libraries where my arduino software is installed. Any help would be appreciated and if you need more information let me know

Here is the WiiChuck.h code as well

/*
 * Nunchuck -- Use a Wii Nunchuck
 * Tim Hirzel http://www.growdown.com
 * 
 notes on Wii Nunchuck Behavior.
 This library provides an improved derivation of rotation angles from the nunchuck accelerometer data.
 The biggest different over existing libraries (that I know of ) is the full 360 degrees of Roll data
 from teh combination of the x and z axis accelerometer data using the math library atan2. 

 It is accurate with 360 degrees of roll (rotation around axis coming out of the c button, the front of the wii),
 and about 180 degrees of pitch (rotation about the axis coming out of the side of the wii).  (read more below)

 In terms of mapping the wii position to angles, its important to note that while the Nunchuck
 sense Pitch, and Roll, it does not sense Yapw, or the compass direction.  This creates an important
 disparity where the nunchuck only works within one hemisphere.  At a result, when the pitch values are 
 less than about 10, and greater than about 170, the Roll data gets very unstable.  essentially, the roll
 data flips over 180 degrees very quickly.   To understand this property better, rotate the wii around the
 axis of the joystick.  You see the sensor data stays constant (with noise).  Because of this, it cant know
 the difference between arriving upside via 180 degree Roll, or 180 degree pitch.  It just assumes its always
 180 roll.


 * 
 * This file is an adaptation of the code by these authors:
 * Tod E. Kurt, http://todbot.com/blog/
 *
 * The Wii Nunchuck reading code is taken from Windmeadow Labs
 * http://www.windmeadow.com/node/42
 * 
 * Conversion to Arduino 1.0 by Danjovic
 * http://hotbit.blogspot.com 
 * 
 */

#ifndef WiiChuck_h
#define WiiChuck_h


#include "Arduino.h"
#include <i2c_t3.h>
//#include <Wire.h>
#include <math.h>


// these may need to be adjusted for each nunchuck for calibration
#define ZEROX 510  
#define ZEROY 490
#define ZEROZ 460
#define RADIUS 210  // probably pretty universal

#define DEFAULT_ZERO_JOY_X 124
#define DEFAULT_ZERO_JOY_Y 132

class WiiChuck {
    private:
        uint8_t cnt;
        uint8_t status[6];		// array to store wiichuck output
        uint8_t averageCounter;
        //int accelArray[3][AVERAGE_N];  // X,Y,Z
        int i;
        int total;
        uint8_t zeroJoyX;   // these are about where mine are
        uint8_t zeroJoyY; // use calibrateJoy when the stick is at zero to correct
        int lastJoyX;
        int lastJoyY;
        int angles[3];

        bool lastZ, lastC;


    public:

        uint8_t joyX;
        uint8_t joyY;
        bool buttonZ;
        bool buttonC;
        void begin() 
        {
            Wire.begin();
            cnt = 0;
            averageCounter = 0;
            // instead of the common 0x40 -> 0x00 initialization, we
            // use 0xF0 -> 0x55 followed by 0xFB -> 0x00.
            // this lets us use 3rd party nunchucks (like cheap $4 ebay ones)
            // while still letting us use official oness.
            // only side effect is that we no longer need to decode bytes in _nunchuk_decode_byte
            // see http://www.arduino.cc/cgi-bin/yabb2/YaBB.pl?num=1264805255
            //  
            Wire.beginTransmission(0x52);	// device address
            Wire.write(0xF0);
            Wire.write(0x55);
            Wire.endTransmission();
            delay(1);
            Wire.beginTransmission(0x52);
            Wire.write(0xFB);
            Wire.write((uint8_t)0x00);

            Wire.endTransmission();
            update();            
            for (i = 0; i<3;i++) {
                angles[i] = 0;
            }
            zeroJoyX = DEFAULT_ZERO_JOY_X;
            zeroJoyY = DEFAULT_ZERO_JOY_Y;
        }


        void calibrateJoy() {
            zeroJoyX = joyX;
            zeroJoyY = joyY;
        }

        void update() {

            Wire.requestFrom (0x52, 6);	// request data from nunchuck
            while (Wire.available ()) {
                // receive byte as an integer
                status[cnt] = _nunchuk_decode_byte (Wire.read()); //
                cnt++;
            }
            if (cnt > 5) {
                lastZ = buttonZ;
                lastC = buttonC;
                lastJoyX = readJoyX();
                lastJoyY = readJoyY();
                //averageCounter ++;
                //if (averageCounter >= AVERAGE_N)
                //    averageCounter = 0;

                cnt = 0;
                joyX = (status[0]);
                joyY = (status[1]);
                for (i = 0; i < 3; i++) 
                    //accelArray[i][averageCounter] = ((int)status[i+2] << 2) + ((status[5] & (B00000011 << ((i+1)*2) ) >> ((i+1)*2))); 
                    angles[i] = (status[i+2] << 2) + ((status[5] & (B00000011 << ((i+1)*2) ) >> ((i+1)*2))); 

                //accelYArray[averageCounter] = ((int)status[3] << 2) + ((status[5] & B00110000) >> 4); 
                //accelZArray[averageCounter] = ((int)status[4] << 2) + ((status[5] & B11000000) >> 6); 

                buttonZ = !( status[5] & B00000001);
                buttonC = !((status[5] & B00000010) >> 1);
                _send_zero(); // send the request for next bytes

            }
        }


    // UNCOMMENT FOR DEBUGGING
    //byte * getStatus() {
    //    return status;
    //}

    float readAccelX() {
       // total = 0; // accelArray[xyz][averageCounter] * FAST_WEIGHT;
        return (float)angles[0] - ZEROX;
    }
    float readAccelY() {
        // total = 0; // accelArray[xyz][averageCounter] * FAST_WEIGHT;
        return (float)angles[1] - ZEROY;
    }
    float readAccelZ() {
        // total = 0; // accelArray[xyz][averageCounter] * FAST_WEIGHT;
        return (float)angles[2] - ZEROZ;
    }

    bool zPressed() {
        return (buttonZ && ! lastZ);
    }
    bool cPressed() {
        return (buttonC && ! lastC);
    }

    // for using the joystick like a directional button
    bool rightJoy(int thresh=60) {
        return (readJoyX() > thresh and lastJoyX <= thresh);
    }

    // for using the joystick like a directional button
    bool leftJoy(int thresh=60) {
        return (readJoyX() < -thresh and lastJoyX >= -thresh);
    }


    int readJoyX() {
        return (int) joyX - zeroJoyX;
    }

    int readJoyY() {
        return (int)joyY - zeroJoyY;
    }


    // R, the radius, generally hovers around 210 (at least it does with mine)
   // int R() {
   //     return sqrt(readAccelX() * readAccelX() +readAccelY() * readAccelY() + readAccelZ() * readAccelZ());  
   // }


    // returns roll degrees
    int readRoll() {
        return (int)(atan2(readAccelX(),readAccelZ())/ M_PI * 180.0);
        //return (int)(acos(readAccelZ()/RADIUS)/ M_PI * 180.0);
    }

    // returns pitch in degrees
    int readPitch() {        
        return (int) (acos(readAccelY()/RADIUS)/ M_PI * 180.0);  // optionally swap 'RADIUS' for 'R()'
    }

    private:
        uint8_t _nunchuk_decode_byte (uint8_t x)
        {
            //decode is only necessary with certain initializations 
            //x = (x ^ 0x17) + 0x17;
            return x;
        }

        void _send_zero()
        {
            Wire.beginTransmission (0x52);	// transmit to device 0x52
            Wire.write ((uint8_t)0x00);		// sends one byte
            Wire.endTransmission ();	// stop transmitting
        }

};


#endif

When I enter that I get: stray '`' in program.

What, exactly, do you mean by that statement? Where are you "getting" them?