'mutichannelGasSensor' was not declared in this scope

Hello,

I am using the Grove Multichannel Gas Sensor with an Arduino Uno. I have installed the Multichannel Gas Sensor library and added it to my Arduino folder. I uploaded my code, and I still get error messages that “‘mutichannelGasSensor’ was not declared in this scope”.

This is the code I am using:

#include <MutichannelGasSensor.h>

/*
    Code for Environmental Sensor that takes air quality, light, temperature, and
    noise data from the environment to display on a lcd screen
*/


#include <Wire.h>
#include "MutichannelGasSensor.h"
#include "rgb_lcd.h"
rgb_lcd lcd;

const int buttonPin = 8;
int buttonPushCounter = 0;
int buttonState = 0;
int lastButtonState = 0;

void setup()
{   
    lcd.begin(16, 2);  // set up the LCD's number of columns and rows
    Serial.begin(9600);  // start serial for output
    lcd.println("power on!");
    lcd.noAutoscroll();
    mutichannelGasSensor.begin(0x04);//the default I2C address of the slave is 0x04
    //mutichannelGasSensor.changeI2cAddr(0x04);
    mutichannelGasSensor.doCalibrate();
    
    pinMode(buttonPin, INPUT);
    
}

void loop()
{
    float c;
    float d;
    float e;
    int f;
    float g;
    int h;
    float r;
    float t;
    float fah;
    mutichannelGasSensor.powerOn();

    buttonState = digitalRead(buttonPin);
    
    // compare the buttonState to its previous state
    if (buttonState != lastButtonState) 
    {
        if (buttonState == HIGH) 
        {
            buttonPushCounter++;
        } 
        // Delay a little bit to avoid bouncing
        //delay(50);
    }

    if (buttonPushCounter==0){
    c = mutichannelGasSensor.measure_NH3();
    lcd.setRGB(155,221,255);
    lcd.print("NH3:");
    if(c>=0) lcd.print(c);
    else lcd.print("invalid");
    lcd.print(" ppm");}

    if (buttonPushCounter==1){
    d = mutichannelGasSensor.measure_CO();
    lcd.setRGB(196,216,226);
    lcd.print("CO:");
    if(d>=0) lcd.print(d);
    else lcd.print("invalid");
    lcd.print(" ppm");}

    if (buttonPushCounter==2){
    e = mutichannelGasSensor.measure_NO2();
    lcd.setRGB(204,255,255);
    lcd.print("NO2:");
    if(e>=0) lcd.print(e);
    else lcd.print("invalid");
    lcd.print(" ppm");}

    if (buttonPushCounter==3){
    f = analogRead(0);
    lcd.setRGB(182,134,44);
    lcd.print("Light:");
    if(f>=0) lcd.print(f);
    else lcd.print("invalid");
    lcd.print(" units");}

    if (buttonPushCounter==4){
    g = analogRead(1);
    r = (float)(1023-g)*10000/g; //resistance calculation
    t=1/(log(r/10000)/3975+1/298.15)-273.15; //temperature in celsius
    fah=t*9/5+32;
    lcd.setRGB(255,102,255);
    lcd.print("Temp:");
    lcd.print(fah);
    lcd.print(" *F");}

    if (buttonPushCounter==5){
    g = analogRead(1);
    r = (float)(1023-g)*10000/g; //resistance calculation
    t=1/(log(r/10000)/3975+1/298.15)-273.15; //temperature in celsius
    lcd.setRGB(255,153,255);
    lcd.print("Temp:");
    lcd.print(t);
    lcd.print(" *C");}

    if (buttonPushCounter==6){
    h = analogRead(2);
    lcd.setRGB(8,30,63);
    lcd.print("Noise:");
    if(h>=0) lcd.print(h);
    else lcd.print("invalid");
    lcd.print(" units");}

    if (buttonPushCounter==7){
      buttonPushCounter=0;
      lcd.setRGB(255,255,255);
    }
    
    delay(250);
    lcd.clear();
    
}

Thank you for any help.

Did you look at the example?

Spot the difference:

#include <Wire.h>
#include "MutichannelGasSensor.h"

void setup()
{
    Serial.begin(115200);  // start serial for output
    Serial.println("power on!");
    gas.begin(0x04);//the default I2C address of the slave is 0x04
    gas.powerOn();
    Serial.print("Firmware Version = ");
    Serial.println(gas.getVersion());
}