Only one message when button pressed

Projects Programming
1

OK so, I have a DFRobot LCD Keypad Shield, but I want to have the serial monitor print when I press a button. I added some simple serial code into the program, but every time the switch is run it will print the output to the serial monitor. How do I change this so it only prints one message to serial, instead of one message every loop?

//Sample using LiquidCrystal library
#include <LiquidCrystal.h>

/*******************************************************

This program will test the LCD panel and the buttons
Mark Bramwell, July 2010

********************************************************/

// select the pins used on the LCD panel
LiquidCrystal lcd(8, 9, 4, 5, 6, 7);

// define some values used by the panel and buttons
int lcd_key     = 0;
int adc_key_in  = 0;
#define btnRIGHT  0
#define btnUP     1
#define btnDOWN   2
#define btnLEFT   3
#define btnSELECT 4
#define btnNONE   5

// read the buttons
int read_LCD_buttons()
{
 adc_key_in = analogRead(0);      // read the value from the sensor
 // my buttons when read are centered at these valies: 0, 144, 329, 504, 741
 // we add approx 50 to those values and check to see if we are close
 if (adc_key_in > 1000) return btnNONE; // We make this the 1st option for speed reasons since it will be the most likely result
 /* For V1.1 us this threshold
 if (adc_key_in < 50)   return btnRIGHT;
 if (adc_key_in < 250)  return btnUP;
 if (adc_key_in < 450)  return btnDOWN;
 if (adc_key_in < 650)  return btnLEFT;
 if (adc_key_in < 850)  return btnSELECT;
*/
 // For V1.0 comment the other threshold and use the one below:

 if (adc_key_in < 50)   return btnRIGHT;
 if (adc_key_in < 195)  return btnUP;
 if (adc_key_in < 380)  return btnDOWN;
 if (adc_key_in < 555)  return btnLEFT;
 if (adc_key_in < 790)  return btnSELECT;



 return btnNONE;  // when all others fail, return this...
}

void setup()
{
 lcd.begin(16, 2);              // start the library
 lcd.setCursor(0,0);
 lcd.print("Push the buttons"); // print a simple message
 Serial.begin(115200);
 Serial.println("LCD Shield Button Readout");
}

void loop()
{
 lcd.setCursor(9,1);            // move cursor to second line "1" and 9 spaces over
 lcd.print(millis()/100);      // display seconds elapsed since power-up


 lcd.setCursor(0,1);            // move to the begining of the second line
 lcd_key = read_LCD_buttons();  // read the buttons

 switch (lcd_key)               // depending on which button was pushed, we perform an action
 {
   case btnRIGHT:
     {
     lcd.print("RIGHT ");
     Serial.print(millis());
     Serial.println(" RIGHT");
     break;
     }
   case btnLEFT:
     {
     lcd.print("LEFT   ");
     Serial.print(millis());
     Serial.println("LEFT");
     break;
     }
   case btnUP:
     {
     lcd.print("UP    ");
     Serial.print(millis());
     Serial.println("UP");
     break;
     }
   case btnDOWN:
     {
     lcd.print("DOWN  ");
     Serial.print(millis());
     Serial.println("DOWN");
     break;
     }
   case btnSELECT:
     {
     lcd.print("SELECT");
     Serial.print(millis());
     Serial.println("SELECT");
     break;
     }
     case btnNONE:
     {
     lcd.print("NONE  ");
     break;
     }
 }

}
2

you need to detect the state CHANGE not just the state.

initialize previous_state to btnNONE in setup

in loop, check current_state.
if it's different than previous_state and it's a button press then display message and memorize the new previous_state.

3

Check the state change example that comes with the IDE

4

You want to do the switch statement only when 'lcd_key' changes.

int lcd_key     = 0;
int last_lcd_key = btnNONE; // Add this global

  // Down in loop(), after:
  lcd_key = read_LCD_buttons();  // read the buttons
  // Add these three lines:
  if (lcd_key != last_lcd_key)
  {
    last_lcd_key = lcd_key;
    // Before the switch:
    switch (lcd_key)               // depending on which button was pushed, we perform an action
    {

And then put a '}' after the switch/case statement to close the "if (lcd_key". Use Tools->Auto Format to fix up the indentation.