MULTIPLE Analog inputs in an array then average each array for analog inputs

Projects Programming
1

I am trying to put four analog inputs into individual channels that contain an array. Once that happens I am trying to get an average of each channel's array getting a single int or float. Lastly, I want to compare the averages in an if statement to get a serial print and divide the compared averages.

I am just confused on:
how to code unsigned int analog inputs with arrays while using channels?
how to code an analogRead to read more then 1 analog input while dealing with array and channels ?
how to code a serial.print showing each of 4 analog inputs' arrays?
how to average each analog input array to get an average of each array?

Thank you for any advice or help.

const unsigned int numReadings = 10; // number of readings
const unsigned int numChannels = 4; // 4 channels  

unsigned int analogVal0[numChannels][numReadings];  //one array
unsigned int analogVal1[numChannels][numReadings];  //one array
unsigned int analogVal2[numChannels][numReadings];  //one array
unsigned int analogVal3[numChannels][numReadings];  //one array

unsigned int i = 0; //position in array
unsigned int chan = 0;

void setup() {
  Serial.begin(9600);
}

void loop() {


//analogVal0[i] = analogRead(A0); 

i++;  // move position over

for (chan <= numChannels; ++chan;){
  analogVal[chan] += analogRead(A0[chan]);  //take sample

if (i >= numReadings){     //if positions is over amount of readings
  Serial.println(analogVal[chan][i]);  //print analog array added chan so analogVal[i]
  i = 0;   //set position to 0
  chan = chan + 1

}
if (chan >= numChannels){
  Serial.println(analogVal[0][i]);
  Serial.println(analogVal1[1][i]);
  Serial.println(analogVal2[2][i]);
  Serial.println(analogVal3[3][i]);
  
  sVal0_avg = analogVal[0][i]/numReadings
  sVal1_avg = sVal1[0][i]/numReadings;
  sVal2_avg = sVal2[0][i]/numReadings;
  sVal3_avg = sVal3[0][i]/numReadings;


}
} 
}

}
2

If you are using a 2 dimentional array, you don't need 4 of them since the one will hold all the samples for all the channels

const unsigned int numReadings = 10; // number of readings
const unsigned int numChannels = 4; // 4 channels
const int channelPin[numChannels] = { A0, A1, A2, A3 };
unsigned int analogVal[numChannels][numReadings];  //one array
unsigned int analogSum[numChannels];

void setup() {
  Serial.begin(9600);
}

void loop() {

  for ( int i = 0; i < numChannels; ++i ) {
    analogSum[i] = 0;
  }
  for ( int i = 0; i < numReadings; ++i ) {
    for (int chan = 0; chan < numChannels; ++chan) {
      analogVal[chan][i] = analogRead(channelPin[chan]);  //take sample
      analogSum[chan] += analogVal[chan][i];
      Serial.println(analogVal[chan][i]);  //print analog array added chan so analogVal[i]
    }
  }

  Serial.println( "Averages" );
  for ( int i = 0; i < numChannels; ++i ) {
    int avg = analogSum[i] / numReadings;
    Serial.println(avg);  //print analog array added chan so analogVal[i]
  }
}
3

consider. not sure what comparisons you want to make

#define N_CHAN      4
#define N_READING   10
   
byte         anlg [N_CHAN] = { A0, A1, A2, A3 };
unsigned int data [N_CHAN][N_READING];
int          nRdg = 0;

char s [40];

// -----------------------------------------------------------------------------
void loop()
{
    // capture data on all channels
    for (int chan = 0; chan < N_CHAN; chan++)
        data [chan][nRdg] = analogRead (anlg [chan]);

    // once every 0.1 sec
    delay (100);

    // dump data & calc average every Nth reading
    if (N_READING <= ++nRdg)  {
        for (int chan = 0; chan < N_CHAN; chan++)  {
            sprintf (s, "chan: %d", chan);
            Serial.println (s);

            unsigned int sum = 0;
            for (int n = 0; n < N_READING; n++)  {
                sum += data [chan][n];
                sprintf (s, "  %6d %6d", sum, data [chan][n]);
                Serial.println (s);
            }
            sprintf (s, "  %6s %6d", "", sum / N_READING);
            Serial.println (s);
        }
        nRdg = 0;
    }
}

// -----------------------------------------------------------------------------
void setup() {
    Serial.begin(9600);
}