OLED not found at i2 scanner

Using Arduino Displays
1

i have a problem, when i upload i2scanner, my OLED cannot detect in i2scanner, i have fixed what is appropriate to turn on oled 128x64. Please help me. im using OLED 7 pin,Ardunio Mega 2560.

i2scanner

// --------------------------------------
// i2c_scanner
//
// Version 1
//    This program (or code that looks like it)
//    can be found in many places.
//    For example on the Arduino.cc forum.
//    The original author is not known.
// Version 2, Juni 2012, Using Arduino 1.0.1
//     Adapted to be as simple as possible by Arduino.cc user Krodal
// Version 3, Feb 26  2013
//    V3 by louarnold
// Version 4, March 3, 2013, Using Arduino 1.0.3
//    by Arduino.cc user Krodal.
//    Changes by louarnold removed.
//    Scanning addresses changed from 0...127 to 1...119,
//    according to the i2c scanner by Nick Gammon
//    https://www.gammon.com.au/forum/?id=10896
// Version 5, March 28, 2013
//    As version 4, but address scans now to 127.
//    A sensor seems to use address 120.
// Version 6, November 27, 2015.
//    Added waiting for the Leonardo serial communication.
//
//
// This sketch tests the standard 7-bit addresses
// Devices with higher bit address might not be seen properly.
//

#include <Wire.h>

void setup() {
  Wire.begin();

  Serial.begin(9600);
  while (!Serial); // Leonardo: wait for Serial Monitor
  Serial.println("\nI2C Scanner");
}

void loop() {
  int nDevices = 0;

  Serial.println("Scanning...");

  for (byte address = 1; address < 127; ++address) {
    // The i2c_scanner uses the return value of
    // the Wire.endTransmission to see if
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    byte error = Wire.endTransmission();

    if (error == 0) {
      Serial.print("I2C device found at address 0x");
      if (address < 16) {
        Serial.print("0");
      }
      Serial.print(address, HEX);
      Serial.println("  !");

      ++nDevices;
    } else if (error == 4) {
      Serial.print("Unknown error at address 0x");
      if (address < 16) {
        Serial.print("0");
      }
      Serial.println(address, HEX);
    }
  }
  if (nDevices == 0) {
    Serial.println("No I2C devices found\n");
  } else {
    Serial.println("done\n");
  }
  delay(5000); // Wait 5 seconds for next scan
}

My codding project Automatic AC control

/*
 * Automatic AC Temperature control using Arduino and TSOP
 * Code by: Aswinth Raj B
 * Dated: 25-10-2017
 * Website: www.circuitdigest.com
 * 
       S.No: Component Pin Arduino Pin
    1 OLED – Vcc  5V 
    2 OLED – Gnd  Gnd
    3 OLED- SCK, D0,SCL,CLK 4
    4 OLED- SDA, D1,MOSI, Data  3
    5 OLED- RES, RST,RESET  7
    6 OLED- DC, A0  5
    7 OLED- CS, Chip Select 6
    8 DHT11 – Vcc 5V
    9 DHT11 – Gnd Gnd
    10  DHT11 – Signal  13
    11  TSOP – Vcc  5V
    12  TSOP – Gnd  Gnd
    13  IR Led – Anode  9
    14  IR Led – Cathode  Gnd
 */
 
 #include <IRremote.h> //Lib for IT Blaster and TSOP
 #include <SPI.h> // Inbuilt Lib
 #include <Wire.h> //Inbuilt Lib
 #include <Adafruit_GFX.h> //Lib for OLED
 #include <Adafruit_SSD1306.h> //Lib for OLED
 #include <dht.h> //Library for dht11 Temperature and Humidity sensor (Download from Link in article)
 
 // Assign pins for OLED (Software config.)
#define OLED_MOSI  3
#define OLED_CLK   4
#define OLED_DC    5
#define OLED_CS    6
#define OLED_RESET 7
Adafruit_SSD1306 display(OLED_MOSI, OLED_CLK, OLED_DC, OLED_RESET, OLED_CS);

