My button is reading from pins that are not declared

Projects Programming
1

#include <Wire.h>
#include <Adafruit_PWMServoDriver.h>
Adafruit_PWMServoDriver pwm = Adafruit_PWMServoDriver();

int buttonPin0 = 2; // Can add as many buttons as needed
int buttonState0 = 0;

int buttonPin1 = 5;
int buttonState1 = 0;

int buttonPin2 = 8;
int buttonState2 = 0;

int buttonPin3 = 11;
int buttonState3 = 0;

void setup() {
Serial.begin(9600);
Serial.println("pca9685_TurnoutFinal!");
pwm.begin();
pwm.setPWMFreq(60);
delay(30);

pinMode(buttonPin0, INPUT);
pinMode(buttonPin1, INPUT);
pinMode(buttonPin2, INPUT);
pinMode(buttonPin3, INPUT);
}

void loop() {
///////////
buttonState0 = digitalRead(buttonPin0);
Serial.println(buttonState0);
delay(1000);
if (buttonState0 == 0) {
pwm.setPWM(0, 0, 370);
}
else {
pwm.setPWM(0, 0, 285);
}
//////////
buttonState1 = digitalRead(buttonPin1);
Serial.println(buttonState1);
delay(1000);
if (buttonState1 == 0) {
pwm.setPWM(1, 0, 370);
}
else {
pwm.setPWM(1, 0, 285);
}
///////////
buttonState2 = digitalRead(buttonPin2);
if (buttonState2 == 0) {
pwm.setPWM(2, 0, 370);
}
else {
pwm.setPWM(2, 0, 285);
}
///////////
buttonState3 = digitalRead(buttonPin3);
if (buttonState3 == 0) {
pwm.setPWM(3, 0, 370);
}
else {
pwm.setPWM(3, 0, 285);
}
}

2

this is my code for now, i tried using digital pin 4 and somehow servomotor1 gets activated

3

@treetilt21 Why do users choose to ignore the advice on posting code ?

The easier you make it to read and copy your code the more likely it is that you will get help

Please follow the advice given in the link below when posting code , use code tags and post the code here

4

How are your inputs wired ?

Any pullup or pulldown resistors in place or are they floating at an unknown voltage when the buttons are not pressed ?

5

Shouldn't that be

pinMode(buttonPin0, INPUT_PULLUP);
pinMode(buttonPin1, INPUT_PULLUP);
pinMode(buttonPin2, INPUT_PULLUP);
pinMode(buttonPin3, INPUT_PULLUP);

Not sure how a button can "read" anything, its a switch.

6

Hi "TreeTilt21",

Welcome to the forum.

A couple of things that might help get you closer to your intended path;

  1. It's great when people post their code - but it's really hard for people to read it easily unless it's posted with what's called "code tags" (especially for people using mobile devices). The good news is that's really easy to do:

  • Pop back into the IDE (where you wrote the program)

  • Do a ctrl+T to auto-format your sketch

  • Do a ctrl+A to select everything

  • Do a ctrl+shift+C to copy everything selected to the clipboard with the correct code tags in place

  • Paste your clipboard into your post here.

I've done that for you below.

  1. When I looked at your code in my IDE I saw a way you can do some things a little easier; if you want to test if a switch is closed you don't need to copy it to a variable first ... you can just pop the digital read directly into the test statement ... which means you're dealing with less code (easier to spot problems) and you don't need to declare as many variables either - I've given you an example below (note: I stripped out your serial portions just so you can focus on what I mean) (I haven't compiled it because I don't have your libraries -- but it should be fine as a learning example).
#include <Wire.h>
#include <Adafruit_PWMServoDriver.h>
Adafruit_PWMServoDriver pwm = Adafruit_PWMServoDriver();

const byte buttonPin0 = 2;                      // Can add as many buttons as needed
const byte buttonPin1 = 5;
const byte buttonPin2 = 8;
const byte buttonPin3 = 11;

