Nano 33 BLE UART compile problem

I’m trying to use UART on Nano 33 BLE and cannot compile following code

#include <ArduinoBLE.h>
#include "wiring_private.h"
Uart mySerial (&sercom1, 13, 8, SERCOM_RX_PAD_1, UART_TX_PAD_2);

// Attach the interrupt handler to the SERCOM
void SERCOM1_Handler()
{
    mySerial.IrqHandler();
}

void setup() {
  // Reassign pins 13 and 8 to SERCOM (not alt this time)
  pinPeripheral(13, PIO_SERCOM);
  pinPeripheral(8, PIO_SERCOM);

  // Start my new hardware serial
  mySerial.begin(9600);
}

void loop() {
  mySerial.write("AT");
}

When I use IoT board it works but on BLE it returns

sketch_jan21a:3:1: error: 'Uart' does not name a type; did you mean 'wait'?
 Uart mySerial (&sercom1, 13, 8, SERCOM_RX_PAD_1, UART_TX_PAD_2);

Is there any example how to use UART on BLE?

Thank you
Steven

It works a bit differently on the Nano 33 BLE boards than on the Nano 33 IoT:

UART mySerial (digitalPinToPinName(8), digitalPinToPinName(13), NC, NC);  // create a hardware serial port named mySerial with RX: pin 13 and TX: pin 8

That's the only special line you need, no #include directive for wiring_private.h, no SERCOM1_Handler, no pinPeripheral(). After that on line, you can use mySerial just like any other hardware serial port. You can use any pins. Note that, unlike everything else serial related in the Arduino code base, the order of the pin parameters is TX, RX.

Demonstration sketch:

UART mySerial (digitalPinToPinName(8), digitalPinToPinName(13), NC, NC);  // create a hardware serial port named mySerial with RX: pin 13 and TX: pin 8

void setup() {
  Serial.begin(9600);
  mySerial.begin(9600);
}

void loop() {
  if (Serial.available()) {
    mySerial.write(Serial.read());
  }
  if (mySerial.available()) {
    Serial.write(mySerial.read());
  }
}