#define SSD1306_LCDHEIGHT 64 //Change if you are using a Different OLED

#define DHT11_PIN 13 //Sensor output pin is connected to pin 13
dht DHT; //Sensor object named as DHT

#define Desired_temperature 27 //The desired temperature is 27*C at any time

//Decoded Remote Signals For my AC ##CHANGE IT FOR YOUR REMOTE
unsigned int ACoff[] = {4600,2500, 400,400, 350,950, 350,950, 350,400, 350,1000, 300,400, 350,400, 350,400, 350,400, 350,950, 350,400, 300,450, 300,1000, 350,400, 300,450, 300,450, 300,400, 350,1000, 300,400, 350,400, 350,950, 350,400, 350,1000, 300,400, 350,1000, 300,400, 350,400, 350,400, 350,400, 350,950, 350,400, 350,400, 350,950, 350,950, 350,400, 350,400, 350,400, 350,950, 350,400, 300,1000, 350,400, 350,400, 300,450, 300,1000, 300,450, 300,450, 300,1000, 300,1000, 350};
unsigned int ACon[] = {4600,2500, 400,400, 300,1000, 350,950, 350,400, 350,950, 350,400, 350,400, 350,400, 300,450, 300,1000, 350,400, 300,450, 300,1000, 300,450, 300,400, 350,400, 350,950, 350,950, 350,450, 300,400, 350,1000, 300,400, 350,1000, 300,450, 300,1000, 300,450, 300,400, 350,400, 350,400, 350,950, 350,400, 350,400, 350,950, 350,900, 400,400, 350,400, 350,400, 350,950, 350,400, 350,950, 350,400, 350,400, 300,450, 300,1000, 350,400, 300,450, 300,1000, 300,1000, 350};
unsigned int Temp23[] = {4600,2500, 400,400, 350,950, 350,1000, 300,400, 350,1000, 300,450, 300,400, 350,400, 350,400, 350,950, 350,400, 350,400, 350,950, 350,400, 350,400, 300,450, 300,450, 300,400, 350,1000, 300,400, 350,1000, 300,400, 350,1000, 300,450, 300,1000, 300,450, 300,400, 350,400, 350,400, 350,950, 350,400, 350,400, 350,950, 350,950, 350,400, 350,400, 350,400, 350,950, 350,400, 350,950, 350,400, 350,400, 350,400, 300,1000, 350,400, 350,400, 300,1000, 350,950, 350};
unsigned int Temp24[] = {4550,2550, 350,450, 300,1000, 300,1000, 350,400, 350,950, 350,400, 350,400, 300,450, 300,450, 300,1000, 300,450, 300,400, 350,1000, 300,400, 350,400, 350,400, 350,400, 350,400, 350,950, 350,400, 300,1000, 350,400, 350,950, 350,400, 350,950, 350,400, 350,400, 300,450, 300,450, 300,1000, 300,450, 300,400, 350,1000, 300,1000, 350,400, 300,450, 300,400, 350,1000, 300,400, 350,1000, 300,450, 300,400, 350,400, 350,950, 350,400, 350,400, 350,950, 350,1000, 300};
unsigned int Temp25[] = {4550,2550, 400,400, 300,1000, 350,950, 350,400, 350,950, 350,400, 350,400, 350,400, 300,450, 300,1000, 350,400, 300,450, 300,1000, 300,450, 300,400, 350,400, 350,1000, 300,400, 350,1000, 300,400, 350,1000, 300,450, 300,1000, 300,450, 300,1000, 300,450, 300,400, 350,400, 350,400, 350,950, 350,400, 350,400, 350,950, 350,950, 350,400, 350,400, 350,400, 350,950, 350,400, 350,950, 350,400, 350,400, 350,400, 300,1000, 350,400, 350,400, 300,1000, 300,1000, 350};
unsigned int Temp26[] = {4550,2550, 400,400, 300,1000, 350,950, 350,400, 350,950, 350,400, 350,400, 350,400, 300,450, 300,1000, 300,450, 300,400, 350,1000, 300,450, 300,400, 350,400, 350,950, 350,400, 350,950, 350,400, 350,1000, 300,400, 350,1000, 300,400, 350,1000, 300,400, 350,400, 350,400, 350,400, 350,950, 350,400, 350,400, 300,1000, 350,950, 350,400, 350,400, 350,400, 300,1000, 350,400, 350,950, 350,400, 350,400, 300,450, 300,1000, 300,450, 300,450, 300,1000, 300,1000, 350};
unsigned int Temp27[] = {4600,2500, 350,450, 300,1000, 350,950, 350,400, 350,950, 350,400, 350,400, 350,400, 350,400, 300,1000, 300,450, 300,450, 300,1000, 300,450, 300,400, 350,400, 350,400, 350,950, 350,1000, 300,400, 350,1000, 300,400, 350,1000, 300,450, 300,1000, 300,450, 300,400, 350,400, 350,400, 350,950, 350,400, 350,400, 350,950, 350,950, 350,400, 350,400, 350,400, 350,950, 350,400, 350,950, 350,400, 350,400, 350,400, 300,1000, 350,400, 300,450, 300,1000, 350,950, 350};
unsigned int Temp28[] = {4550,2550, 350,450, 300,1000, 300,1000, 350,400, 300,1000, 350,400, 350,400, 350,400, 300,450, 300,1000, 300,450, 300,400, 350,1000, 300,400, 350,400, 350,400, 350,400, 350,950, 350,950, 350,400, 350,950, 350,400, 350,1000, 300,400, 350,1000, 300,400, 350,400, 350,400, 350,400, 350,950, 350,400, 350,400, 300,1000, 350,950, 350,400, 350,400, 350,400, 300,1000, 350,400, 300,1000, 350,400, 350,400, 300,450, 300,1000, 300,450, 300,450, 300,1000, 300,1000, 300};
unsigned int Temp29[] = {4550,2550, 350,400, 350,1000, 300,1000, 300,450, 300,1000, 350,400, 350,400, 300,450, 300,400, 350,1000, 300,400, 350,400, 350,950, 350,400, 350,400, 350,400, 350,950, 350,950, 350,1000, 300,400, 350,1000, 300,450, 300,1000, 300,450, 300,1000, 300,450, 300,400, 350,400, 350,400, 350,950, 350,400, 350,400, 350,950, 350,1000, 300,400, 350,400, 350,400, 350,950, 350,400, 350,950, 350,400, 350,400, 350,400, 300,1000, 350,400, 350,400, 300,1000, 300,1000, 350};
unsigned int Temp30[] = {4600,2500, 400,400, 350,1000, 300,1000, 300,450, 300,1000, 300,450, 300,400, 350,400, 350,400, 350,950, 350,400, 350,400, 350,950, 350,400, 350,400, 350,400, 300,1000, 350,950, 350,950, 350,400, 350,1000, 300,400, 350,1000, 300,400, 350,1000, 300,400, 350,400, 350,400, 350,400, 350,950, 350,400, 350,400, 350,950, 350,950, 350,400, 350,400, 350,400, 300,1000, 350,400, 300,1000, 350,400, 350,400, 300,450, 300,1000, 300,450, 300,450, 300,1000, 300,1000, 350};
//Change it for your remote

