morse code without delay

Projects Programming
1

Trying to turn this into a finite state machine (FSM):

  digitalWrite(ledPin, HIGH);
  delay(duration);
  digitalWrite(ledPin, LOW);
  delay(wait);

Seemed simple enough following the directions here.

Below is the code I wrote to flash an LED in Morse Code to signal SOS. The FSM is in the void flash() function. The issue I'm having when I run the code is that the LED blinks HIGH for 700ms and LOW for 700ms unless I only call the function once. The intent of the code is for the LED to blink 3 short times using flash(dot), 3 long times using flash(dash), and 3 short times again using flash(dot).

const byte ledPin = 13;
const int dot = 200;
const int dash = 500;
const int wait = 300;
const int morsePause = 700;
unsigned long ledTimer;
int blinkState = 0;


void setup() {
  Serial.begin(9600);
  pinMode(ledPin, OUTPUT);
}

void loop() {
flash(dot); 
flash(dot); 
flash(dot);
delay(morsePause);
flash(dash); 
flash(dash); 
flash(dash);
delay(morsePause);
flash(dot); 
flash(dot); 
flash(dot);
delay(morsePause);
}

void flash(int duration)
{
//  digitalWrite(ledPin, HIGH);
//  delay(duration);
//  digitalWrite(ledPin, LOW);
//  delay(wait);
  
  switch(blinkState)
  {
    case 0:
      digitalWrite(ledPin, HIGH);
      Serial.println("LED on");
      ledTimer = millis();
      blinkState = 1;
      break;
    case 1:
      if(millis() - ledTimer >= duration)
      {
        blinkState = 2;
      }
      break;
    case 2:
      digitalWrite(ledPin, LOW);
      Serial.println("LED off");
      ledTimer = millis();
      blinkState = 3;
      break;
    case 3:
      if(millis() - ledTimer >= wait)
      {
        blinkState = 0;
      }
      break;
  }
}

The program works fine if I remove the FSM and only use delays in the void & flash functions. Once I get the void flash() issue solved, then I plan to convert the void loop into a FSM.

PS: This is not for a homework assignment. :slight_smile: I'm merely trying to get away from using delay() and start using FSMs in the future.

2

Where to start....

Your code doesn't implement a fsm. You are still stepping through loop() one Morse character at a time. Loop() should go round freely many thousands of times per second.

You probably need an array to store the Morse characters and your fsm will step through the array slowly with timing given by millis().

Try the tutorial again.

There's tutorials on here for using millis for timing and doing several things at once. Study those.

https://forum.arduino.cc/index.php?topic=503368.0

https://forum.arduino.cc/index.php?topic=223286.0

3

I've put this together for you as an example, it kind of does what you are trying to achieve but I've left plenty of room for improvement. Note how loop() is free to loop and how morse() just checks if the right amount of time has elapsed and only does something if there is something to be done. I'm not even sure if this properly counts as a FSM it's so simple, I suppose it does. There are 2 variables that keep track of the states, these are index and toneOn.

#define LEDpin 13

uint32_t SOS[] = {200, 200, 200, 500, 500, 500};
uint32_t silence = 200;
uint8_t noOfbeeps = 6;

void setup() {
  pinMode(LEDpin, OUTPUT);
}
void loop() {
  morse();
}

void morse() { 
  uint32_t currentMillis = millis();
  static uint8_t index = 0;
  static uint32_t lastMillis;
  static uint32_t waitTime;
  static bool toneOn;
  if (currentMillis - lastMillis >= waitTime) {
    lastMillis = currentMillis;
    if (toneOn) {
      toneOn = false;
      digitalWrite(LEDpin, LOW);
      waitTime = silence;
    } else {
      toneOn = true;
      digitalWrite(LEDpin, HIGH);
      waitTime = SOS[index];
      index = (index + 1) % 6;
    }
  }
}
4

PerryBebbington:
I've put this together for you as an example, it kind of does what you are trying to achieve but I've left plenty of room for improvement. Note how loop() is free to loop and how morse() just checks if the right amount of time has elapsed and only does something if there is something to be done. I'm not even sure if this properly counts as a FSM it's so simple, I suppose it does. There are 2 variables that keep track of the states, these are index and toneOn.

Thanks. I'll start working through it. It might take a minute or two to digest.

5

PerryBebbington:

      waitTime = SOS[index];

index = (index + 1) % 9;

So I'm getting hung up on the remainder operator (%). I've looked at what Reference says about % and saw it even used an array as an example. Is there an advantage (other than less code) to using % rather than a simple counter?

      waitTime = SOS[index];      // waitTime duration = SOS array
      index++;                    // increment index + 1
      if(index >= 9)              // if index greater than 8
      {
        index = 0;                // reset index to 0
      }
6

The advantage of using % is that it's simple and tidy, nothing else as far as I know. When I first learnt C I didn't use it because I found it easier to understand if I wrote out the code the long way as you have done. Do it whichever way you prefer and don't worry about it.

7

The Morse code programs I have looked at ALL decide on a basic unit of Morse code time. They all pick the length of time for a DOT. A dash might be two or three dots in length. The time between letters might be 4 dots. The time between words might be 5 dots.
Then if you want the code to be faster or slower, only the actual timing of a dot needs to be changed.
Paul

8

This topic was automatically closed 120 days after the last reply. New replies are no longer allowed.