# Mehrere Servos mit Taster

**URL:** <https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415>\
**Category:** Deutsch\
**Created:** [August 15, 2025, 10:21am UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415 "2025-08-15T10:21:38Z")\
**Posts on this page:** 20\
**Page:** 1

<div class="post-metadata">

**Author:** ![andy-anfaenger](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/andy-anfaenger/32/1126549_2.png) [@andy-anfaenger](https://forum.arduino.cc/u/andy-anfaenger)\
**Post date:** [August 15, 2025, 10:21am UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/1 "2025-08-15T10:21:38Z")

</div>

Hallo zusammen,

wie mein Username schon sagt bin ich absoluter Anfänger. Bitte schlagt mich nicht 😂  
Nun zu meiner Frage:

Ich möchte das 4 Servos mit einem Tastendruck sich nacheinander bewegen und dann stoppen. Also das Programm nicht wieder von vorne startet, sondern erst wenn ich wieder auf den Knopf drücke.

Drücke auf den Taster….Servo1 dreht sich 180 Grad und geht wieder auf null zurück….Pause 10 Sekunden …..Servo 2 das selbe….Servo 3 das selbe…Servo 4 dreht sich 180Grad zurück auf Null 2 mal….und stop

Gibt es schon so einen Sketch? Oder kann mir jemand erklären wie ich das hinbekommen kann?

Wäre euch echt dankbar 😉

---

<div class="post-metadata">

**Author:** ![Rentner](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/rentner/32/601027_2.png) [@Rentner](https://forum.arduino.cc/u/Rentner)\
**Post date:** [August 15, 2025, 10:40am UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/2 "2025-08-15T10:40:05Z")

</div>

Hallo,  
das machst Du am besten mit einer Schrittkette, Ablaufsteuerung, Statemaschine. Das sind alles Begriffe für das Gleiche. Du kannst z.B hier im Forum danach suchen , es gibt unzählige Beispiele.  
Im einfachsten Fall geht das sicher auch mit delay() und einer if Abfrage "Taster gedrückt"

---

<div class="post-metadata">

**Author:** ![my\_xy\_projekt](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/my_xy_projekt/32/810062_2.png) [@my\_xy\_projekt](https://forum.arduino.cc/u/my_xy_projekt)\
**Post date:** [August 15, 2025, 11:11am UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/3 "2025-08-15T11:11:50Z")

</div>

> [@andy-anfaenger](#):
>
> kann mir jemand erklären wie ich das hinbekommen kann?

Ja.  
Gerade gebaut und nicht direkt für Servos, das Ergebnis ist aber das selbe:

> [@Schaltung auf Arduino umstellen](https://forum.arduino.cc/t/schaltung-auf-arduino-umstellen/1400671/57):
>
> // Forensketch "Feuerwehrhaus" // https://forum.arduino.cc/ #define relais // Wenn aktiv: Antriebe mit Relaisschaltung, sonst H-Brücke #include \<Streaming.h\> // https://github.com/janelia-arduino/Streaming enum class DOORDIR {STP, UP, DWN, OPN, CLS}; // STOP, gehe AUF, gehe ZU, ist AUF, ist ZU enum class CARDIR {STP, FWD, BWD, OUT, IN}; // STOP, fahre raus, fahre rein, ist draussen, ist drinnen struct DOOR // Was alles zum Hallentor gehört { const uint8\_t enaP…

Da Du keine Endschalter brauchst, ist nur das Steppen durch die Schrittkette und die Pausen interessant.

Gebaut werden kann das unterschiedlich - was bleibt, ist Deine Schrittkette.

Mal kurz zusammengebaut.  
Ist eigentlich selbsterklärend.

```arduino
// Forensketch
// https://forum.arduino.cc/

#include <Streaming.h> // https://github.com/janelia-arduino/Streaming
#include <Servo.h>

Servo servoOne;
Servo servoTwo;
Servo servoThree;
Servo servoFour;

constexpr uint8_t sNums {4};
Servo myServo[sNums] = {servoOne, servoTwo, servoThree, servoFour};
constexpr uint8_t servoPin[sNums] {9, 10, 11, 12}; // angeschlossene Servo Pins

constexpr uint8_t tasterPin {2};

uint8_t schritt = 0;;
uint32_t stepStart; // Merker für Start
uint32_t stepTime; // Laufzeit des jeweiligen Step

void setup()
{
  Serial.begin(115200);
  delay(300);
  Serial << (F("\r\nStart...\r\n")) << endl;

  for (byte b = 0; b < sNums; b++) // zählt durch alle Servos
  { myServo[b].attach(servoPin[b]); } // Zuweisung der Pins

  pinMode(tasterPin, INPUT_PULLUP); // Taste schaltet nach GND
  pinMode(LED_BUILTIN, OUTPUT); // Kontrollleuchte
}

void loop()

{
  schrittKette(); // Abaufsteuerung
  heartBeat(500); // lässt die onBoardLed blinken
}

void setServo(const uint8_t sNum, const uint8_t winkel, const uint32_t myTime)
{
  Serial << F("Servo: ") << sNum + 1 << F(" Winkel: ") << winkel << "°" << F(" mit Laufzeit: ") << myTime << "ms" << endl;
  myServo[sNum].write(winkel);
  stepStart = millis();
  stepTime = myTime;
}

bool timeIsEnd()
{
  if (millis() - stepStart >= stepTime)
  {
    Serial << F("Schrittzeit abgelaufen") << endl;
    return 1;
  }

  return 0;
}

void schrittKette()
{
  switch (schritt)
  {
    case 0: // Warten auf Tastendruck
      if (!digitalRead(tasterPin)) // Taste ausgelöst
      {
        setServo(0, 180, 100); // Servonummer, Winkelstellung, Haltezeit
        schritt++; // nächster Schritt
      }

      break;

    case 1:
      if (timeIsEnd())
      {
        setServo(0, 0, 10000);
        schritt++; // nächster Schritt
      }

      break;

    case 2:
      if (timeIsEnd())
      {
        setServo(1, 180, 100);
        schritt++; // nächster Schritt
      }

      break;

    case 3:
      if (timeIsEnd())
      {
        setServo(1, 0, 10000);
        schritt++; // nächster Schritt
      }

      break;

    case 4:
      if (timeIsEnd())
      {
        setServo(2, 180, 100);
        schritt++; // nächster Schritt
      }

      break;

    case 5:
      if (timeIsEnd())
      {
        setServo(2, 0, 10000);
        schritt++; // nächster Schritt
      }

      break;

    case 6:
      if (timeIsEnd())
      {
        setServo(3, 180, 100);
        schritt++; // nächster Schritt
      }

      break;

    case 7:
      if (timeIsEnd())
      {
        setServo(3, 0, 100);
        schritt++; // nächster Schritt
      }

      break;

    case 8:
      if (timeIsEnd())
      {
        setServo(3, 180, 100);
        schritt++; // nächster Schritt
      }

      break;

    case 9:
      if (timeIsEnd())
      {
        setServo(3, 0, 100);
        schritt++; // nächster Schritt
      }

      break;

    case 10:
      if (digitalRead(tasterPin))
      {
        schritt = 0;
      }

      break;
  }
}

void heartBeat(const uint32_t switchTime)
{
  static uint32_t lastTik = 0;

  if (millis() - lastTik >= switchTime)
  {
    digitalWrite(LED_BUILTIN, !digitalRead(LED_BUILTIN));
    lastTik = millis();
  }
}

```

---

<div class="post-metadata">

**Author:** ![andy-anfaenger](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/andy-anfaenger/32/1126549_2.png) [@andy-anfaenger](https://forum.arduino.cc/u/andy-anfaenger)\
**Post date:** [August 15, 2025, 2:06pm UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/4 "2025-08-15T14:06:41Z")

</div>

Hey wow danke. Muss ich später gleich mal ausprobieren

---

<div class="post-metadata">

**Author:** ![my\_xy\_projekt](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/my_xy_projekt/32/810062_2.png) [@my\_xy\_projekt](https://forum.arduino.cc/u/my_xy_projekt)\
**Post date:** [August 15, 2025, 2:09pm UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/5 "2025-08-15T14:09:58Z")

</div>

Ist nicht schön, sollte aber funktionieren.

Achtung: Ich habe für die Bewegung des Servo 100ms eingeplant. Wenn die nicht reicht, dann musst Du probieren. Wie und wo sollte aus den Kommentaren ersichtlich sein 😉

---

<div class="post-metadata">

**Author:** ![ec2021](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/ec2021/32/997272_2.png) [@ec2021](https://forum.arduino.cc/u/ec2021)\
**Post date:** [August 15, 2025, 4:26pm UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/6 "2025-08-15T16:26:30Z")

</div>

Moin @my_xy_projekt ,

habe mir erlaubt, Deinen Sketch bei Wowki einzustellen:  
[https://wokwi.com/projects/439369305035539457](https://wokwi.com/projects/439369305035539457)

und einige wenige Anpassungen einzufügen, die das Testen möglicherweise vereinfachen können;

- Konstante shortWaitTime und longWaitTime eingeführt
- shortWaitTime von 100 auf 500 ms hochgesetzt, damit die Zeit für die Servos genügt
- Grüne Led eingeführt, die anzeigt, wann der Tastendruck (wieder) akzeptiert wird

Die 100 ms waren für die Wokwi-Servos zu kurz, daher 500 ms.

```arduino
/*
  Forum: https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/4
  Wokwi: https://wokwi.com/projects/439369305035539457

  2025/08/15
  Sketch von my_xy_projekt
  umgesetzt und (nur leicht) angepasst durch ec2021

  - Konstante shortWaitTime und longWaitTime eingeführt
  - shortWaitTime von 100 auf 500 ms hochgesetzt, damit die Zeit für die Servos genügt
  - Grüne Led eingeführt, die anzeigt, wann der Tastendruck (wieder) akzeptiert wird

*/
// Forensketch
// https://forum.arduino.cc/

#include <Streaming.h> // https://github.com/janelia-arduino/Streaming
#include <Servo.h>

Servo servoOne;
Servo servoTwo;
Servo servoThree;
Servo servoFour;

constexpr uint8_t ledPin {3};
constexpr uint32_t shortWaitTime {500};
constexpr uint32_t longWaitTime {10000};
constexpr uint8_t sNums {4};
Servo myServo[sNums] = {servoOne, servoTwo, servoThree, servoFour};
constexpr uint8_t servoPin[sNums] {9, 10, 11, 12}; // angeschlossene Servo Pins

constexpr uint8_t tasterPin {2};

uint8_t schritt = 0;;
uint32_t stepStart; // Merker für Start
uint32_t stepTime; // Laufzeit des jeweiligen Step

void setup()
{
  Serial.begin(115200);
  delay(300);
  Serial << (F("\r\nStart...\r\n")) << endl;

  for (byte b = 0; b < sNums; b++) // zählt durch alle Servos
  {
    myServo[b].attach(servoPin[b]); // Zuweisung der Pins
  }

  pinMode(tasterPin, INPUT_PULLUP); // Taste schaltet nach GND
  pinMode(LED_BUILTIN, OUTPUT); // Kontrollleuchte
  pinMode(ledPin, OUTPUT);
  digitalWrite(ledPin, HIGH);
}

void loop()

{
  schrittKette(); // Abaufsteuerung
  heartBeat(500); // lässt die onBoardLed blinken
}

void setServo(const uint8_t sNum, const uint8_t winkel, const uint32_t myTime)
{
  Serial << F("Servo: ") << sNum + 1 << F(" Winkel: ") << winkel << "°" << F(" mit Laufzeit: ") << myTime << "ms" << endl;
  myServo[sNum].write(winkel);
  stepStart = millis();
  stepTime = myTime;
}

bool timeIsEnd()
{
  if (millis() - stepStart >= stepTime)
  {
    Serial << F("Schrittzeit abgelaufen") << endl;
    return 1;
  }

  return 0;
}

void schrittKette()
{
  switch (schritt)
  {
    case 0: // Warten auf Tastendruck
      if (!digitalRead(tasterPin)) // Taste ausgelöst
      {
        digitalWrite(ledPin, LOW);
        setServo(0, 180, shortWaitTime); // Servonummer, Winkelstellung, Haltezeit
        schritt++; // nächster Schritt
      }
      break;

    case 1:
      if (timeIsEnd())
      {
        setServo(0, 0, longWaitTime);
        schritt++; // nächster Schritt
      }

      break;

    case 2:
      if (timeIsEnd())
      {
        setServo(1, 180, shortWaitTime);
        schritt++; // nächster Schritt
      }

      break;

    case 3:
      if (timeIsEnd())
      {
        setServo(1, 0, longWaitTime);
        schritt++; // nächster Schritt
      }

      break;

    case 4:
      if (timeIsEnd())
      {
        setServo(2, 180, shortWaitTime);
        schritt++; // nächster Schritt
      }

      break;

    case 5:
      if (timeIsEnd())
      {
        setServo(2, 0, longWaitTime);
        schritt++; // nächster Schritt
      }

      break;

    case 6:
      if (timeIsEnd())
      {
        setServo(3, 180, shortWaitTime);
        schritt++; // nächster Schritt
      }

      break;

    case 7:
      if (timeIsEnd())
      {
        setServo(3, 0, longWaitTime);
        schritt++; // nächster Schritt
      }

      break;

    case 8:
      if (timeIsEnd())
      {
        setServo(3, 180, shortWaitTime);
        schritt++; // nächster Schritt
      }

      break;

    case 9:
      if (timeIsEnd())
      {
        setServo(3, 0, longWaitTime);
        schritt++; // nächster Schritt
      }

      break;

    case 10:
      if (digitalRead(tasterPin))
      {
        schritt = 0;
        digitalWrite(ledPin, HIGH);
      }

      break;
  }
}

void heartBeat(const uint32_t switchTime)
{
  static uint32_t lastTik = 0;

  if (millis() - lastTik >= switchTime)
  {
    digitalWrite(LED_BUILTIN, !digitalRead(LED_BUILTIN));
    lastTik = millis();
  }
}

```

Hoffe, dass es Dir gut geht!  
Grüße  
ec2021

@andy-anfaenger : Und Dir natürlich viel Spaß mit der Arduino-Technik! Falls Du Wokwi noch nicht kanntest, ist das möglicherweise für Dich auch eine hervorragende Möglichkeit, Dich mit der Anwendung verschiedener Sensoren und Aktuatoren auseinanderzusetzen, ohne vorher stecken oder löten zu müssen ... 😉

---

<div class="post-metadata">

**Author:** ![my\_xy\_projekt](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/my_xy_projekt/32/810062_2.png) [@my\_xy\_projekt](https://forum.arduino.cc/u/my_xy_projekt)\
**Post date:** [August 15, 2025, 4:41pm UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/7 "2025-08-15T16:41:08Z")

</div>

> [@ec2021](#):
>
> Konstante shortWaitTime und longWaitTime eingeführt

Hatte ich extra noch nicht gebaut, weil wenn die Timings noch angepasst werden, lohnt sich vielleicht ein struct und sowohl timing als auch status dann mit einer Funktion abhandeln.

> [@ec2021](#):
>
> Hoffe, dass es Dir gut geht!

Ich lebe und brauch noch keinen Rollator. 🙂

---

<div class="post-metadata">

**Author:** ![andy-anfaenger](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/andy-anfaenger/32/1126549_2.png) [@andy-anfaenger](https://forum.arduino.cc/u/andy-anfaenger)\
**Post date:** [August 16, 2025, 6:57am UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/8 "2025-08-16T06:57:46Z")

</div>

Ich kenne überhaupt noch nicht viel von dem ganzen, aber ich finde es so faszinierend was man damit alles machen kann und deshalb möchte ich das ganze lernen. Bin für jeden Tipp dankbar.

---

<div class="post-metadata">

**Author:** ![my\_xy\_projekt](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/my_xy_projekt/32/810062_2.png) [@my\_xy\_projekt](https://forum.arduino.cc/u/my_xy_projekt)\
**Post date:** [August 16, 2025, 10:43am UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/9 "2025-08-16T10:43:40Z")

</div>

> [@andy-anfaenger](#):
>
> Bin für jeden Tipp dankbar.

Den Code schon getestet?  
Brauchst Du noch was zusätzlich?

Und dann Lektüre, die relativ einfach geschrieben ist. Bis zur Hälfte sind es Grundlagen. Nur durchlesen. Wenn Du weist, was drin steht, kannste später nachschlagen 🙂

> **[ArduinoForum.de - Das deutschsprachige Forum rund um den Arduino - Arduino...](https://www.arduinoforum.de/referenz.php)**

---

<div class="post-metadata">

**Author:** ![ec2021](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/ec2021/32/997272_2.png) [@ec2021](https://forum.arduino.cc/u/ec2021)\
**Post date:** [August 16, 2025, 11:07am UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/10 "2025-08-16T11:07:13Z")

</div>

Die Faszination für die technischen Möglichkeiten der Mikrocontroller-Welt, die heute nahezu jedem zugänglich ist, ist sicher ein wesentliche Motivation für viele hier im Forum!

Nun kommt es noch darauf an, mit welchen Vorkenntnissen und Erfahrungen man startet:

- Programmiersprachen?
- Elektronik-Kenntnisse ?

Das Internet bietet reichlich Tutorials, um sich Grundlagen zu erarbeiten.

Man sollte aber berücksichtigen, dass die allermeisten Beispiele tatsächlich nur die grundsätzliche Handhabung aufzeigen und eher selten zur Lösung realer Anwendungen taugen.

Das ist vergleichbar mit dem ersten Schulbuch im Deutschunterricht. Man lernt korrektes Schreiben, den Aufbau von Sätzen und die ersten Regeln der Zeichensetzung. Für das Erstellen eines Aufsatzes reicht es jedoch kaum.

Um über das Niveau der Beispiele hinaus zu kommen, lohnt sich i.d.R. ein Buch zum Erlernen der Programmiersprache C++.

Ich empfehle ein "analoges" Buch, weil man sich damit auch ohne Ablenkung durch eine verführerische Tastatur Zusammenhänge erarbeiten kann.

Zusätzlich findet man mit ein wenig Suche gerade hier im Forum gute Tutorials, die über die absoluten Basics hinaus gehen.

Gruß  
ec2021

---

<div class="post-metadata">

**Author:** ![Tommy56](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/tommy56/32/232943_2.png) [@Tommy56](https://forum.arduino.cc/u/Tommy56)\
**Post date:** [August 16, 2025, 11:30am UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/11 "2025-08-16T11:30:04Z")

</div>

Aktuell für 11,99€ im Angebot [Breymann C++-Programmieren](https://www.terrashop.de/Buch/C-programmieren-Ulrich-Breymann-ISBN-3446463860/art/44646386/). Ursprünglich 40€.  
Als Buch mit PDF (gut zum Suchen)

Gruß Tommy

---

<div class="post-metadata">

**Author:** ![andy-anfaenger](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/andy-anfaenger/32/1126549_2.png) [@andy-anfaenger](https://forum.arduino.cc/u/andy-anfaenger)\
**Post date:** [August 16, 2025, 3:18pm UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/12 "2025-08-16T15:18:33Z")

</div>

@ec2021 wenn ich ehrlich bin hab ich von beidem nicht viel Ahnung.  
Elektrik ein bisschen vom Modellbau, aber programmieren absolut nichts.  
Man kann ja aber versuchen es zu lernen.

Gruß Andi

---

<div class="post-metadata">

**Author:** ![andy-anfaenger](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/andy-anfaenger/32/1126549_2.png) [@andy-anfaenger](https://forum.arduino.cc/u/andy-anfaenger)\
**Post date:** [August 16, 2025, 3:22pm UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/13 "2025-08-16T15:22:27Z")

</div>

@Tommy56 Danke dir. Hab ich bestellt 😉

Gruß Andi

---

<div class="post-metadata">

**Author:** ![Tommy56](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/tommy56/32/232943_2.png) [@Tommy56](https://forum.arduino.cc/u/Tommy56)\
**Post date:** [August 16, 2025, 3:24pm UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/14 "2025-08-16T15:24:59Z")

</div>

Du hast ja einiges an Lesematerial vorgeschlagen bekommen. AIch die IDE bringt viele Beispiele mit. Fange klein an. Taster einlesen, LED zum leichten bringen, 2 LED mit unterschiedlicher Geschwindigkeit blinken lassen, ...  
Wenn Du diese Grundlagen verinnerlicht hast, kannst Du an die Servos gehen.  
Dazu sind dann die MoBaTools zu empfehlen, da sie gut dokumentiert sind.

Gruß Tommy

---

<div class="post-metadata">

**Author:** ![andy-anfaenger](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/andy-anfaenger/32/1126549_2.png) [@andy-anfaenger](https://forum.arduino.cc/u/andy-anfaenger)\
**Post date:** [August 16, 2025, 3:29pm UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/15 "2025-08-16T15:29:30Z")

</div>

@my_xy_projekt erstmal Danke für deine Hilfe.  
Hab mir das ganze etwas leichter vorgestellt, aber aller Anfang ist schwer.  
Um ehrlich zu sein qualmt mir gerade der Kopf.  
Bin noch nicht dazu gekommen deinen Code auszuprobieren. Denke am Montag hab ich Zeit.  
Mach jetzt mal Heute und Morgen Pause.

---

<div class="post-metadata">

**Author:** ![paulpaulson](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/paulpaulson/32/363643_2.png) [@paulpaulson](https://forum.arduino.cc/u/paulpaulson)\
**Post date:** [August 17, 2025, 6:09am UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/16 "2025-08-17T06:09:16Z")

</div>

Hallo [andy-anfaenger](https://forum.arduino.cc/u/andy-anfaenger?_gl=1*rzi3w9*_up*MQ..*_ga*MTU2NDEzMDU3MS4xNzU1Mzk3OTQ1*_ga_NEXN8H46L5*czE3NTUzOTc5NDQkbzEkZzAkdDE3NTUzOTc5NDQkajYwJGwwJGgxMDI3NzE4MTQz)

Hier kommen prima Anleitungen von Harmut zum Üben und Lernen.

Viel Spass beim gemeinsamen Hobby 🙂

> **[Alle Anleitungen als PDF - Projekte für Arduino und ESP32-Mikrocontroller](https://hartmut-waller.info/arduinoblog/pdf-aufgaben/)**
>
> Anleitungen als PDF anzeigen

---

<div class="post-metadata">

**Author:** ![andy-anfaenger](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/andy-anfaenger/32/1126549_2.png) [@andy-anfaenger](https://forum.arduino.cc/u/andy-anfaenger)\
**Post date:** [August 17, 2025, 8:58pm UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/17 "2025-08-17T20:58:41Z")

</div>

@paulpaulson vielen Dank 😉 sowas kann ich gut gebrauchen.

Grüße Andi

---

<div class="post-metadata">

**Author:** ![andy-anfaenger](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/andy-anfaenger/32/1126549_2.png) [@andy-anfaenger](https://forum.arduino.cc/u/andy-anfaenger)\
**Post date:** [August 18, 2025, 10:25am UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/18 "2025-08-18T10:25:00Z")

</div>

@my_xy_projekt brauche doch vielleicht noch was 🙈  
Meinst du der Arduino UNO packt das mit den 4 Servos und dem Taster oder soll ich besser externen Strom nehmen?

Geht die Variante mit der LED auch beim UNO?

Man bin ich eine Lötfeile🙈 ne, ich bin bei Strom vielleicht zu vorsichtig.

Grüße Andi

---

<div class="post-metadata">

**Author:** ![Doc\_Arduino](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/doc_arduino/32/215810_2.png) [@Doc\_Arduino](https://forum.arduino.cc/u/Doc_Arduino)\
**Post date:** [August 18, 2025, 10:33am UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/19 "2025-08-18T10:33:50Z")

</div>

Hallo,

für ein kleines Servo ohne Last reicht es, also zum ersten Test. Ansonsten immer eigene Stromversorgung für Servos einplanen.

---

<div class="post-metadata">

**Author:** ![my\_xy\_projekt](https://dub1.discourse-cdn.com/arduino/user_avatar/forum.arduino.cc/my_xy_projekt/32/810062_2.png) [@my\_xy\_projekt](https://forum.arduino.cc/u/my_xy_projekt)\
**Post date:** [August 18, 2025, 10:35am UTC](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415/20 "2025-08-18T10:35:54Z")

</div>

> [@andy-anfaenger](#):
>
> soll ich besser externen Strom nehmen?

Da immer nur ein Servo läuft, sollte das auch mit der Versorgung aus dem UNO heraus funktionieren.

> [@andy-anfaenger](#):
>
> Geht die Variante mit der LED auch beim UNO?

Die LED geht überall, solange Du einen PIN dafür hast.  
In meinem Code ist die ON-Board-LED benutzt. Die liegt parallel an PIN 13. Du kannst den PIN also nutzen UND die LED auf dem Board läuft mit.

Bei anderen Boards ist zu prüfen, ob und wo eine LED verbaut ist.

Wenn Dir die da nicht gefällt, kannst Du die auch auf einen anderen PIN legen, brauchst dann aber zwingend eine externe LED-

[Next page](https://forum.arduino.cc/t/mehrere-servos-mit-taster/1402415.md?page=2)