IRsend irsend;

int Measured_temp;
int Measured_Humi;
int AC_Temp;
char temp_error = 2;
int Pev_value;
boolean AC = false;

int khz = 38; // 38kHz carrier frequency for the NEC protocol

void setup()
{
Serial.begin(9600);
display.begin(SSD1306_SWITCHCAPVCC);
display.clearDisplay();
}

void loop() {
  
  DHT.read11(DHT11_PIN); //Read the Temp and Humidity
  Measured_temp = DHT.temperature + temp_error;
  Measured_Humi = DHT.humidity;

// text display tests
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0,0);
  display.print("Temperature: "); display.print(Measured_temp);display.println("C");
  display.setCursor(0,10);
  display.print("Humidity: "); display.print(Measured_Humi);display.println("%");
  display.setCursor(0,20);
  display.print("AC Temp: "); display.print(AC_Temp);display.println("C");

  display.display();
  delay(500); 
  display.clearDisplay();
 
 if ((Measured_temp <= (Desired_temperature-3)) && AC == true) //If AC is turned on and temperature is less than 3 degree of Desired value #24 turn off
 {
  irsend.sendRaw(ACoff, sizeof(ACoff) / sizeof(ACoff[0]), khz);  delay(2000);//Send signal to Turn Off the AC
  AC_Temp = 0; AC=false;
 }

 if ((Measured_temp >= Desired_temperature+4) && AC == false) //If AC is off and measured Temp is greater than Desired Temp
 {
  irsend.sendRaw(ACon, sizeof(ACon) / sizeof(ACon[0]), khz); delay(2000); //Send Signal to Turn On the AC 
  delay(2000);
  irsend.sendRaw(Temp27, sizeof(Temp27) / sizeof(Temp27[0]), khz); //Send signal to set 27*C
  AC_Temp = 27; AC=true;
 }

