ohne Gewährleistung und Garantie (ungetestet, aber weils schon fertig ist ...)
/*
Statemaschine with Debounce Button
Each time the input pin goes from LOW to HIGH (e.g. because of a push-button
press), the state will be incremented
The circuit:
- two relais attached to the definied PINs
- pushbutton attached from pin 2 to +5V
- 10 kilohm resistor attached from pin 2 to ground
- Note: On most Arduino boards, there is already an LED on the board connected
to pin 13, so you don't need any extra components for this example.
This example code is based on the "Debounce" Example of the Arduino IDE http://www.arduino.cc/en/Tutorial/Debounce
*/
// constants won't change. They're used here to set pin numbers:
const int buttonPin = 2; // the number of the pushbutton pin
const int relayPin1 = 13; // the number of the first relay PIN
const int relayPin2 = 14;
// using a enum helps us to avoid "magic numbers" in the source
enum {
WAITING,
CLOCKWISE,
PAUSE,
COUNTER_CLOCKWISE,
TOTAL_NO_OF_STATES
};
// Variables will change:
byte currentState = 0; // the current state of the output pin
int buttonState; // the current reading from the input pin
int lastButtonState = LOW; // the previous reading from the input pin
// the following variables are unsigned longs because the time, measured in
// milliseconds, will quickly become a bigger number than can be stored in an int.
unsigned long lastDebounceTime = 0; // the last time the output pin was toggled
unsigned long debounceDelay = 50; // the debounce time; increase if the output flickers
void setup() {
pinMode(buttonPin, INPUT);
pinMode(relayPin1, OUTPUT);
pinMode(relayPin2, OUTPUT);
// set initial LED state
digitalWrite(relayPin1, false);
digitalWrite(relayPin2, false);
}
void loop() {
// read the state of the switch into a local variable:
int reading = digitalRead(buttonPin);
// check to see if you just pressed the button
// (i.e. the input went from LOW to HIGH), and you've waited long enough
// since the last press to ignore any noise:
// If the switch changed, due to noise or pressing:
if (reading != lastButtonState) {
// reset the debouncing timer
lastDebounceTime = millis();
}
if ((millis() - lastDebounceTime) > debounceDelay) {
// whatever the reading is at, it's been there for longer than the debounce
// delay, so take it as the actual current state:
// if the button state has changed:
if (reading != buttonState) {
buttonState = reading;
// increment the state if the new button state is HIGH
if (buttonState == HIGH) {
currentState++;
if (currentState >= TOTAL_NO_OF_STATES) currentState = WAITING;
//quick'n'dirty react on state change
switch (currentState)
{
case WAITING:
case PAUSE:
digitalWrite(relayPin1, false);
digitalWrite(relayPin2, false);
break;
case CLOCKWISE:
digitalWrite(relayPin1, true);
digitalWrite(relayPin2, false);
break;
case COUNTER_CLOCKWISE:
digitalWrite(relayPin1, false);
digitalWrite(relayPin2, true);
break;
}
}
}
}
// save the reading. Next time through the loop, it'll be the lastButtonState:
lastButtonState = reading;
// do what ever else you want to do ;-)
// ...
}