void setup() 
{
  pwm.begin();                                  // Setup PWM
  pwm.setPWMFreq(60);
  
  delay(30);                                    // Wait 30ms

  pinMode(buttonPin0, INPUT);                   // Setup pin modes
  pinMode(buttonPin1, INPUT);
  pinMode(buttonPin2, INPUT);
  pinMode(buttonPin3, INPUT);
}

void loop() {
  
  if (digitalRead(buttonPin0) == 0) 
  {
    pwm.setPWM(0, 0, 370);
  }
  
  else 
  {
    pwm.setPWM(0, 0, 285);
  }
  
  delay(1000);
  
  if (digitalRead(buttonPin1) == 0) 
  {
    pwm.setPWM(1, 0, 370);
  }
  
  else 
  {
    pwm.setPWM(1, 0, 285);
  }
  
 if (digitalRead(buttonPin2) == 0) 
  {
    pwm.setPWM(2, 0, 370);
  }
  
  else 
  {
    pwm.setPWM(2, 0, 285);
  }
  
    if (digitalRead(buttonPin3) == 0) 
  {
    pwm.setPWM(3, 0, 370);
  }
  
  else {
    pwm.setPWM(3, 0, 285);
  }

  delay(1000);
}

There are other techniques to get around multiple sections of code that are for the most part identical too (called arrays), but that's a different topic for a different day -- still might be something you'd like to research at some point though.

With regards to the actual issue you're having, I really can't tell without knowing how you've got things connected. Because - as my learned friend alluded to - inputs can "float" to any state if there's nothing driving them either way - there's some simple techniques that we use to make sure that doesn't happen ...

  • One way is to use what's called a pull-down resister (10,000 ohms works well) between the pin and ground - and then connect the pin via a switch to your high voltage (+5 or +3.3 depending on what you're using). This is called "active high" (it's active when it's high).

  • But there's an even easier way ... all of the digital pins have a built in 20,000ohm pull-up resistor ... but it has to be turned on by using pinMode(buttonPin1, INPUT_PULLUP) - then all you need to do is connect the switch directly between the pin and ground ... no external resister needed. There's no real "downside" to this as such, but you do have to make a slight change to your program because the circuit is now what's called "active low" - so you'd test it using something like:

if(digitalRead(buttonPin1) == low)
{
my code ...
}

Does that help?

7

All available from the right click menu in the IDE, which may be easier..No need to do the ctrl+A as copying the whole sketch for the forum is the default

True, but then you don't have a variable to print for debugging when you need it. Sensibly named variables can also make code easier to read

8

You have two seconds of delay() in your loop(). That means that 99.9% of the time, your sketch is doing nothing. It also means you may need to hold a button down for more than two seconds before it will be noticed. I recommend you get rid of delays.

Are you 'buttons' actually switches? That would explain why your code is written to move the servo whenever the input changes.

1 Like
9

Here is a way to simplify code with an array of pin numbers instead of four different variables.

#include <Wire.h>
#include <Adafruit_PWMServoDriver.h>
Adafruit_PWMServoDriver pwm = Adafruit_PWMServoDriver();

// Can add as many switch inputs as there are servo outputs
const byte SwitchPins[] = {2, 5, 8, 11};       
const int SwitchCount = sizeof SwitchPins / sizeof SwitchPins[0];

void setup()
{
  pwm.begin();                                  // Setup PWM
  pwm.setPWMFreq(60);

  for (int i = 0; i < SwitchCount; i++)
    pinMode(SwitchPins[i], INPUT_PULLUP); // Switches between pin and Ground
}

void loop()
{
  for (int i = 0; i < SwitchCount; i++)
  {
    if (digitalRead(SwitchPins[i]) == LOW)
      pwm.setPWM(i, 0, 370);  // Switch closed (Pin grounded)
    else
      pwm.setPWM(i, 0, 285);  // Switch open (Pin pulled up)
  }
}
10

This topic was automatically closed 120 days after the last reply. New replies are no longer allowed.