I've compiled your code in post #3 for a ProMicro without problems; there are a couple of warnings.
Did you install the (correct) Joystick library?
Regarding the '18'
C:\Users\sterretje\AppData\Local\Temp\arduino_modified_sketch_86101\sketch_sep21a.ino:15:0: warning: "LIST_MAX" redefined
#define LIST_MAX 18
In file included from C:\Users\sterretje\AppData\Local\Temp\arduino_modified_sketch_86101\sketch_sep21a.ino:7:0:
C:\Users\sterretje\Documents\Arduino\libraries\Keypad\src/Keypad.h:69:0: note: this is the location of the previous definition
#define LIST_MAX 10 // Max number of keys on the active list.
This warning means that LIST_MAX is used in the Keypad library and you can't use it in your program for something else. In your sketch, replace all occurences of LIST_MAX by something else, e.g. MAX_BUTTONS.
#define MAX_BUTTONS 18
[edit]
Note that there are other warnings that you can't ignore; I don't have the time to study that.
C:\Users\sterretje\AppData\Local\Temp\arduino_modified_sketch_805101\sketch_sep21a.ino: In function 'CheckAllButtons()':
C:\Users\sterretje\AppData\Local\Temp\arduino_modified_sketch_805101\sketch_sep21a.ino:116:26: warning: iteration 10 invokes undefined behavior [-Waggressive-loop-optimizations]
if ( buttbx.key[i].stateChanged )
~~~~~~~~~~~~~~^~~~~~~~~~~~
C:\Users\sterretje\AppData\Local\Temp\arduino_modified_sketch_805101\sketch_sep21a.ino:114:23: note: within this loop
for (int i = 0; i < MAX_BUTTONS; i++)
C:\Users\sterretje\AppData\Local\Arduino15\packages\arduino\hardware\avr\1.8.3\cores\arduino\main.cpp: In function 'main':
C:\Users\sterretje\AppData\Local\Temp\arduino_modified_sketch_805101\sketch_sep21a.ino:116:26: warning: iteration 10 invokes undefined behavior [-Waggressive-loop-optimizations]
if ( buttbx.key[i].stateChanged )
^
C:\Users\sterretje\AppData\Local\Temp\arduino_modified_sketch_805101\sketch_sep21a.ino:114:23: note: within this loop
for (int i = 0; i < MAX_BUTTONS; i++)
^
Sketch uses 9004 bytes (31%) of program storage space. Maximum is 28672 bytes.
Global variables use 473 bytes (18%) of dynamic memory, leaving 2087 bytes for local variables. Maximum is 2560 bytes.
[/edit]
Can you please post your code using code tags. The easiest is:
- In the IDE, use tools -> autoformat; this will properly indent your code.
- In the IDE, use edit -> copy for forum; this will place your code (including the code tags) on the clipboard.
- Paste the content of the clipboard in a reply here.
This is your code, properly formatted and with the above fix.
//BUTTON BOX
//USE w ProMicro
//Tested in WIN10 + Assetto Corsa
//AMSTUDIO
//20.8.17
#include <Keypad.h>
#include <Joystick.h>
#define ENABLE_PULLUPS
#define NUMROTARIES 3
#define NUMBUTTONS 18
#define NUMROWS 3
#define NUMCOLS 6
#define MAX_BUTTONS 18
byte buttons[NUMROWS][NUMCOLS] = {
{1, 2, 3, 4, 5, 6},
{7, 8, 9, 10, 11, 12},
{13, 14, 15, 16, 17, 18},
};
struct rotariesdef {
byte pin1;
byte pin2;
int ccwchar;
int cwchar;
volatile unsigned char state;
};
rotariesdef rotaries[NUMROTARIES] {
{0, 1, 19, 20, 0},
{2, 3, 21, 22, 0},
{4, 5, 23, 24, 0},
};
#define DIR_CCW 0x10
#define DIR_CW 0x20
#define R_START 0x0
#ifdef HALF_STEP
#define R_CCW_BEGIN 0x1
#define R_CW_BEGIN 0x2
#define R_START_M 0x3
#define R_CW_BEGIN_M 0x4
#define R_CCW_BEGIN_M 0x5
const unsigned char ttable[6][4] = {
// R_START (00)
{R_START_M, R_CW_BEGIN, R_CCW_BEGIN, R_START},
// R_CCW_BEGIN
{R_START_M | DIR_CCW, R_START, R_CCW_BEGIN, R_START},
// R_CW_BEGIN
{R_START_M | DIR_CW, R_CW_BEGIN, R_START, R_START},
// R_START_M (11)
{R_START_M, R_CCW_BEGIN_M, R_CW_BEGIN_M, R_START},
// R_CW_BEGIN_M
{R_START_M, R_START_M, R_CW_BEGIN_M, R_START | DIR_CW},
// R_CCW_BEGIN_M
{R_START_M, R_CCW_BEGIN_M, R_START_M, R_START | DIR_CCW},
};
#else
#define R_CW_FINAL 0x1
#define R_CW_BEGIN 0x2
#define R_CW_NEXT 0x3
#define R_CCW_BEGIN 0x4
#define R_CCW_FINAL 0x5
#define R_CCW_NEXT 0x6
const unsigned char ttable[7][4] = {
// R_START
{R_START, R_CW_BEGIN, R_CCW_BEGIN, R_START},
// R_CW_FINAL
{R_CW_NEXT, R_START, R_CW_FINAL, R_START | DIR_CW},
// R_CW_BEGIN
{R_CW_NEXT, R_CW_BEGIN, R_START, R_START},
// R_CW_NEXT
{R_CW_NEXT, R_CW_BEGIN, R_CW_FINAL, R_START},
// R_CCW_BEGIN
{R_CCW_NEXT, R_START, R_CCW_BEGIN, R_START},
// R_CCW_FINAL
{R_CCW_NEXT, R_CCW_FINAL, R_START, R_START | DIR_CCW},
// R_CCW_NEXT
{R_CCW_NEXT, R_CCW_FINAL, R_CCW_BEGIN, R_START},
};
#endif
byte rowPins[NUMROWS] = {21, 20, 19};
byte colPins[NUMCOLS] = {14, 16, 10, 9, 8, 7};
Keypad buttbx = Keypad( makeKeymap(buttons), rowPins, colPins, NUMROWS, NUMCOLS);
Joystick_ Joystick(JOYSTICK_DEFAULT_REPORT_ID,
JOYSTICK_TYPE_JOYSTICK, 25, 0,
false, false, false, false, false, false,
false, false, false, false, false);
void setup() {
Joystick.begin();
rotary_init();
}
void loop() {
CheckAllEncoders();
CheckAllButtons();
}
void CheckAllButtons(void) {
if (buttbx.getKeys())
{
for (int i = 0; i < MAX_BUTTONS; i++)
{
if ( buttbx.key[i].stateChanged )
{
switch (buttbx.key[i].kstate) {
case PRESSED:
case HOLD:
Joystick.setButton(buttbx.key[i].kchar, 1);
break;
case RELEASED:
case IDLE:
Joystick.setButton(buttbx.key[i].kchar, 0);
break;
}
}
}
}
}
void rotary_init() {
for (int i = 0; i < NUMROTARIES; i++) {
pinMode(rotaries[i].pin1, INPUT);
pinMode(rotaries[i].pin2, INPUT);
#ifdef ENABLE_PULLUPS
digitalWrite(rotaries[i].pin1, HIGH);
digitalWrite(rotaries[i].pin2, HIGH);
#endif
}
}
unsigned char rotary_process(int _i) {
unsigned char pinstate = (digitalRead(rotaries[_i].pin2) << 1) | digitalRead(rotaries[_i].pin1);
rotaries[_i].state = ttable[rotaries[_i].state & 0xf][pinstate];
return (rotaries[_i].state & 0x30);
}
void CheckAllEncoders(void) {
for (int i = 0; i < NUMROTARIES; i++) {
unsigned char result = rotary_process(i);
if (result == DIR_CCW) {
Joystick.setButton(rotaries[i].ccwchar, 1); delay(50); Joystick.setButton(rotaries[i].ccwchar, 0);
};
if (result == DIR_CW) {
Joystick.setButton(rotaries[i].cwchar, 1); delay(50); Joystick.setButton(rotaries[i].cwchar, 0);
};
}
}