Proximity sensor serial print output

[nice_servo]

Hi, i am using a proximity sensor... Its closed NPN.... when it senses i can see its red light turn on but this code is not printing anything in serial:

Wiring (brown in 5v, blue in GRD, black in pin 2) * all online tutorials say the same wiring.

#define inputPin  2

void setup() {
  Serial.begin(9600);
  // put your setup code here, to run once:
pinMode(inputPin, INPUT);
}

void loop() {
  // put your main code here, to run repeatedly:
 digitalRead(inputPin);


if (inputPin == LOW) {
  Serial.println( "None" );
  delay(1000);
}

if (inputPin == HIGH) {
  Serial.println( "Detected" );
  delay(1000);
}

}

[lastchancename]

From the code, I’m guessing you have an external input pullup resistor?

[kolaha]

#define inputPin  2

void setup() {
  Serial.begin(9600);
  pinMode(inputPin, INPUT);
}

void loop() {
  if (digitalRead(inputPin) == LOW)     Serial.println( "None" );
  else Serial.println( "Detected" );
 }

[nice_servo]

Thanks, i just had to switch your high to low. and it didnt need the last line - i commented it. It is just frustrating that my original code didnt work. But thank you, yours works.

void loop() {
  if (digitalRead(inputPin) == LOW)     
  Serial.println( "Detected" );
  else Serial.println( "None" );
  //digitalRead(inputPin);
}

[StefanL38]

I added comments to your original code that explain what your code does

@nice_servo

void loop() {
  // put your main code here, to run repeatedly:
 digitalRead(inputPin); // read the state of the IO-pin specified with constant inputPin after reading throw the result away

 digitalRead(inputPin); with your 
#define inputPin  2
this is the same as

 digitalRead(2); 

if (inputPin == LOW) {  // compare the value of constant inputPin with the value "LOW"
// which means compare 2 == 0   ==> always false
  Serial.println( "None" );
  delay(1000);
}

if (inputPin == HIGH) {   // compare the value of constant inputPin with the value "LOW"
// which means compare 2 == 1   ==> always false
  Serial.println( "Detected" );
  delay(1000);
}

.
if (inputPin == LOW) {
.
with your definition
#define inputPin 2
this is the same as

if (2 == LOW) {
.
.
.
if (inputPin == HIGH) {
with your definition
#define inputPin 2
this is the same as
if (2 == HIGH) {

kolaha showed the most compact version
your original code works if you use a variable that stores the IO-pin-state in this variable

#define inputPin  2

byte myIO_PinState; // variable to store the state of the IO-pin

void setup() {
  Serial.begin(9600);
  pinMode(inputPin, INPUT);
}

void loop() {
  myIO_PinState = digitalRead(inputPin); // store value of IO-pin 2 into variable named "myIO_PinState"

  if (myIO_PinState == HIGH) {
    Serial.println( "None" );
    delay(1000); // blockate = disable code-execution for 1 second
  }

  if (myIO_PinState == LOW) {
    Serial.println( "Detected" );
    delay(1000); // blockate = disable code-execution for 1 second
  }
}

delay() does blockate = disable code-exection for the specified time

a non-blocking way of doing things from time to time is shown in this code-version
How this works can be read here

Example-code for timing based on millis() easier to understand through the use of example-numbers / avoiding delay()

non-blocking timing. Execute code only from time to time. There are a lot of different ways to learn programming. This thread wants to add another approach that is different to the yet existing ones. UPDATE 06.01.2023 if you are mainly interested in applying non-blocking timing you can do a quick read of this short tutorial / demonstration If you are intersted in understanding the details how it works go on reading here. I use an everyday analogon in this post to explain the basic princip…

#define inputPin  2

byte myIO_PinState;  // variable to store the state of the IO-pin
unsigned long MyPrintTimer = 0; // Timer-variables MUST be of type unsigned long


boolean TimePeriodIsOver (unsigned long &expireTime, unsigned long TimePeriod) {
  unsigned long currentMillis  = millis();
  if ( currentMillis - expireTime >= TimePeriod ) {
    expireTime = currentMillis; // set new expireTime
    return true;                // more time than TimePeriod) has elapsed since last time if-condition was true
  }
  else return false;            // not expired
}


void setup() {
  Serial.begin(9600);
  Serial.println( F("Setup-Start") );
  pinMode(inputPin, INPUT);
  MyPrintTimer = millis(); // initialise timer-variable with actual snapshot of time
}

void loop() {
  myIO_PinState = digitalRead(inputPin); // store value of IO-pin 2 into variable named "myIO_PinState"

  if ( TimePeriodIsOver(MyPrintTimer, 1000) ) {
    // if 1000 milliseconds time have passed by
    // execute code below
    if (myIO_PinState == HIGH) {
      Serial.println( "None" );
    }
    else { // myIO_PinState has a different value than "HIGH"
      Serial.println( "Detected" );
    }
  }
}

Be the change you want to see in the world
best regards Stefan