Need help with bmp280 altitude

[reseenalisa]

Hello guys, I need help with my code. I am a beginner and I don't know what to do. I'm using this code for my BMP280 but I can't get altidute right. It says
Approx altitude = inf m
How can we fix this?
I'm writing the code below.

#include <Wire.h>
#include <SPI.h>
#include <Adafruit_BMP280.h>

#define BMP_SCK  (13)
#define BMP_MISO (12)
#define BMP_MOSI (11)
#define BMP_CS   (10)

Adafruit_BMP280 bmp;

int pressure = bmp.readPressure();

void setup() {
  Serial.begin(9600);
  while ( !Serial ) delay(100);
  Serial.println(F("BMP280 test"));
  unsigned status;
  status = bmp.begin(0x76);
  if (!status) {
    Serial.println(F("Could not find a valid BMP280 sensor, check wiring or "
                      "try a different address!"));
    while (1) delay(10);
  }
}

void loop() {
    Serial.print(F("Temperature = "));
    Serial.print(bmp.readTemperature());
    Serial.println(" *C");

    Serial.print(F("Pressure = "));
    Serial.print(bmp.readPressure());
    Serial.println(" Pa");

    Serial.print(F("Approx altitude = "));
    Serial.print(bmp.readAltitude(pressure/100));
    Serial.println(" m");

    Serial.println();
    delay(2000);
}

Like I said, I am a beginner, please don't make fun of me.

[xfpd]

@reseenalisa

Approx altitude = inf m

Verify "pressure" is valid in size and type for "bmp.readAltitude();"

[PaulRB]

BMP280 cannot measure altitude like a GPS sensor can. It can only measure air pressure. But the way air pressure changes with altitude is easy to calculate. If the sensor knows the air pressure at zero altitude, it can estimate the current altitude from the difference in pressure. But if it doesn't know the air pressure at zero altitude...

[jremington]

Start out by verifying that you can measure the raw pressure.

To measure altitude, a reference sea level pressure is required, and that reference value may be missing (random nonsense) or zero.

Study Adafruit's tutorials for that sensor, since you are using their library.

[reseenalisa]

I can measure pressure. But I cant measure altitude. I can't understand. Thanks for your help.

[jremington]

But I cant measure altitude.

Follow the instructions in reply #4 before firing off another post.

Adafruit BMP280 Barometric Pressure + Temperature Sensor Breakout

[TomGeorge]

HI, @reseenalisa
Welcome to the forum.

Thanks for using code tags.

Did you try the complete bmp280test example that come with the Library?

/***************************************************************************
  This is a library for the BMP280 humidity, temperature & pressure sensor

  Designed specifically to work with the Adafruit BMP280 Breakout
  ----> http://www.adafruit.com/products/2651

  These sensors use I2C or SPI to communicate, 2 or 4 pins are required
  to interface.

  Adafruit invests time and resources providing this open source code,
  please support Adafruit andopen-source hardware by purchasing products
  from Adafruit!

  Written by Limor Fried & Kevin Townsend for Adafruit Industries.
  BSD license, all text above must be included in any redistribution
 ***************************************************************************/

#include <Wire.h>
#include <SPI.h>
#include <Adafruit_BMP280.h>

#define BMP_SCK  (13)
#define BMP_MISO (12)
#define BMP_MOSI (11)
#define BMP_CS   (10)

Adafruit_BMP280 bmp; // I2C
//Adafruit_BMP280 bmp(BMP_CS); // hardware SPI
//Adafruit_BMP280 bmp(BMP_CS, BMP_MOSI, BMP_MISO,  BMP_SCK);

void setup() {
  Serial.begin(9600);
  while ( !Serial ) delay(100);   // wait for native usb
  Serial.println(F("BMP280 test"));
  unsigned status;
  //status = bmp.begin(BMP280_ADDRESS_ALT, BMP280_CHIPID);
  status = bmp.begin();
  if (!status) {
    Serial.println(F("Could not find a valid BMP280 sensor, check wiring or "
                      "try a different address!"));
    Serial.print("SensorID was: 0x"); Serial.println(bmp.sensorID(),16);
    Serial.print("        ID of 0xFF probably means a bad address, a BMP 180 or BMP 085\n");
    Serial.print("   ID of 0x56-0x58 represents a BMP 280,\n");
    Serial.print("        ID of 0x60 represents a BME 280.\n");
    Serial.print("        ID of 0x61 represents a BME 680.\n");
    while (1) delay(10);
  }

  /* Default settings from datasheet. */
  bmp.setSampling(Adafruit_BMP280::MODE_NORMAL,     /* Operating Mode. */
                  Adafruit_BMP280::SAMPLING_X2,     /* Temp. oversampling */
                  Adafruit_BMP280::SAMPLING_X16,    /* Pressure oversampling */
                  Adafruit_BMP280::FILTER_X16,      /* Filtering. */
                  Adafruit_BMP280::STANDBY_MS_500); /* Standby time. */
}

void loop() {
    Serial.print(F("Temperature = "));
    Serial.print(bmp.readTemperature());
    Serial.println(" *C");

    Serial.print(F("Pressure = "));
    Serial.print(bmp.readPressure());
    Serial.println(" Pa");

    Serial.print(F("Approx altitude = "));
    Serial.print(bmp.readAltitude(1013.25)); /* Adjusted to local forecast! */
    Serial.println(" m");

    Serial.println();
    delay(2000);
}

What model Arduino are you using?

Thanks.. Tom..