Library example not compiling

Hello Everyone,

I am about to get started on a project building a temp controller using a DHT22 sensor and decided to use my Raspberry Pi to run the IDE. I have installed Arduino IDE 1.8.8 for ARM on my PI and then went into the library manager and installed DHT Sensor Library Version 1.3.2. and restarted the IDE. I then opened the DHT tester example and try to compile and get the following error. I have gone back to the library folder for the DHT Sensor and don’t see anything about the <Adafruit_Sensor.h>

What am I doing wrong?

Thanks,

Vince

// Example testing sketch for various DHT humidity/temperature sensors
// Written by ladyada, public domain

// REQUIRES the following Arduino libraries:
// - DHT Sensor Library: https://github.com/adafruit/DHT-sensor-library
// - Adafruit Unified Sensor Lib: https://github.com/adafruit/Adafruit_Sensor

#include "DHT.h"

#define DHTPIN 2     // Digital pin connected to the DHT sensor
// Feather HUZZAH ESP8266 note: use pins 3, 4, 5, 12, 13 or 14 --
// Pin 15 can work but DHT must be disconnected during program upload.

// Uncomment whatever type you're using!
//#define DHTTYPE DHT11   // DHT 11
#define DHTTYPE DHT22   // DHT 22  (AM2302), AM2321
//#define DHTTYPE DHT21   // DHT 21 (AM2301)

// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor

// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors.  This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
  Serial.begin(9600);
  Serial.println(F("DHTxx test!"));

  dht.begin();
}

void loop() {
  // Wait a few seconds between measurements.
  delay(2000);

  // Reading temperature or humidity takes about 250 milliseconds!
  // Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
  float h = dht.readHumidity();
  // Read temperature as Celsius (the default)
  float t = dht.readTemperature();
  // Read temperature as Fahrenheit (isFahrenheit = true)
  float f = dht.readTemperature(true);

  // Check if any reads failed and exit early (to try again).
  if (isnan(h) || isnan(t) || isnan(f)) {
    Serial.println(F("Failed to read from DHT sensor!"));
    return;
  }

  // Compute heat index in Fahrenheit (the default)
  float hif = dht.computeHeatIndex(f, h);
  // Compute heat index in Celsius (isFahreheit = false)
  float hic = dht.computeHeatIndex(t, h, false);

  Serial.print(F("Humidity: "));
  Serial.print(h);
  Serial.print(F("%  Temperature: "));
  Serial.print(t);
  Serial.print(F("°C "));
  Serial.print(f);
  Serial.print(F("°F  Heat index: "));
  Serial.print(hic);
  Serial.print(F("°C "));
  Serial.print(hif);
  Serial.println(F("°F"));
}
Arduino: 1.8.8 (Linux), Board: "Arduino/Genuino Uno"

In file included from /home/pi/Arduino/libraries/DHT_sensor_library/DHT_U.cpp:22:0:
/home/pi/Arduino/libraries/DHT_sensor_library/DHT_U.h:25:29: fatal error: Adafruit_Sensor.h: No such file or directory
 #include <Adafruit_Sensor.h>

                             ^
compilation terminated.
exit status 1
Error compiling for board Arduino/Genuino Uno.

This report would have more information with
"Show verbose output during compilation"
option enabled in File -> Preferences.

Tremolo:
What am I doing wrong?

You didn't carefully read Adafruit's DHT Web Page

This is the third time in the last week I've seen someone asking about this same error.
Would be nice if the library manager checked dependencies.

You need the Adafruit Unified Sensor library.

Thanks, I feel pretty dumb right now after posting I took a short break from it and as soon as I opened the example I saw the two lines about what libraries are required, installed the Unified Sensor Library, tested it and came back to let everyone know i figured it out but you guys beat me to it. It's been a long day of trying to figure out how to install libraries in the first place. Turned out I had the wrong version of the IDE installed and had to figure out how to remove it and install the correct IDE.

Sorry for wasting everybody's time.