if ( Measured_temp != Pev_value) //Change the temperature only if the measured voltage value changes
{

if (Measured_temp == Desired_temperature+3) //If AC is ON and measured temp is very very high than desired
{
   irsend.sendRaw(Temp24, sizeof(Temp24) / sizeof(Temp24[0]), khz); delay(2000);//Send signal to set 24*C
  AC_Temp = 24; 
}

if (Measured_temp == Desired_temperature+2) //If AC is ON and measured temp is very high than desired
{
   irsend.sendRaw(Temp25, sizeof(Temp25) / sizeof(Temp25[0]), khz); delay(2000);//Send signal to set 25*C
  AC_Temp = 25; 
}

if (Measured_temp == Desired_temperature+1) //If AC is ON and measured temp is very high than desired
{
   irsend.sendRaw(Temp26, sizeof(Temp26) / sizeof(Temp26[0]), khz); delay(2000);//Send signal to set 26*C
  AC_Temp = 26; 
}

if (Measured_temp == 27 ) //If AC is ON and measured temp is desired value
{
  irsend.sendRaw(Temp27, sizeof(Temp27) / sizeof(Temp27[0]), khz); //Send signal to set 27*C
  AC_Temp = 27; 
}

if (Measured_temp == Desired_temperature-1) //If AC is ON and measured temp is low than desired value
{
  irsend.sendRaw(Temp28, sizeof(Temp28) / sizeof(Temp28[0]), khz); delay(2000);//Send signal to set 28*C
  AC_Temp = 28; 
}

if (Measured_temp == Desired_temperature-2 ) //If AC is ON and measured temp is very low than desired value
{
  irsend.sendRaw(Temp29, sizeof(Temp29) / sizeof(Temp29[0]), khz); delay(2000);//Send signal to set 29*C
  AC_Temp = 29; 
}

if (Measured_temp == Desired_temperature-3 ) //If AC is ON and measured temp is very very low desired value
{
  irsend.sendRaw(Temp30, sizeof(Temp30) / sizeof(Temp30[0]), khz); delay(2000);//Send signal to set 30*C
  AC_Temp = 30; 
}

}
Pev_value = Measured_temp;
}

ssd 1306_128x64_i2c

/**************************************************************************
 This is an example for our Monochrome OLEDs based on SSD1306 drivers

 Pick one up today in the adafruit shop!
 ------> http://www.adafruit.com/category/63_98

 This example is for a 128x64 pixel display using I2C to communicate
 3 pins are required to interface (two I2C and one reset).

 Adafruit invests time and resources providing this open
 source code, please support Adafruit and open-source
 hardware by purchasing products from Adafruit!

 Written by Limor Fried/Ladyada for Adafruit Industries,
 with contributions from the open source community.
 BSD license, check license.txt for more information
 All text above, and the splash screen below must be
 included in any redistribution.
 **************************************************************************/

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels

// Declaration for an SSD1306 display connected to I2C (SDA, SCL pins)
// The pins for I2C are defined by the Wire-library. 
// On an arduino UNO:       A4(SDA), A5(SCL)
// On an arduino MEGA 2560: 20(SDA), 21(SCL)
// On an arduino LEONARDO:   2(SDA),  3(SCL), ...
#define OLED_RESET     4 // Reset pin # (or -1 if sharing Arduino reset pin)
#define SCREEN_ADDRESS 0x3D ///< See datasheet for Address; 0x3D for 128x64, 0x3C for 128x32
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

#define NUMFLAKES     10 // Number of snowflakes in the animation example

#define LOGO_HEIGHT   16
#define LOGO_WIDTH    16
static const unsigned char PROGMEM logo_bmp[] =
{ 0b00000000, 0b11000000,
  0b00000001, 0b11000000,
  0b00000001, 0b11000000,
  0b00000011, 0b11100000,
  0b11110011, 0b11100000,
  0b11111110, 0b11111000,
  0b01111110, 0b11111111,
  0b00110011, 0b10011111,
  0b00011111, 0b11111100,
  0b00001101, 0b01110000,
  0b00011011, 0b10100000,
  0b00111111, 0b11100000,
  0b00111111, 0b11110000,
  0b01111100, 0b11110000,
  0b01110000, 0b01110000,
  0b00000000, 0b00110000 };

void setup() {
  Serial.begin(9600);

  // SSD1306_SWITCHCAPVCC = generate display voltage from 3.3V internally
  if(!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }

  // Show initial display buffer contents on the screen --
  // the library initializes this with an Adafruit splash screen.
  display.display();
  delay(2000); // Pause for 2 seconds

  // Clear the buffer
  display.clearDisplay();

  // Draw a single pixel in white
  display.drawPixel(10, 10, SSD1306_WHITE);

  // Show the display buffer on the screen. You MUST call display() after
  // drawing commands to make them visible on screen!
  display.display();
  delay(2000);
  // display.display() is NOT necessary after every single drawing command,
  // unless that's what you want...rather, you can batch up a bunch of
  // drawing operations and then update the screen all at once by calling
  // display.display(). These examples demonstrate both approaches...

  testdrawline();      // Draw many lines

  testdrawrect();      // Draw rectangles (outlines)

  testfillrect();      // Draw rectangles (filled)

  testdrawcircle();    // Draw circles (outlines)

  testfillcircle();    // Draw circles (filled)

  testdrawroundrect(); // Draw rounded rectangles (outlines)

  testfillroundrect(); // Draw rounded rectangles (filled)

  testdrawtriangle();  // Draw triangles (outlines)

  testfilltriangle();  // Draw triangles (filled)

  testdrawchar();      // Draw characters of the default font

  testdrawstyles();    // Draw 'stylized' characters

  testscrolltext();    // Draw scrolling text

  testdrawbitmap();    // Draw a small bitmap image

  // Invert and restore display, pausing in-between
  display.invertDisplay(true);
  delay(1000);
  display.invertDisplay(false);
  delay(1000);

  testanimate(logo_bmp, LOGO_WIDTH, LOGO_HEIGHT); // Animate bitmaps
}

void loop() {
}

