Library not found

I was trying a program I found on this site to use a joystick as a mouse, I copied it and replaced some variables, but it always gives me this error message even though I’ve added that library.

Arduino: 1.8.5 (Mac OS X), Board: "Arduino/Genuino Uno"

/Users/filippo/Desktop/prog/Arduino Projects/rgb/rgb.ino: In function 'void setup()':
rgb:54: error: 'Mouse' not found. Does your sketch include the line '#include <Mouse.h>'?
   Mouse.begin();
   ^
/Users/filippo/Desktop/prog/Arduino Projects/rgb/rgb.ino: In function 'void loop()':
rgb:77: error: 'Mouse' not found. Does your sketch include the line '#include <Mouse.h>'?
     Mouse.move(xReading, yReading, 0);
     ^
rgb:84: error: 'Mouse' not found. Does your sketch include the line '#include <Mouse.h>'?
     if (!Mouse.isPressed(MOUSE_LEFT)) {
          ^
rgb:84: error: 'MOUSE_LEFT' was not declared in this scope
     if (!Mouse.isPressed(MOUSE_LEFT)) {
                          ^
rgb:91: error: 'Mouse' not found. Does your sketch include the line '#include <Mouse.h>'?
     if (Mouse.isPressed(MOUSE_LEFT)) {
         ^
rgb:91: error: 'MOUSE_LEFT' was not declared in this scope
     if (Mouse.isPressed(MOUSE_LEFT)) {
                         ^
exit status 1
'Mouse' not found. Does your sketch include the line '#include <Mouse.h>'?

This report would have more information with
"Show verbose output during compilation"
option enabled in File -> Preferences.

and this is the code:

/*
  JoystickMouseControl

  Controls the mouse from a joystick on an Arduino Leonardo, Micro or Due.
  Uses a pushbutton to turn on and off mouse control, and a second pushbutton
  to click the left mouse button.

  Hardware:
  - 2-axis joystick connected to pins A0 and A1
  - pushbuttons connected to pin D2 and D3

  The mouse movement is always relative. This sketch reads two analog inputs
  that range from 0 to 1023 (or less on either end) and translates them into
  ranges of -6 to 6.
  The sketch assumes that the joystick resting values are around the middle of
  the range, but that they vary within a threshold.

  WARNING: When you use the Mouse.move() command, the Arduino takes over your
  mouse! Make sure you have control before you use the command. This sketch
  includes a pushbutton to toggle the mouse control state, so you can turn on
  and off mouse control.

  created 15 Sep 2011
  updated 28 Mar 2012
  by Tom Igoe

  This example code is in the public domain.

  http://www.arduino.cc/en/Tutorial/JoystickMouseControl
*/

#include <Mouse.h>

// set pin numbers for switch, joystick axes, and LED:
const int switchPin = 2;      // switch to turn on and off mouse control
const int mouseButton = 7;    // input pin for the mouse pushButton
const int xAxis = A5;         // joystick X axis
const int yAxis = A4;         // joystick Y axis
const int ledPin = 5;         // Mouse control LED

// parameters for reading the joystick:
int range = 12;               // output range of X or Y movement
int responseDelay = 5;        // response delay of the mouse, in ms
int threshold = range / 4;    // resting threshold
int center = range / 2;       // resting position value

boolean mouseIsActive = false;    // whether or not to control the mouse
int lastSwitchState = LOW;        // previous switch state

void setup() {
  pinMode(switchPin, INPUT);       // the switch pin
  pinMode(ledPin, OUTPUT);         // the LED pin
  // take control of the mouse:
  Mouse.begin();
}

void loop() {
  // read the switch:
  int switchState = digitalRead(switchPin);
  // if it's changed and it's high, toggle the mouse state:
  if (switchState != lastSwitchState) {
    if (switchState == HIGH) {
      mouseIsActive = !mouseIsActive;
      // turn on LED to indicate mouse state:
      digitalWrite(ledPin, mouseIsActive);
    }
  }
  // save switch state for next comparison:
  lastSwitchState = switchState;

  // read and scale the two axes:
  int xReading = readAxis(A0);
  int yReading = readAxis(A1);

  // if the mouse control state is active, move the mouse:
  if (mouseIsActive) {
    Mouse.move(xReading, yReading, 0);
  }

  // read the mouse button and click or not click:
  // if the mouse button is pressed:
  if (digitalRead(mouseButton) == HIGH) {
    // if the mouse is not pressed, press it:
    if (!Mouse.isPressed(MOUSE_LEFT)) {
      Mouse.press(MOUSE_LEFT);
    }
  }
  // else the mouse button is not pressed:
  else {
    // if the mouse is pressed, release it:
    if (Mouse.isPressed(MOUSE_LEFT)) {
      Mouse.release(MOUSE_LEFT);
    }
  }

  delay(responseDelay);
}

/*
  reads an axis (0 or 1 for x or y) and scales the analog input range to a range
  from 0 to <range>
*/

int readAxis(int thisAxis) {
  // read the analog input:
  int reading = analogRead(thisAxis);

  // map the reading from the analog input range to the output range:
  reading = map(reading, 0, 1023, 0, range);

  // if the output reading is outside from the rest position threshold, use it:
  int distance = reading - center;

  if (abs(distance) < threshold) {
    distance = 0;
  }

  // return the distance for this axis:
  return distance;
}

What do you think this means at the start of your second code

Controls the mouse from a joystick [color=red]on an Arduino Leonardo, Micro or Due.[/color]

What kind of arduino do you have? (i know the answer because in the first error I see Arduino: 1.8.5 (Mac OS X),[color=blue] Board: "Arduino/Genuino Uno[/color]")

So....