Proyecto dispensador de pasta para soldar

Hola a todos los miembros del foro, soy un entusiasta a muchos oficios entre ellos, a la electronica,
tambien son nuevo en arduino, se me hace un tema interesante por aprender.
Resulta que un amigo me encargo la construccion de un dispensador de pasta para soldar utilizando un
compresor de aire, 2 valvulas neumaticas, un interruptor momentaneo, una unidad arduino con un par de relays.
Estoy tomando como ejemplo el siguiente link:

En dicho sitio explica el funcionamiento del sistema excepto como configurar el arduino, si alguien
tiene nociones en esto y me puede ayudar con el desarroyo del proyecto, se los agradecere enormemente.

Buenas y bienvenido al foro, podrías explicar que es lo que tiene que hacer el arduino y cual vas a utilizar?

Gracias por responder a mi pedido de ayuda, pienso utilizar arduino uno a menos que me recomienden otra cosa, como dije anteriormente, soy nuevo en esto y me gustaria aprender las amplias posibilidades de arduino. La funcion de arduino sera controlar un par de relevadores mediante un switch que estos a su vez controlen 2 valvulas selenoides neumaticas, pueden ser de 12, 24 o 110 voltios, al presionar el switch debe de activar una valvula selenoide permitiendo el flujo de aire comprimido de un compresor hacia la jeringa que esta a su vez aplique la pasta en el pcb, al soltar el switch debe de activar la segunda valvula que hace la funcion de alivio, permitiendo liberar la presion en el sistema y asi evitar que la jeringa siga aplicando pasta debido a la falta de presion.

Aqui esta un video de youtube si sirve de algo http://youtu.be/DpgOYNB1Kng

Gracias

Un solo pulsador, al pulsar da señal A, y al soltar da señal B, intuyo que al soltar la señal A cesara y la B se mantendrá un tiempo, es correcto?

Asi es

No lo probé, pero prueba algo asi:

#define Pulsador   2            // Pin usado para el pulsaador
#define V_Alimen   3            // Pin usado para Valvula alimentacion
#define V_Alivio   4            // Pin usado para Valvula alivio

#define ON   HIGH               // Cambiar aqui para activar rele con positivo o negativo 
#define OF   LOW                // Cambiar aqui para activar rele con positivo o negativo

bool Estado_Pulsador = false;   // Para controlar el estado del pulsador
bool Estado_Anterior = false;   // Para controlar los cambios de estado del pulsador

unsigned long T_Alivio = 1000;  // Milisegundos que estara la valvula alivio abierta
unsigned long MillisT   = 0;    // Para controlar el timpo de valvula de alivio
unsigned long U_Millis = 0;     // Para controlar eldesborde de millis()

void setup() 
{
  pinMode(Pulsador, INPUT);     // Establecer pin de pulsador como entrada
  pinMode(V_Alimen, OUTPUT);    // Establecer pin de valvula1 como salida
  pinMode(V_Alivio, OUTPUT);    // Establecer pin de valvula2 como salida
  digitalWrite(V_Alimen, OF);   // Desactivar rele valvula 1
  digitalWrite(V_Alivio, OF);   // Desactivar rele valvula 2
}

void loop() 
{
  U_Millis = millis();                        // Cargamos millis para comprobar desborde
  Estado_Pulsador = digitalRead(Pulsador);    // Leer pin pulsador
  if (Estado_Pulsador != Estado_Anterior)     // Ha variado el estado del pulsador
  {
    if (Estado_Pulsador)                      // Pulsador pulsado
    {
      digitalWrite(V_Alivio, OF);             // Desactivar valvula alivio
      delay(100);                             // Dejamos tiempo para que actue la valvula
      digitalWrite(V_Alimen, ON);             // Activar alimentacion
      MillisT=0;                              // No hay tiempo de alivio
    }                                        
    else                                      // Pulsador soltado
    {
      digitalWrite(V_Alimen, OF);             // Desactivar alimentacion
      digitalWrite(V_Alivio, ON);             // Activar valvula alivio
      MillisT  =millis() + T_Alivio;          // Tiempo para parar la valvula de alivio
    }
  }

  Estado_Anterior=Estado_Pulsador;

  if (U_Millis>millis())                      // Millis ha desbordado
  {
    MillisT = MillisT - U_Millis + millis();  // Nuevo tiempo para fin alivio
  }
  
  if (MillisT > millis())                     // Finalizo tiempo para desactivar valvula alivio 
  {
    digitalWrite(V_Alivio, OF);               // Desactivar valvula alivio
    MillisT=0;                                // Dejamos de controlar el tiempo           
  }
}

Muchas gracias, lo voy a intentar y veremos resultados

Ya iras contando.