Keyboard.h et antislash

Bonjour à tous, quelqu'un sait il comment afficher un "\" via la librairie keyboard.h,

J'ai également tenté d'afficher un "\" via la librarie : https://www.arduinolibraries.info/libraries/keyboard-azerty-fr

Pour le même résultat

KeyboardAzertyFr.print("\\"); // retourne *
KeyboardAzertyFr.print("\"); // retourne *

Merci pour votre retour

Cordialement

Dans la bibliothèque keyboard.h il doit y avoir une fonction 'press' (je ne l'ai jamais utilisée, j'ai juste regardé le code), essaye de lui donner 92 en argument.

Un tutoriel ici:

Et pour ta réponse avec la librairie standard:

// ---------------------------------------------------
// nico78
// scancode keyboard qwerty et correspondance azerty
// ---------------------------------------------------
//  ' ' est le symbole qui désigne un espace, il a la valeur 44
//  Alt Gr azerty                   €                                                                    ~  #  {  [  |  `  \  ^  @    ' '  ]  }  ¤       
//   Shift azerty       Q  B  C  D  E  F  G  H  I  J  K  L  ?  N  O  P  A  R  S  T  U  V  Z  X  Y  Z  1  2  3  4  5  6  7  8  9  0    ' '  °  +  ¨  £  µ  No fr  M  %  NONE  .  /  §    >
//         azerty       q  b  c  d  e  f  g  h  i  j  k  l  ,  n  o  p  a  r  s  t  u  v  z  x  y  z  &  é  "  '  (  -  è  _  ç  à    ' '  )  =  ^  $  *  No fr  m  ù   ²    ;  :  !    <
//         qwerty       a  b  c  d  e  f  g  h  i  j  k  l  m  n  o  p  q  r  s  t  u  v  w  x  y  z  1  2  3  4  5  6  7  8  9  0    ' '  -  =  [  ]  \  No US  ;  '   `    ,  .  /   No US      
//       scancode       4, 5, 6, 7, 8, 9, 10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36,37,38,39,  44, 45,46,47,48,49,  50,  51,52, 53,  54,55,56,  100}; 

#include <Keyboard.h>

void setup() {
  // put your setup code here, to run once:
  
  Keyboard.begin();
  delay(5000);

  // Pour composer le A majuscule"
  Keyboard.press(KEY_LEFT_SHIFT);
  keyboardScanCode(20); // ou keyboard.print('q');
  Keyboard.release(KEY_LEFT_SHIFT);

  // Pour composer le caractère '\'
  // Alt Gr = Ctrl + Alt
  Keyboard.press(KEY_LEFT_CTRL);
  Keyboard.press(KEY_LEFT_ALT);
  keyboardScanCode(37);
  Keyboard.release(KEY_LEFT_ALT);
  Keyboard.release(KEY_LEFT_CTRL);  
  
  // Pour composer le caractère @
  // Alt Gr = Ctrl + Alt
  Keyboard.press(KEY_LEFT_CTRL);
  Keyboard.press(KEY_LEFT_ALT);
  keyboardScanCode(39); // ou keyboard.print('0');
  Keyboard.release(KEY_LEFT_ALT);
  Keyboard.release(KEY_LEFT_CTRL);  

  // Pour composer le caractère ê
  // nécessite deux séquences de touches, l'appui sur la touche ^ (0x2F)(dead key)
  // puis ensuite la touche e (0x08)
  keyboardScanCode(47);
  keyboardScanCode(8); // ou keyboard.print('e');

  Keyboard.end();
}

void loop() {
  // put your main code here, to run repeatedly:
}

void keyboardScanCode(byte code){
  Keyboard.press(code+136);
  delay(4);
  Keyboard.release(code+136);
  delay(4);
}

Hello, je n'étais pas tombé sur ton tutoriel merci ca fonctionne