Probleme de compilation

International Français
1

Bonjour , j essais de compiler ce programme mais il arrete à
while (!LoRa.begin(BAND)) && (counter < 10){

, pourquoi ? j ai pas trouvé. Il me donne une erreur de
Compilation error: no matching function for call to 'LoRaClass::begin(double)'Downloading AsyncTCP@1.1.4

typ
void startLoRA() {
  //SPI LoRa pins
  SPI.begin(SCK, MISO, MOSI, CS);
  //setup LoRa transceiver module
  LoRa.setPins(CS, RST, DIO0);
 

  while (!LoRa.begin(BAND)) && (counter < 10){
    Serial.print(".");
    counter++;
    delay(500);
  }
  if (counter == 10) {
    // Increment readingID on every new reading
    readingID++;
    Serial.println("Starting LoRa failed!");
  }
  Serial.println("LoRa Initialization OK!");
  display.setCursor(0, 10);
  display.clearDisplay();
  display.print("LoRa Initializing OK!");
  display.display();
  delay(2000);
}
e or paste code here
2

Il faut fournir le code en entier, là on ne sait pas comment tu as déclaré LoRa ni quelles bibliothèques tu utilises. Il y en a visiblement une qui n'est pas utilisée correctement, c'est tout ce qu'on peut dire pour le moment.

3

Manifestement begin(), dans la librairie que tu utilises, n'attend pas un double comme argument.
Regarde les exemples installés avec cette librairie.

4

Il faudrait savoir aussi quelle carte est utilisée : un ESP32 ?

image
image800×800 80.4 KB

Mais ça peut aussi être un module LoRa connecté à un Uno.
Je retrouve le code que tu as posté ici :

La bibliothèque LoRa.h attend un long:
int begin(long frequency);

On trouve ces valeurs, qui dépendent de l'endroit où on les utilise (ce sont des valeurs de fréquence en MHz: 433, 866 ou 915 MHz.

//433E6 for Asia
//866E6 for Europe
//915E6 for North America
#define BAND 915E6

Pour toi, ce sera probablement
#define BAND 866E6

5

C est bel et bien un heltec lora 32 .
mais pourquoi la compilation ne se fait pas?
et oui pour la frequence ici c est bien 915E6

6

Cest quoi que tu veux dire par double?

7

J ai essayer de mettre 915E6 a la place du BAND mais ca a bloqué aussi. C est quoi vous voulez dire par un double?

8
9

...

10 
//Libraries for LoRa
#include <SPI.h>
#include <LoRa.h>

//Libraries for OLED Display
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

//Libraries for BME280
#include <Adafruit_Sensor.h>
#include <Adafruit_BME280.h>

//define the pins used by the LoRa transceiver module
#define SCK 5
#define MISO 19
#define MOSI 27
#define SS 18
#define RST 14
#define DIO0 26

//433E6 for Asia
//866E6 for Europe
//915E6 for North America
#define BAND 866E6

//OLED pins
#define OLED_SDA 4
#define OLED_SCL 15 
#define OLED_RST 16
#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels

//BME280 definition
#define SDA 21
#define SCL 13

TwoWire I2Cone = TwoWire(1);
Adafruit_BME280 bme;

//packet counter
int readingID = 0;

int counter = 0;
String LoRaMessage = "";

float temperature = 0;
float humidity = 0;
float pressure = 0;

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RST);

//Initialize OLED display
void startOLED(){
  //reset OLED display via software
  pinMode(OLED_RST, OUTPUT);
  digitalWrite(OLED_RST, LOW);
  delay(20);
  digitalWrite(OLED_RST, HIGH);

  //initialize OLED
  Wire.begin(OLED_SDA, OLED_SCL);
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3c, false, false)) { // Address 0x3C for 128x32
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }
  display.clearDisplay();
  display.setTextColor(WHITE);
  display.setTextSize(1);
  display.setCursor(0,0);
  display.print("LORA SENDER");
}

//Initialize LoRa module
void startLoRA(){
  //SPI LoRa pins
  SPI.begin(SCK, MISO, MOSI, SS);
  //setup LoRa transceiver module
  LoRa.setPins(SS, RST, DIO0);

  while (!LoRa.begin(BAND) && counter < 10) {
    Serial.print(".");
    counter++;
    delay(500);
  }
  if (counter == 10) {
    // Increment readingID on every new reading
    readingID++;
    Serial.println("Starting LoRa failed!"); 
  }
  Serial.println("LoRa Initialization OK!");
  display.setCursor(0,10);
  display.clearDisplay();
  display.print("LoRa Initializing OK!");
  display.display();
  delay(2000);
}

void startBME(){
  I2Cone.begin(SDA, SCL, 100000); 
  bool status1 = bme.begin(0x76, &I2Cone);  
  if (!status1) {
    Serial.println("Could not find a valid BME280_1 sensor, check wiring!");
    while (1);
  }
}

void getReadings(){
  temperature = bme.readTemperature();
  humidity = bme.readHumidity();
  pressure = bme.readPressure() / 100.0F;
}

void sendReadings() {
  LoRaMessage = String(readingID) + "/" + String(temperature) + "&" + String(humidity) + "#" + String(pressure);
  //Send LoRa packet to receiver
  LoRa.beginPacket();
  LoRa.print(LoRaMessage);
  LoRa.endPacket();
  
  display.clearDisplay();
  display.setCursor(0,0);
  display.setTextSize(1);
  display.print("LoRa packet sent!");
  display.setCursor(0,20);
  display.print("Temperature:");
  display.setCursor(72,20);
  display.print(temperature);
  display.setCursor(0,30);
  display.print("Humidity:");
  display.setCursor(54,30);
  display.print(humidity);
  display.setCursor(0,40);
  display.print("Pressure:");
  display.setCursor(54,40);
  display.print(pressure);
  display.setCursor(0,50);
  display.print("Reading ID:");
  display.setCursor(66,50);
  display.print(readingID);
  display.display();
  Serial.print("Sending packet: ");
  Serial.println(readingID);
  readingID++;
}

void setup() {
  //initialize Serial Monitor
  Serial.begin(115200);
  startOLED();
  startBME();
  startLoRA();
}
void loop() {
  getReadings();
  sendReadings();
  delay(10000);
}
11

As-tu testé les exemples de la bibliothèque LoRa.h auparavant ?

Si tu as deux modules, tu devrais tester ce tutoriel :

12

Le problème venait d un sketch copié. J ai pris la version originale de l auteur et ca fonctionne. merci a tous

13

This topic was automatically closed 180 days after the last reply. New replies are no longer allowed.