New to Arduino: error: request for member 'write' in 'servchn0', which is of non

Hello, I’m new to Arduino and trying to adapt a drawing arm using three servos hooked up to a TLC 5940 breakout board. I keep getting "error: request for member ‘write’ in ‘servchn0’, which is of non-class type ‘byte {aka unsigned char}’ " Any suggestions what might be causing the error? Thank you in advance.

#include "SparkFun_Tlc5940.h"
#include "tlc_servos.h"

byte servchn0 = 0;      // Joint at base
byte servchn1 = 1;      // Elbow between a and b

// Servo Angles
byte ServoS_0_Angle = 90;
byte ServoS_1_Angle = 90;

// Define arm Constants
const float a = 14.5;      // lower joint length (cm)
const float b = 11.5;      // upper joint length (cm)

// Correction factors to align servo values with their respective axis
const float S_0_CorrectionFactor = -10;     // Align arm "a" with the horizontal when at 0 degrees
const float S_1_CorrectionFactor = -77;     // Align arm "b" with arm "a" when at 0 degrees

// Correction factor to shift origin out to edge of the mount
const float X_CorrectionFactor = 6.5;       // X direction correction factor (cm)
const float Y_CorrectionFactor = -4;       // Y direction correction factor (cm)

// Angle Variables
float A;            //Angle oppposite side a (between b and c)
float B;            //Angle oppposite side b
float C;            //Angle oppposite side c
float theta;        //Angle formed between line from origin to (x,y) and the horizontal

// Distance variables
float x;            // x position (cm)
float y;            // y position (cm)
float c;            // Hypotenuse legngth in cm
const float pi = M_PI;

//Circle Setup
const float Radius = 3.5;       // Radius of circle in centimeters
const int CircleCenterX = 14;   // X coordinate of the center of the circle 
const int CircleCenterY = 6;    // Y coordinate of the center of the circle

//===================================================================================

void setup()
{
  tlc_initServos();  // Note: this will drop the PWM freqency down to 50Hz.
  Serial.begin(9600);
}
//--------------------------------------------------------------


void loop()
{
  for (int t = 0; t<360; t++)           // Get t value
  {
    // Equation of a circle in parametric form
    x = Radius * cos(t *(pi/180)) + CircleCenterX; 
    y = Radius * sin(t *(pi/180)) + CircleCenterY;
    Serial.println(x);
    FixCoordinates(x,y);           // Enter coordinates of point.
    CalculateServoAngles();           // Calculate angle of servos
    MoveArm(); // Move arm to new position
    Tlc.update();
    delay(10);
  }
}

//====================================================================================

// Get x and y measured from the bottom of the base. Function corrects for offset
void FixCoordinates(float x_input, float y_input)
{
  x = x_input + X_CorrectionFactor;
  y = y_input + Y_CorrectionFactor;
}

// Calculate necessary servo angles to move arm to desired points
void CalculateServoAngles()
{
  c = sqrt( sq(x) + sq(y) );                                            // pythagorean theorem
  B = (acos( (sq(b) - sq(a) - sq(c))/(-2*a*c) )) * (180/pi);            // Law of cosines: Angle opposite upper arm section
  C = (acos( (sq(c) - sq(b) - sq(a))/(-2*a*b) )) * (180/pi);            // Law of cosines: Angle opposite hypotenuse
  theta = (asin( y / c )) * (180/pi);                                   // Solve for theta to correct for lower joint's impact on upper joint's angle
  ServoS_0_Angle = B + theta + S_0_CorrectionFactor;                    // Find necessary angle. Add Correction
  ServoS_1_Angle = C + S_1_CorrectionFactor;                            // Find neceesary angle. Add Correction

}

// Update the servos
void MoveArm()
{
  servchn0.write(ServoS_0_Angle);              // Move joint to desired position
  servchn1.write(ServoS_1_Angle);              // Move joint to desired position
}

Instead of calling the .write() method on the servo number, I think you should be using the tlc_setServo() function.