void testdrawline() {
  int16_t i;

  display.clearDisplay(); // Clear display buffer

  for(i=0; i<display.width(); i+=4) {
    display.drawLine(0, 0, i, display.height()-1, SSD1306_WHITE);
    display.display(); // Update screen with each newly-drawn line
    delay(1);
  }
  for(i=0; i<display.height(); i+=4) {
    display.drawLine(0, 0, display.width()-1, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  delay(250);

  display.clearDisplay();

  for(i=0; i<display.width(); i+=4) {
    display.drawLine(0, display.height()-1, i, 0, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  for(i=display.height()-1; i>=0; i-=4) {
    display.drawLine(0, display.height()-1, display.width()-1, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  delay(250);

  display.clearDisplay();

  for(i=display.width()-1; i>=0; i-=4) {
    display.drawLine(display.width()-1, display.height()-1, i, 0, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  for(i=display.height()-1; i>=0; i-=4) {
    display.drawLine(display.width()-1, display.height()-1, 0, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  delay(250);

  display.clearDisplay();

  for(i=0; i<display.height(); i+=4) {
    display.drawLine(display.width()-1, 0, 0, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }
  for(i=0; i<display.width(); i+=4) {
    display.drawLine(display.width()-1, 0, i, display.height()-1, SSD1306_WHITE);
    display.display();
    delay(1);
  }

  delay(2000); // Pause for 2 seconds
}

void testdrawrect(void) {
  display.clearDisplay();

  for(int16_t i=0; i<display.height()/2; i+=2) {
    display.drawRect(i, i, display.width()-2*i, display.height()-2*i, SSD1306_WHITE);
    display.display(); // Update screen with each newly-drawn rectangle
    delay(1);
  }

  delay(2000);
}

void testfillrect(void) {
  display.clearDisplay();

  for(int16_t i=0; i<display.height()/2; i+=3) {
    // The INVERSE color is used so rectangles alternate white/black
    display.fillRect(i, i, display.width()-i*2, display.height()-i*2, SSD1306_INVERSE);
    display.display(); // Update screen with each newly-drawn rectangle
    delay(1);
  }

  delay(2000);
}

void testdrawcircle(void) {
  display.clearDisplay();

  for(int16_t i=0; i<max(display.width(),display.height())/2; i+=2) {
    display.drawCircle(display.width()/2, display.height()/2, i, SSD1306_WHITE);
    display.display();
    delay(1);
  }

  delay(2000);
}

void testfillcircle(void) {
  display.clearDisplay();

  for(int16_t i=max(display.width(),display.height())/2; i>0; i-=3) {
    // The INVERSE color is used so circles alternate white/black
    display.fillCircle(display.width() / 2, display.height() / 2, i, SSD1306_INVERSE);
    display.display(); // Update screen with each newly-drawn circle
    delay(1);
  }

  delay(2000);
}

void testdrawroundrect(void) {
  display.clearDisplay();

  for(int16_t i=0; i<display.height()/2-2; i+=2) {
    display.drawRoundRect(i, i, display.width()-2*i, display.height()-2*i,
      display.height()/4, SSD1306_WHITE);
    display.display();
    delay(1);
  }

  delay(2000);
}

void testfillroundrect(void) {
  display.clearDisplay();

  for(int16_t i=0; i<display.height()/2-2; i+=2) {
    // The INVERSE color is used so round-rects alternate white/black
    display.fillRoundRect(i, i, display.width()-2*i, display.height()-2*i,
      display.height()/4, SSD1306_INVERSE);
    display.display();
    delay(1);
  }

  delay(2000);
}

void testdrawtriangle(void) {
  display.clearDisplay();

  for(int16_t i=0; i<max(display.width(),display.height())/2; i+=5) {
    display.drawTriangle(
      display.width()/2  , display.height()/2-i,
      display.width()/2-i, display.height()/2+i,
      display.width()/2+i, display.height()/2+i, SSD1306_WHITE);
    display.display();
    delay(1);
  }

  delay(2000);
}

void testfilltriangle(void) {
  display.clearDisplay();

  for(int16_t i=max(display.width(),display.height())/2; i>0; i-=5) {
    // The INVERSE color is used so triangles alternate white/black
    display.fillTriangle(
      display.width()/2  , display.height()/2-i,
      display.width()/2-i, display.height()/2+i,
      display.width()/2+i, display.height()/2+i, SSD1306_INVERSE);
    display.display();
    delay(1);
  }

  delay(2000);
}

void testdrawchar(void) {
  display.clearDisplay();

  display.setTextSize(1);      // Normal 1:1 pixel scale
  display.setTextColor(SSD1306_WHITE); // Draw white text
  display.setCursor(0, 0);     // Start at top-left corner
  display.cp437(true);         // Use full 256 char 'Code Page 437' font

  // Not all the characters will fit on the display. This is normal.
  // Library will draw what it can and the rest will be clipped.
  for(int16_t i=0; i<256; i++) {
    if(i == '\n') display.write(' ');
    else          display.write(i);
  }

  display.display();
  delay(2000);
}

void testdrawstyles(void) {
  display.clearDisplay();

  display.setTextSize(1);             // Normal 1:1 pixel scale
  display.setTextColor(SSD1306_WHITE);        // Draw white text
  display.setCursor(0,0);             // Start at top-left corner
  display.println(F("Hello, world!"));

  display.setTextColor(SSD1306_BLACK, SSD1306_WHITE); // Draw 'inverse' text
  display.println(3.141592);

  display.setTextSize(2);             // Draw 2X-scale text
  display.setTextColor(SSD1306_WHITE);
  display.print(F("0x")); display.println(0xDEADBEEF, HEX);

  display.display();
  delay(2000);
}

void testscrolltext(void) {
  display.clearDisplay();

  display.setTextSize(2); // Draw 2X-scale text
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(10, 0);
  display.println(F("scroll"));
  display.display();      // Show initial text
  delay(100);

  // Scroll in various directions, pausing in-between:
  display.startscrollright(0x00, 0x0F);
  delay(2000);
  display.stopscroll();
  delay(1000);
  display.startscrollleft(0x00, 0x0F);
  delay(2000);
  display.stopscroll();
  delay(1000);
  display.startscrolldiagright(0x00, 0x07);
  delay(2000);
  display.startscrolldiagleft(0x00, 0x07);
  delay(2000);
  display.stopscroll();
  delay(1000);
}

void testdrawbitmap(void) {
  display.clearDisplay();

  display.drawBitmap(
    (display.width()  - LOGO_WIDTH ) / 2,
    (display.height() - LOGO_HEIGHT) / 2,
    logo_bmp, LOGO_WIDTH, LOGO_HEIGHT, 1);
  display.display();
  delay(1000);
}

#define XPOS   0 // Indexes into the 'icons' array in function below
#define YPOS   1
#define DELTAY 2

void testanimate(const uint8_t *bitmap, uint8_t w, uint8_t h) {
  int8_t f, icons[NUMFLAKES][3];

  // Initialize 'snowflake' positions
  for(f=0; f< NUMFLAKES; f++) {
    icons[f][XPOS]   = random(1 - LOGO_WIDTH, display.width());
    icons[f][YPOS]   = -LOGO_HEIGHT;
    icons[f][DELTAY] = random(1, 6);
    Serial.print(F("x: "));
    Serial.print(icons[f][XPOS], DEC);
    Serial.print(F(" y: "));
    Serial.print(icons[f][YPOS], DEC);
    Serial.print(F(" dy: "));
    Serial.println(icons[f][DELTAY], DEC);
  }

  for(;;) { // Loop forever...
    display.clearDisplay(); // Clear the display buffer

    // Draw each snowflake:
    for(f=0; f< NUMFLAKES; f++) {
      display.drawBitmap(icons[f][XPOS], icons[f][YPOS], bitmap, w, h, SSD1306_WHITE);
    }

    display.display(); // Show the display buffer on the screen
    delay(200);        // Pause for 1/10 second

    // Then update coordinates of each flake...
    for(f=0; f< NUMFLAKES; f++) {
      icons[f][YPOS] += icons[f][DELTAY];
      // If snowflake is off the bottom of the screen...
      if (icons[f][YPOS] >= display.height()) {
        // Reinitialize to a random position, just off the top
        icons[f][XPOS]   = random(1 - LOGO_WIDTH, display.width());
        icons[f][YPOS]   = -LOGO_HEIGHT;
        icons[f][DELTAY] = random(1, 6);
      }
    }
  }
}

if you know i take this project from this website

WhatsApp Image 2021-11-28 at 21.09.56 (2)
WhatsApp Image 2021-11-28 at 21.09.56 (2)1280×960 131 KB

WhatsApp Image 2021-11-28 at 21.09.56 (1)
WhatsApp Image 2021-11-28 at 21.09.56 (1)960×1280 82.6 KB

WhatsApp Image 2021-11-28 at 21.09.56
WhatsApp Image 2021-11-28 at 21.09.56960×1280 84.1 KB

2

Go on. Please apply some honesty. Photo #2 shows 4-SPI configuration (which is probably how the new display came out of the box)

Photo #3 shows an incomplete I2C configuration i.e. omits R8.

I would expect Photo #2 to work fine with your second sketch.
I would not expect Photo #3 to work with i2c_scanner or with ssd 1306_128x64_i2c

Please say which photo is associated with which sketch.

Oh, there is little point in running a 7-pin as I2C. A new 7-pin runs SPI faster and easier than I2C.

David.

3

Is the OLED a 5V device?

4

I used the second photo OLED and it not running and when i check on i2scanner, it cannot detect my OLED, in serial monitor say No I2c device found. I dont know how to detect the problem and thank you reply to my message. i try touch my cabel to check connection but still nothing happen. i try using another OLED(photo 3)but still nothing happen and still in serial monitor say No I2c device found.

5

Nothing is plugged into SDA, SCL on the Mega.

6

Of course the OP has not said which photos are real.

Photo #2, #3 both show 5V regulators.

The SSD1306 datasheet specifies VDD: min = 1.65V max = 3.3V.
In an ideal world you use VDD=3.3V and 3.3V logic

However in practice it appears to work with VDD=3.3V and 5V logic.
This means high levels will conduct through the substrate diodes. I presume that these currents are limited to a safe level.

David.

7

I think it depends on your definition of "safe". Many 3.3V device specs provide a maximum clamping current value. If you dig deeper, often you find some language that discourages you from introducing any current there.

I never run OLEDs on 5V since I had one expensive unit fail on me. I know it's anecdotal, but the specifications do back up the prohibition. Lots of people do it, but there really isn't good feedback about the long term performance of projects built this way. My feeling is, it's okay for experiments, but if you are building some kind of final project, it's not a good idea.

8

I agree with you 100%. If the datasheet says VDD max=3.3V then the logic should be max 3.3V.

However most Ebay and AliExpress I2C modules provide a 3.3V regulator and have onboard I2C pullups.

Personally, I use 3.3V logic. But the Solomon Systech and Sino Weatlth chips seem to work on a 5V Uno.
When it comes to TFT Controllers, Ilitek just refuse to work with 5V logic.

I suspect that the OP will work just fine when configured correctly for I2C. But some of these boards do not provide the correct jumpers for SDA ACK. In which case you can use U8g2 library.

David.

9

I want to ask, if OLED are blue and my coding display.setTextColor (WHITE); Is this the reason OLEDs don't work

10

No.

Regardless of how your sketch and library attempts to configure the OLED, it should still be detected, if its in I2C mode by the I2C scanner.

11

i dont know how to fix my OLED but when i go upload ssd1306_128x64_spi, my OLED start function but when i using my project coding, my OLED not function. Idk how to fix this because im new to arduino. idont know whats the problem with my coding.

12

I have OLEDs that are WHITE, BLUE, YELLOW, and even YELLOW-BLUE.
When the software says BLACK it means dark, WHITE means lit.

I suggest that you run your 7-pin OLED as 4-Wire SPI.

If you want to use I2C, configure it correctly.
The obvious thing is to follow the printed instructions carefully.
I don't have your exact model. So I can't see if there is a design fault.

If you really want to use I2C, buy a 4-pin OLED in the first place.

David.

13

Nothing is plugged into SDA, SCL on the Mega. How can you expect anything to be detected there?

14

Go on. You can see that photo #1 shows the 4-Wire SPI from photo #2 (i.e. green tab)
And the Constructor is

Yes, I would be much happier if the OP actually quoted which photo goes with which sketch.
Photo #3 (I2C) has a blue tab.

Personally, I always remove the protective tabs as soon as I unpack the box.

David.

15

This topic was automatically closed 180 days after the last reply. New replies are no longer allowed.