Ambas se leen en digital. en PPM se utiliza solo un pin , en PWM un pin por cada canal.
buscate el proyecto de multiwii copter, es el que hice yo. el código te permite leer los datos del receptor en ambos casos. echale un vistazo al codigo y puedes hacerte una idea de como hacerlo .
Un saludo ¡
Por lo que he leido en vuestras respuestas diria que estoy leyendo PWM ya que tengo un cable de señal por cada canal y ya que segun decis se leen en pin digital he probado con el codigo:
void setup() {
Serial.begin(9600);
pinMode(9,INPUT);
}
void loop() {
int sensorValue =analogRead(9); // He probado tanto analogRead como digitalRead;
Serial.println(sensorValue);
delay(1000);
}
Pero lo único que me muestra por el serial son valores aleatorio =(
no te has mirado lo que te he dicho …
mírate el código para ver de que manera obtiene los valores de cada uno de los canales.
Os lo tenemos que dar todo mascao…
el codigo viene comentado, vienen las dos formas de obtener los datos
un saludo
pd: hay una version 7 de este codigo pero actualiza otras cosas, buscala de todas formas y le echas un vistazo
tambien tiene un software con el cual puedes ver el valor de los sensores , acelerometros, posicion de los sticks etc .
un saludo
MultiWii_1_6.pde (72.4 KB)
una pista ...
// ****************** // rc functions // ******************
Si, he estado mirando el codigo SrDonGato pero nose que tengo que sacar de ahi ya que si el arduino me diera valores proporcionales al potenciometro de la emisora ya sabria que codigo ponerle, el problema es que el arduino ni se inmuta a los cambios de la emisora simplemente me devuelve 0.
La forma que tienes de ver el estado del pin es si está a 0 o 1 en un determinado momento.
Te has fijado como son las señales PWM y PPM ?, debes fijarte primero que es lo que queires leer por esa patilla.
aqui tienes un codigo que saque de no me acuerdo donde para leer una señal PPM, normalmente tienes que abrir el receptor para obtener la señal del pin de un chip que tiene interno, que es el que decodifica de PPM a PWM a cada canal. la ventaja del PPM es que con 1 entrada digital obtienes los valores de todos los canales. con PWM obtienes el valor de 1 solo canal por lo que necesitas tantas entradas digitales como canales tenga tu radio .
#define channumber 6 //Cuantos canales tiene tu radio???????/How many channels have your radio???
#define filter 10 // Filtro anti salto/ Glitch Filter
int channel[channumber]; //Valores de canales leidos/ readed Channel values
int lastReadChannel[channumber]; //Ultima lectura obtenida/ Last values readed
int conta=0; //Contador/couter
void setup()
{
Serial.begin(9600); //Iniciamos com serial/ Serial Begin
pinMode(4, INPUT); //Patita 4 como entrada / Pin 4 as input
pinMode(13, OUTPUT); // Led pin 13
}
void loop()
{
if(pulseIn(4, HIGH) > 3000) //Si el pulso del pin 4 es > 3000 usegundos continua /If pulse > 3000 useconds, continues
{
for(int i = 0; i <= channumber-1; i++) //lee los pulsos de los canales / Read the pulses of the channels
{
channel[i]=pulseIn(4, HIGH);
}
for(int i = 0; i <= channumber-1; i++) //Promedia los pulsos/Average the pulses
{
if((channel[i] > 2000) || (channel[i] <100))//Si se pasa del rango envia ultimo pulso/ If channel > max range, chage the value to the last pulse
{
channel[i]= lastReadChannel[i];
}
else
{
channel[i]=(lastReadChannel[i]+channel[i])/2; //Promedio el pulso pasado con el nuevo pulso/Average the last pulse eith the current pulse
conta++; //Incrementa el contador/ increment counter
}
}
}
if(conta > filter)//Si el contador es mayor al filtro imprime valores/ If counter is > than filter, then prints values
{
for(int i = 0; i <= channumber-1; i++) //Ciclo para imprimir valores/Cycle to print values
{
Serial.print("CH"); //Canal/Channel
Serial.print(i+1); // Numero del canal / Channel number
Serial.print(": "); // que te importa
Serial.println(channel[i]);
lastReadChannel[i]=channel[i];
}
if(channel[4] > 1000) //si el canal 5 tiene un rango mayor a 500 enciende el LED/ If channel 5 is > than 500 turn on the led
{
digitalWrite(13, HIGH);
}
else
{
digitalWrite(13, LOW);//Si no lo apaga/If not turn it off
}
delay(400); //Delay
conta=0;//Reinicia el contador/ Restart couter.
}
}
a ver si te encuentro lo otro ...
// ******************
// rc functions
// ******************
#define MINCHECK 1100
#define MAXCHECK 1900
static uint8_t pinRcChannel[8] = {ROLLPIN, PITCHPIN, YAWPIN, THROTTLEPIN, AUX1PIN,AUX2PIN,CAM1PIN,CAM2PIN};
volatile uint16_t rcPinValue[8] = {1500,1500,1500,1500,1500,1500,1500,1500}; // interval [1000;2000]
static int16_t rcData[8] ; // interval [1000;2000]
static int16_t rcCommand[4] ; // interval [1000;2000] for THROTTLE and [-500;+500] for ROLL/PITCH/YAW
static int16_t rcHysteresis[8] ;
static int16_t rcData4Values[8][4];
static uint8_t rcRate8;
static uint8_t rcExpo8;
static float rcFactor1;
static float rcFactor2;
// ***PPM SUM SIGNAL***
#ifdef SERIAL_SUM_PPM
static uint8_t rcChannel[8] = {SERIAL_SUM_PPM};
#endif
volatile uint16_t rcValue[8] = {1500,1500,1500,1500,1500,1500,1500,1500}; // interval [1000;2000]
// Configure each rc pin for PCINT
void configureReceiver() {
#ifndef SERIAL_SUM_PPM
for (uint8_t chan = 0; chan < 8; chan++)
for (uint8_t a = 0; a < 4; a++)
rcData4Values[chan][a] = 1500; //we initiate the default value of each channel. If there is no RC receiver connected, we will see those values
#if defined(PROMINI)
// PCINT activated only for specific pin inside [D0-D7] , [D2 D4 D5 D6 D7] for this multicopter
PORTD = (1<<2) | (1<<4) | (1<<5) | (1<<6) | (1<<7); //enable internal pull ups on the PINs of PORTD (no high impedence PINs)
PCMSK2 |= (1<<2) | (1<<4) | (1<<5) | (1<<6) | (1<<7);
PCICR = 1<<2; // PCINT activated only for the port dealing with [D0-D7] PINs
#endif
#if defined(MEGA)
// PCINT activated only for specific pin inside [A8-A15]
DDRK = 0; // defined PORTK as a digital port ([A8-A15] are consired as digital PINs and not analogical)
PORTK = (1<<0) | (1<<1) | (1<<2) | (1<<3) | (1<<4) | (1<<5) | (1<<6) | (1<<7); //enable internal pull ups on the PINs of PORTK
PCMSK2 |= (1<<0) | (1<<1) | (1<<2) | (1<<3) | (1<<4) | (1<<5) | (1<<6) | (1<<7);
PCICR = 1<<2; // PCINT activated only for PORTK dealing with [A8-A15] PINs
#endif
#else
PPM_PIN_INTERRUPT
#endif
}
#ifndef SERIAL_SUM_PPM
ISR(PCINT2_vect) { //this ISR is common to every receiver channel, it is call everytime a change state occurs on a digital pin [D2-D7]
uint8_t mask;
uint8_t pin;
uint16_t cTime,dTime;
static uint16_t edgeTime[8];
static uint8_t PCintLast;
#if defined(PROMINI)
pin = PIND; // PIND indicates the state of each PIN for the arduino port dealing with [D0-D7] digital pins (8 bits variable)
#endif
#if defined(MEGA)
pin = PINK; // PINK indicates the state of each PIN for the arduino port dealing with [A8-A15] digital pins (8 bits variable)
#endif
mask = pin ^ PCintLast; // doing a ^ between the current interruption and the last one indicates wich pin changed
sei(); // re enable other interrupts at this point, the rest of this interrupt is not so time critical and can be interrupted safely
PCintLast = pin; // we memorize the current state of all PINs [D0-D7]
cTime = micros(); // micros() return a uint32_t, but it is not usefull to keep the whole bits => we keep only 16 bits
// mask is pins [D0-D7] that have changed // the principle is the same on the MEGA for PORTK and [A8-A15] PINs
// chan = pin sequence of the port. chan begins at D2 and ends at D7
if (mask & 1<<2) //indicates the bit 2 of the arduino port [D0-D7], that is to say digital pin 2, if 1 => this pin has just changed
if (!(pin & 1<<2)) { //indicates if the bit 2 of the arduino port [D0-D7] is not at a high state (so that we match here only descending PPM pulse)
dTime = cTime-edgeTime[2]; if (900<dTime && dTime<2200) rcPinValue[2] = dTime; // just a verification: the value must be in the range [1000;2000] + some margin
} else edgeTime[2] = cTime; // if the bit 2 of the arduino port [D0-D7] is at a high state (ascending PPM pulse), we memorize the time
if (mask & 1<<4) //same principle for other channels // avoiding a for() is more than twice faster, and it's important to minimize execution time in ISR
if (!(pin & 1<<4)) {
dTime = cTime-edgeTime[4]; if (900<dTime && dTime<2200) rcPinValue[4] = dTime;
} else edgeTime[4] = cTime;
if (mask & 1<<5)
if (!(pin & 1<<5)) {
dTime = cTime-edgeTime[5]; if (900<dTime && dTime<2200) rcPinValue[5] = dTime;
} else edgeTime[5] = cTime;
if (mask & 1<<6)
if (!(pin & 1<<6)) {
dTime = cTime-edgeTime[6]; if (900<dTime && dTime<2200) rcPinValue[6] = dTime;
} else edgeTime[6] = cTime;
if (mask & 1<<7)
if (!(pin & 1<<7)) {
dTime = cTime-edgeTime[7]; if (900<dTime && dTime<2200) rcPinValue[7] = dTime;
} else edgeTime[7] = cTime;
#if defined(MEGA)
if (mask & 1<<0)
if (!(pin & 1<<0)) {
dTime = cTime-edgeTime[0]; if (900<dTime && dTime<2200) rcPinValue[0] = dTime;
} else edgeTime[0] = cTime;
if (mask & 1<<1)
if (!(pin & 1<<1)) {
dTime = cTime-edgeTime[1]; if (900<dTime && dTime<2200) rcPinValue[1] = dTime;
} else edgeTime[1] = cTime;
if (mask & 1<<3)
if (!(pin & 1<<3)) {
dTime = cTime-edgeTime[3]; if (900<dTime && dTime<2200) rcPinValue[3] = dTime;
} else edgeTime[3] = cTime;
#endif
}
#else
void rxInt() {
uint16_t now,diff;
static uint16_t last = 0;
static uint8_t chan = 0;
now = micros();
diff = now - last;
last = now;
if(diff>5000) chan = 0;
else {
if(900<diff && diff<2200 && chan<8 ) rcValue[chan] = diff;
chan++;
}
}
#endif
uint16_t readRawRC(uint8_t chan) {
uint16_t data;
uint8_t oldSREG;
oldSREG = SREG;
cli(); // Let's disable interrupts
#ifndef SERIAL_SUM_PPM
data = rcPinValue[pinRcChannel[chan]]; // Let's copy the data Atomically
#else
data = rcValue[rcChannel[chan]];
#endif
SREG = oldSREG;
sei();// Let's enable the interrupts
return data; // We return the value correctly copied when the IRQ's where disabled
}
void computeRC() {
static uint8_t rc4ValuesIndex = 0;
uint8_t chan,a;
rc4ValuesIndex++;
for (chan = 0; chan < 8; chan++) {
rcData4Values[chan][rc4ValuesIndex%4] = readRawRC(chan);
rcData[chan] = 0;
for (a = 0; a < 4; a++)
rcData[chan] += rcData4Values[chan][a];
rcData[chan]= (rcData[chan]+2)/4;
if ( rcData[chan] < rcHysteresis[chan] -4) rcHysteresis[chan] = rcData[chan]+2;
if ( rcData[chan] > rcHysteresis[chan] +4) rcHysteresis[chan] = rcData[chan]-2;
}
#if defined(FORCE_LEVEL)
rcData[AUX1] = 2000;
#endif
}
los valores de los canales los guarda en rcData[chan] siendo chan el número de canal .
Si quieres hacer el quadcopter y no tienes mucha idea de programacion lo vas a tener complicado. mirate el wiicopter , funcina muy bien , los sensores son baratos ( los de la wii) y ya tienes el codigo hecho, ademas un software para ver el estado de los sensores y motores, posicion del aparato etc.
un saludo
Ya he conseguido leer un dato proporcional a la acción sobre la emisora, gracias por todo y disculpa las molestias SrDonGato la inforamación que me has dado me ha sido muy útil para solucionar el problema.
PD: Gracias también a los demás por vuestras aportaciones.
SrDonGato, te veo puesto en el tema, cuando menos lo has usado y practicado. Aprovecho para hacerte unas consultas. Decirte que ahora estoy escribiendo desde un móvil y no veo las ventanas de código enteras (no me aparecen las barras de desplazamiento).
Entiendo que el primer código que has puesto lee PPM y el segundo no tengo claro si es el del proyecto wiicopter y por tanto está preparado para leer tanto PPM como PWM tal como decías más arriba.
Además de la diferencia de necesitar un sólo pin para PPM (ventaja para este método) pero no tener que acceder al interior del receptor y localizar la señal PPM en el caso de las PWM (ventaja para este otro método), ¿sabes o has notado si uno u otro método tiene más precisión, fiabilidad, o menor exigencia del arduino?
Sobre el proyecto del wiicopter comentas que lo hiciste. Una duda. ¿Todos los cálculos se realizan sobre una sóla tarjeta arduino? Entiendo que en este proyecto hacen todo, el IMU con los acelerómetros y gyros aplicando no sé si filtro Kalman o sistema de cosenos directores, lectura de canales RC y cálculos PID. No sé si me dejo algún otro cálculo que exija en gran medida a arduino.
adrib: disculpa las molestias SrDonGato
No son mmolestias atrib ¡¡ mas que ponemos soluciones y no las miráis, estamos para ayudar :) para cuando querais
Cheyenne, la placa de arduino hace todo, lee la radio, lee los sensores a traves de I2C, los acelerometros, giroscopos, sensores barométricos etc etc.
el codigo tiene la particularidad de que es configurable para cualquier modelo, activas y desactivas opciones al principio del codigo segun lo tengas construido, tiene en cuenta las tensiones de las celdas de las lipos, un pequeño zumbador etc.
solo la placa de aruino hace todo, todos los calculos y demas. hay muchos videos en youtube y puedes ver los resultados de como vuelan. yo aun no he conseguido poner bien los parametros pid bien, ademas lo tengo parado desde que se me rompieron las helices, estoy esperando un nuevo pedido porque solas me salen por un ojo la cara.
Sin saber mucho de programacion ( yo tampoco soy un gurú) es fácil el montaje y la configuracion del mismo a traves el programa que hn hecho a tal efecto, y puedes ver los valores de las configuraciones, los valores de los sticks y los valores comandados a los motores.
se han currado mucho el codigo .
un saludo ¡
Veo mucha confusión con el tema del PWM y el radio control, a ver si arrojo un poco de luz sobre esto hasta llegar al capítulo de mi curso en el que lo explicaré con todo lujo de detalles.
En un sistema de RC (Radio Control) las PWM se utilizan SOLO entre el variador y el motor, para NADA más.
Tampoco se utiliza PPM. Esto es algo parecido, pero no es igual.
Toda la comunicación física entre elementos de RC (receptor, servos, variadores, giróscopos, mezcladores, inversores de servos, etc) se hace por un particular tren de pulsos: un pulso de entre 1 y 2 milisegundos, una pausa de 20 milisegundos. Ya está, no tiene ninguna otra complicación.
Para leer las señales que emite un receptor hacia sus periféricos basta con programar un control de tiempos con las entradas digitales o utilizar el comando pulseIn(), aunque este último puede dar problemas a la hora de leer varios canales a la vez.
Por favor, no me volvais a mezclar PWMs con servos o receptores, que hace que me duela la vista.
Un saludo.
josemanu:
Veo mucha confusión con el tema del PWM y el radio control, a ver si arrojo un poco de luz sobre esto hasta llegar al capítulo de mi curso en el que lo explicaré con todo lujo de detalles.En un sistema de RC (Radio Control) las PWM se utilizan SOLO entre el variador y el motor, para NADA más.
Tampoco se utiliza PPM. Esto es algo parecido, pero no es igual.
Toda la comunicación física entre elementos de RC (receptor, servos, variadores, giróscopos, mezcladores, inversores de servos, etc) se hace por un particular tren de pulsos: un pulso de entre 1 y 2 milisegundos, una pausa de 20 milisegundos. Ya está, no tiene ninguna otra complicación.
Si parece que hay un error de conceptos …
al variador como a los servos hay que entregarle una señal PWM par hacerlos funcionar, el variador entregará al motor una fuerza-velocidad proporcional al ancho del pulso que se le entrega, en el caso de los servos la posicion del servo es proporcional al ancho del pulso que se le entrega.
La señal PWM en RC tiene una frecuencia de 50 hz, aunque esta frecuencia puede ser variable, es decir tiene un periodo de 20 milisegundos., y no una pausa como dice josemanu, en esos 20 milisegundos en PPM tiene que haber un pulso por cada canal que tengamos en la emisora.
Las emisoras emiten en PPM, es el receptor el que se ocupa de convertir las señales PPM en PWM, una por cada canal.
En un sistema de RC (Radio Control) las PWM se utilizan SOLO entre el variador y el motor, para NADA más.
No es cierto del todo, la señal que se entrega al motor varia en frecuencia y tensión, en algunos casos se utiliza una señal PWM interna para generar una onda senoidal, pero son técnicas de paso de D/A.
puedes ver un articulo de tecnicas para el control de los mismos en Domain Registered at Safenames y Domain Registered at Safenames
Os dejo un ejemplo de como obtener la señal PPM de un receptor RC. En algunos casos en necesaria amplificarla para utilizarla.
http://forum.mikrokopter.de/topic-2747.html
y una gráfica para entender como pasa el chip del receptor de señal PPM a PWM y como se generan, como se puede ver las señales PWM de todos los canales no empiezan a la misma vez, sino que se concatenan, cuando hay un flanco de bajada del canal anterior empieza el canal siguiente, aun así mantienen todas la misma frecuencia.
Espero que todo se haya aclarado. Un saludo
Coincido con lo explicado por SrDonGato, funcionamiento de emisión PPM, conversión a PWM a cada canal a frecuencia 50 Hz.
Muy interesantes los PDFs sobre generación de señales PWM para motores brushless... pero esas señales las genera el variador y se las manda al motor.
al variador como a los servos hay que entregarle una señal PWM par hacerlos funcionar
No, no y no. Es lo que intentaba aclarar: una señal modulada por ancho de pulso (PWM) sirve para "simular" una señal analógica mediante una digital... y eso no funciona ni con servos ni con receptores.
Una señal de Modulación por Posición de Pulso (PPM) es un tipo de modulación en la cual una palabra de R bits es codificada por la transmisión de un único pulso que puede encontrarse en alguna de las 2M posiciones posibles.... se parece mucho, pero no es lo mismo. Por mucho que en el foro de mikrocopter lo llamen PPM no es PPM.
Cometí un error en mi explicación: no es pulso, pausa, pulso, pausa, etc..... Es cada 20 milisegundos un flanco de subida, un pulso que dura entre 1 y 2 milisegundos, y se repite. No es PWM por que no se simula una salida analógica y no es PPM por que el pulso emitido está siempre en la misma posición, varía su anchura no su posición. Para ser PPM el pulso siempre tiene la misma anchura pero varía su posición.
Gráfico:
Puede ser confundido con una señal PWM por que modula en ancho del pulso dentro de sus intervalos de 20ms, pero no es lo mismo ni se le parece a la señal PWM que generan los pines 3, 5, 6, 9, 10 y 11. De hecho para controlar un servo o un variador no se necesita utilizar esos pines, se puede utilizar cualquiera.
Buscando en la Wikipedia resulta que también llaman PWM a la señal de control de RC, aunque especifican que es una señal PWM de 50hz. Vale, quizá sea correcto, no quiero entrar en tanto detalle.
La cuestión es que la señal de control de RC si la llamamos PWM se confunde directamente con la señal que generan los pines PWM de Arduino al dar una orden analogWrite().
Por eso (no por nada más) insisto e insistiré siempre en no llamar PWM a la señal de control en RC. Ateniendonos a definiciones en mucho más correcto decir que la señal de RC es un "Tren de Pulsos".
Uf..... a ver si ahora queda claro.
No es PWM por que no se simula una salida analógica
Vamos a ver .. que un tipo de señal tenga determinados usos no quiere decir que si se utiliza para otra cosa no sea PWM, Es un tipo de codificación digital y su característica es que es de FRECUENCIA FIJA y que lo que varía es el dutty-cicle, esto es, el tiempo que permanece en nivel alto y nvel bajo. Cierto que esta señal se aplica mucho en control de potencia... que si ... pero no quiere decir que no se utilice para otras cosas, en etapas de potencia se utiliza para atacar los triacks o IGBTs , la salida de estos se aplica a un filtro y se obtiene así una onda senoidal. en RC la señal que se aplican a servos y variados son PWM, es una aplicacion más.
y no es PPM por que el pulso emitido está siempre en la misma posición, varía su anchura no su posición. Para ser PPM el pulso siempre tiene la misma anchura pero varía su posición.
Puede ser confundido con una señal PWM por que modula en ancho del pulso dentro de sus intervalos de 20ms, pero no es lo mismo ni se le parece a la señal PWM que generan los pines 3, 5, 6, 9, 10 y 11. De hecho para controlar un servo o un variador no se necesita utilizar esos pines, se puede utilizar cualquiera.
El utilizar los pines de arduino con salida PWM es por simplificar el código, el atmega lo genera por hardware, de esa manera nos despreocupamos en el código de calcular tiempos y poner a 0 o 1 los pines, pero claro está que lo puedes hacer con cualquier salida digital.
Las distintas codificaciones digitales no tienen un uso específico, cada una tiene una característica pero se puede utilizar para la aplicación que queramos. nombrar por ejemplo FSK, PSK, QAM que no tienen una única aplicación .
Un saludo
De acuerdo en que la señal de control de RC, si nos ceñimos a las definiciones establecidas, es una señal PWM de 50Hz.
El utilizar los pines de arduino con salida PWM es por simplificar el código, el atmega lo genera por hardware, de esa manera nos despreocupamos en el código de calcular tiempos y poner a 0 o 1 los pines, pero claro está que lo puedes hacer con cualquier salida digital.
Utilizar los pines PWM no tiene ningún sentido para manejar servos por que no les puedes mandar un analogWrite(), por que la señal PWM que Arduino les va a mandar no va a ser a 50Hz, va a ser a 16MHz. Haz la prueba, conecta la entrada de señal de un servo al pin 10 (que está marcado como PWM) y mandale un "analogWrite(255); " a ver si se pone en la posición de 180º. Te digo yo que no.
Para controlar elementos de RC con Arduino hay que utilizar la librería servo.h que sirve, precisamente, para generar una señal PWM de 50Hz en cualquier pin digital de la placa. Esta librería permite utilizar hasta 12 servos (no hay tantas salidas PWM) y deshabilita la función PWM de los pines 9 y 10, haya o no un servo conectado a ellos.
Relacionar los pines marcados con la serigrafía PWM en la placa con control de mecanismos para RC solo crea confusión entre los novatos. O entre los que no han conectado nunca un servo a una placa Arduino.
De la misma forma, no se puede leer la señal que un receptor de RC le manda a un servo o a un variador mediante una entrada analógica. Prueba a medir tensión entre el pin de señal de un receptor y GND, el multímetro te marcará 0v hagas lo que hagas con la emisora. La forma de leer la señal que un receptor manda a un servo o a un variador se lee con el comando pulseIn().
Una vez más os recomiendo hacer pruebas y lo vereis por vosotros mismos. Toda la información erronea que circula por el foro acerca de este tema solo contribuye a que de tanto en tanto aparezca un disparate: hace unos meses un chaval quería convertir un coche RC en un robot y quería mandarle las señales desde el mando, pues hubo un iluminado que le recomendó que conectara la antena de la emisora a un pin PWM.
En electrónica todo el tema de modulación, pulsos, frecuencia y todo lo que tiene que ver con señales es complejo y la mayoría de gente que lee este foro no tiene conocimientos de electrónica suficientes, precisamente vienen aquí para aprender. Vamos a simplificar las cosas para no marear: los pines PWM de Arduino simulan señales analógicas, el que luego quiera profundizar en este tipo de señal y modificar su frecuencia (que se puede) investigará por su cuenta.
El que quiera controlar mecanismos de RC sin complicarse la vida puede generar las señales de control con la librería servo.h en cualquier pin digital y puede leer estas mismas señales con el comando pulseIn().
El que quiera profundizar en el control de tiempos y generar una señal cuadrada de amplitud variable y una frecuencia de 50Hz puede hacerlo por software y comprobar si lo hace bien o mal con un simple servo.
...por lo menos nadie a dicho que sea PPM, algo hemos avanzado.
Utilizar los pines PWM no tiene ningún sentido para manejar servos por que no les puedes mandar un analogWrite(), por que la señal PWM que Arduino les va a mandar no va a ser a 50Hz, va a ser a 16MHz. Haz la prueba, conecta la entrada de señal de un servo al pin 10 (que está marcado como PWM) y mandale un "analogWrite(255); " a ver si se pone en la posición de 180º. Te digo yo que no.
Cierto que no son de 50 hz, pero por defecto son son de 16 Mhz. hay que configurarlo a posta para obtener esa frecuencia.
http://www.arduino.cc/cgi-bin/yabb2/YaBB.pl?num=1227085157
y explicacion del pwm del atmega.
josemanu, la señal PWM que genera el analogWrite es a 490 Hz (no 16 MHz). Que Arduino en su core configure a dicha frecuencia la función analogWrite, no significa que no tenga sentido usar PWM. Estoy de acuerdo que para un novato es mejor usar la librería preparada para servos, pero como ha dicho SrDonGato, no dejan de ser PWM... ;) Como también ha dicho SrDonGato, si usas el módulo de PWM del micro, puedes estar haciendo otras tareas, ya que los timer harán el trabajo por tí. La librería servo usa timers para ir generando en los pines los PWM adecuados. Lo hace por soft, para poder controlar mayor número de salidas utilizando el menor número de timers del micro (creo que manejan 12 salidas por cada timer).
Yo creo, que lo que hay que dejar claro es que analogWrite() del lenguaje Arduino genera un PWM de 490 Hz, que no es apto para el control de servos.
Copio del link que puse más arriba...
The following are lists of common devices that use PPM and PWM.
R/C Devices that use PWM Pulses:
Servos Electronic Speed Controllers R/C switches R/C lights R/C receivers Data loggers Failsafe's Autopilot/Stabilization systems Servo Controller
R/C Devices that use PPM Pulses:
R/C transmitters R/C receivers Autopilot/Stabilization systems PCTx
Salu2
josemanu: Relacionar los pines marcados con la serigrafía PWM en la placa con control de mecanismos para RC solo crea confusión entre los novatos. O entre los que no han conectado nunca un servo a una placa Arduino.
[...]
Una vez más os recomiendo hacer pruebas y lo vereis por vosotros mismos. Toda la información erronea que circula por el foro acerca de este tema solo contribuye a que de tanto en tanto aparezca un disparate: hace unos meses un chaval quería convertir un coche RC en un robot y quería mandarle las señales desde el mando, pues hubo un iluminado que le recomendó que conectara la antena de la emisora a un pin PWM.
Yo creo que es al revés, hay que explicar las cosas tal cual son indicando sus particularidades: la señal de control de un servo es PWM pero no se pueden controlar directamente mediante la función analogWrite() con los pines serigrafiados como PWM en la placa Arduino porque esa función saca una señal PWM a 490 Hz y el control de servos es a 50 Hz.
Nombras lo de información errónea como si lo explicado por SrDonGato fuera erróneo (en cuanto a las argumentaciones en este hilo) cuando es lo contrario, tu simplificación como para aclararlo a los novatos es lo que ha entrado en conceptos técnicos erróneos. Podemos simplificar las cosas todo lo que quieras (queramos) o puedas (podamos) que siempre aparecerán como dices "iluminados" (yo prefiero nombrarlos como "aventurados") que dirán unos disparates impresionantes.
