Making led blink with simple maths equation

Projects Programming
1

Hi guys. I'm trying to input some simple maths equation (for example: 3*2) into the serial monitor to make my led blink the amount of times equal to that equation answer however, it only blinks correctly when I input a number or a sum. How can I make so that any simple maths equation works?

It has to use the cycle for() because it is for university and my teacher is asking me to do with it.

Here's my code

int i, pin1=13;
void setup()
{
  pinMode(pin1, OUTPUT);
  Serial.begin(9600);
 
  
}

void loop()
{
  {
   int x = Serial.parseInt();
   for (i=0; i<x;i++)
   {
    digitalWrite(13, HIGH);
    delay(200);
    digitalWrite(13, LOW);
    delay(200);
   }
  }
}
[code]
2

I made this code for Help on arduino calculator project.

const byte maxMsgLen = 64;
const byte cbLF = 10;
const byte cbCR = 13;
const byte cbBlank = ' ';

const char ops[] = "+-*/";

void setup() {
  Serial.begin(250000);
  Serial.println(F("Enter simple expressions like '84 / 2'"));
}

void loop() {
  handleSerial();
}

void oneLineReceived(const char * buffer) {
  int32_t arg1, arg2;
  char op;
  int count = sscanf(buffer, "%ld%c%ld", &arg1, &op, &arg2);
  if (count != 3) {
    Serial.print(buffer);
    Serial.println(F(" - bad expression format"));
  } else {
    char* ptr = strchr(ops, op);
    if (ptr == nullptr) {
      Serial.print(buffer);
      Serial.println(F(" - operator not supported"));
    } else {
      int32_t result = 0;
      switch (op) {
        case '+':
          result = arg1 + arg2;
          break;
        case '-':
          result = arg1 - arg2;
          break;
        case '*':
          result = arg1 * arg2;
          break;
        case '/':
          result = arg1 / arg2;
          break;
      }
      Serial.print(arg1);
      Serial.write(' ');
      Serial.write(op);
      Serial.write(' ');
      Serial.print(arg2);
      Serial.print(F(" = "));
      Serial.print(result);
      Serial.println();
    }
  }
}

void handleSerial() {
  static uint8_t bIndex;
  static uint8_t buffer[maxMsgLen + 1];
  bool lineReady = false;
  if (Serial.available()) {
    uint8_t inChar = Serial.read();
    if (inChar != cbLF && inChar != cbBlank) {
      if (inChar == cbCR) {
        lineReady = true;
      } else {
        buffer[bIndex++] = inChar;
        lineReady = (bIndex == maxMsgLen);
      }
      if (lineReady) {
        buffer[bIndex] = 0;
        oneLineReceived((const char*)buffer);
        bIndex = 0;
      }
    }
  }
}
1 Like
3

Thanks for replying but I think that's not what I need. It's too complicated for my needs and I didn't even learn most of the things in the code. I think you must've read the post wrong.

4

Tortels:
It's too complicated for my needs and I didn't even learn most of the things in the code.

It's pretty basic code, you could lookup each function to learn it,
which you should if this is homework anyway.

I doubt that you can implement "that any simple maths equation works" with less or simpler code.

Reading a full line and interpreting it is a very easy and robust method for serial input.
It does not block, so you could easily integrate it in the 'blink without delay' example.

1 Like