Newbie coding problem

Using Arduino Project Guidance
1 
void loop()
{
  if ( a >= b )
  {
    i++;
  }
}

As the code above, we know that the Arduino microprocessor will keep loop this code forever. So, whenever the if ( a >= b ) condition is met, the i will ++ for sure, and i increasing continuously.

My question is, is there any method to let the machine know: -

if ( a >= b ) is met continuously, "condition on", i++ will only execute once.
then,
if ( a >= b ) is not met, "condition off", ready to meet the condition again.
then,
if ( a >= b ) is met again, "condition on", i++ will only execute once.
also,
if ( a >= b ) is met without changing into ( a < b ), "condition on", do nothing until "condition off" again.

2

Sure, just put some flags in with a>b to control things.

For example:

if (a>b && runOnce == 0){
runOnce = 1;
i++;
}

Then something external has to set runOnce back to 0 to let it run again.

3

State Change Detection, performing an action when a state CHANGES, is a very common problem. The built-in example: File->Examples->02.Digital->StateChangeDetection shows one way to do it.

4

CrossRoads had solve my coding problem.

johnwasser also help me to link the correlation of my problem with the example.

Thank you very much for the answers! :smiley:

5

winterpie:
CrossRoads had solve my coding problem.

johnwasser also help me to link the correlation of my problem with the example.

Thank you very much for the answers! :smiley:

Here is the example I pointed to. The example gets its current state information with:

buttonState = digitalRead(buttonPin);

Since you are interested in the condition "a >= b" rather than the state of an input pin, you would use "a >= b" in place of the "digitalRead()" call. Of course the names "buttonState" and "lastButtonState" don't make sense in your context so you should do a search-and-replace to change them to something like "condition" and "lastCondition". Replace the "buttonPushCounter++;" with what you want to happen when the 'condition' changes from false to true.

/*
  State change detection (edge detection)


  Often, you don't need to know the state of a digital input all the time, but
  you just need to know when the input changes from one state to another.
  For example, you want to know when a button goes from OFF to ON. This is called
  state change detection, or edge detection.


  This example shows how to detect when a button or button changes from off to on
  and on to off.


  The circuit:
  - pushbutton attached to pin 2 from +5V
  - 10 kilohm resistor attached to pin 2 from ground
  - LED attached from pin 13 to ground (or use the built-in LED on most
    Arduino boards)


  created  27 Sep 2005
  modified 30 Aug 2011
  by Tom Igoe


  This example code is in the public domain.


  http://www.arduino.cc/en/Tutorial/ButtonStateChange
*/


// this constant won't change:
const int  buttonPin = 2;    // the pin that the pushbutton is attached to
const int ledPin = 13;       // the pin that the LED is attached to


// Variables will change:
int buttonPushCounter = 0;   // counter for the number of button presses
int buttonState = 0;         // current state of the button
int lastButtonState = 0;     // previous state of the button


void setup()
{
  // initialize the button pin as a input:
  pinMode(buttonPin, INPUT);
  // initialize the LED as an output:
  pinMode(ledPin, OUTPUT);
  // initialize serial communication:
  Serial.begin(9600);
}




void loop()
{
  // read the pushbutton input pin:
  buttonState = digitalRead(buttonPin);


  // compare the buttonState to its previous state
  if (buttonState != lastButtonState)
  {
    // if the state has changed, increment the counter
    if (buttonState == HIGH)
    {
      // if the current state is HIGH then the button went from off to on:
      buttonPushCounter++;
      Serial.println("on");
      Serial.print("number of button pushes: ");
      Serial.println(buttonPushCounter);
    }
    else
    {
      // if the current state is LOW then the button went from on to off:
      Serial.println("off");
    }
    // Delay a little bit to avoid bouncing
    delay(50);
  }
  // save the current state as the last state, for next time through the loop
  lastButtonState = buttonState;




  // turns on the LED every four button pushes by checking the modulo of the
  // button push counter. the modulo function gives you the remainder of the
  // division of two numbers:
  if (buttonPushCounter % 4 == 0)
  {
    digitalWrite(ledPin, HIGH);
  }
  else
  {
    digitalWrite(ledPin, LOW);
  }


}
6