PWM durch Sensor ändern

Hallo Leute,

ich habe für einen DC-Motor schon eine kompletten Code geschrieben, wo ich manuell die PWM ändern kann. Funktioniert auch alles soweit.
Nun würde ich gerne über einen weiteren Pin ein Signal von einem Sensor einlesen. Der die PWM von zum Beispiel 80% auf 60% reduziert. Dann soll es mit 60% weiterlaufen, bis erneut das Signal eingelesen wird und wieder auf 80% springt.
Irgendwie habe ich gerade eine Denkblockade wie ich das in meinen Loop bauen soll, da der Sensor mir die Spannung immer nur einmal kurz am Eingangs-Pin gibt.

Danke schon einmal für Ideen
lg

Gib mal etwas mehr Infos, z.B. was für ein Sensor
Dann was gibt das ganze?

Was hast du bereits an Code?

Einen Reflexsensor, welcher über Uce 5V erzeugt.

 int PWM_out_pin = 9;  

void setup() {
pinMode(PWM_out_pin, OUTPUT);
}
void loop() {
byte PWM_out_level;
PWM_out_level = 204;
analogWrite( PWM_out_pin, PWM_out_level);
}

okocha90:
Einen Reflexsensor, welcher über Uce 5V erzeugt.

 int PWM_out_pin = 9;  

void setup() {
pinMode(PWM_out_pin, OUTPUT);
}
void loop() {
byte PWM_out_level;
PWM_out_level = 204;
analogWrite( PWM_out_pin, PWM_out_level);
}

Hallo JayJay,

seit wann programmierst du denn den Arduino ?
:smiley: :smiley: :smiley: :smiley:
Grüßle

Harry

Seitdem ich zu alt zum Kicken bin :-[ :stuck_out_tongue: :stuck_out_tongue_closed_eyes:
Also, ich bin kein großer Programmierer, aber es funktioniert so zumindest :-[

Dan starte einen Timer, wenn der Sensor Signal gegeben hat und gib PWM 60 aus. und Sperre die weitere Sensorabfrage. Nach Ablauf des Timers gibst du dann PWM 80 aus. Wenn dann der Sensor wieder Signal gibt, alles von vorne.

Oder soll bei Sensor High nur die Ausgabe getoggelt werden? Dann wäre Blinkwithoutdelay dein Freund

ElEspanol:
Dan starte einen Timer, wenn der Sensor Signal gegeben hat und gib PWM 60 aus. und Sperre die weitere Sensorabfrage. Nach Ablauf des Timers gibst du dann PWM 80 aus. Wenn dann der Sensor wieder Signal gibt, alles von vorne.

Oder soll bei Sensor High nur die Ausgabe getoggelt werden? Dann wäre Blinkwithoutdelay dein Freund

Ja genau, wenn der Input die 5V vom Sensor erkennt soll auf PWM 60 getoggled werden und sobald ernaut wieder 5V am Input sind zurück auf PWM 80 getoggled...und immer so weiter als Schleife.

Also, dann ist Blinkwithoutdelay dein Sketck. Anstatt aus und einzuschalten, schreibst du eben die PWM Werte, und der Sensor ist dein Taster. Fals der Sensor kein LOW liefert, solltest du noch einen Pulldowm an den Signalpin machen.

edit: Nicht Blinkwithoutdelay, sondern Taster als Schalter. War grad auf dem falschen Dampfer

Wenn ich das richtig interpretiere, dann willst du sowas:

Sensorsignal kommt: PWM 60;
neues Sensorsignal kommt: PWM 80;
nächstes Sensorsignal: PWM 60
....

Falls es das ist, dann kann sowas funktionieren:

Der Sensor wird eingelesen.
Wenn sich der Wert von LOW auf HIGH geändert hat, dann wird jedes mal der PWM Wert gewechselt, und der neue Wert ausgegeben.
Um einen Wechseln von LOW auf HIGH zu detektieren, merkt man sich den letzten Wert und vergleicht mit dem aktuellen.

int PWM_out_pin = 9;
int Sensor_pin = 10;

boolean last_SensorVal = 0;    
byte PWM_out_level;

void setup() {
  pinMode(PWM_out_pin, OUTPUT);
  pinMode(Sensor_pin, INPUT_PULLUP);
}
void loop() {
  boolean SensorVal = digitalRead(Sensor_pin);      // Sensor einlesen
  if (SensorVal && !last_SensorVal){                // wenn sich der pegel von 0 auf 1 geändert hat
    last_SensorVal = SensorVal;                       // alten Wert merken
    
    if (PWM_out_level == 60)   PWM_out_level = 80;    // Umschalten PWM Wert
    else                       PWM_out_level = 60;  
    
    analogWrite( PWM_out_pin, PWM_out_level);         // neuen PWM Wert schreiben.
  }
}

In den Beispielen heisst das

mit leichten Änderungen

 if (SensorVal && !last_SensorVal){                // wenn sich der pegel von 0 auf 1 geändert hat

last_SensorVal = SensorVal;                      // alten Wert merken

Kannst du mir den Teil nochmal erläutern bitte?
Den alten Wert merken heißt er merkt sich immer das Low am Input war, hab ich richtig verstanden?
Er erkennt input als high, führt die if else Befehle aus und steht dann wieder auf low, oder?

Nicht ganz.

Wir wissen nicht, wie lange der Sensor auf HIGH steht, wenn er auslöst.
Der Arduino fragt unter Umständen ein paar millionen mal pro sekunde den Sensor ab.

daher:

  • Wert lesen
  • vergleichen mit dem letzten Wert : low => High? dann PWM setzen
  • Sensorwert merken.

als Tabelle sieht das so aus:
Zwischenablage01.jpg

Und in dem Moment, dem ich das schreibe, fällt mir auf, dass ich oben im Code den Befehl “last_SensorVal = SensorVal;” an der falschen Stelle stehen hatte. Das passiert, wenn man “blind” Code schreibt, ohne Testmöglichkeit.

so solls aussehen:

int PWM_out_pin = 9;
int Sensor_pin = 10;

boolean last_SensorVal = 0;    
byte PWM_out_level;

void setup() {
  pinMode(PWM_out_pin, OUTPUT);
  pinMode(Sensor_pin, INPUT_PULLUP);
}
void loop() {
  boolean SensorVal = digitalRead(Sensor_pin);      // Sensor einlesen
  if (SensorVal && !last_SensorVal){                // wenn sich der pegel von 0 auf 1 geändert hat
    
    if (PWM_out_level == 60)   PWM_out_level = 80;    // Umschalten PWM Wert
    else                       PWM_out_level = 60;  
    
    analogWrite( PWM_out_pin, PWM_out_level);         // neuen PWM Wert schreiben.
  }
  last_SensorVal = SensorVal;                       // alten Wert merken <=== Zeile nach unten geschoben
}

guntherb:
Und in dem Moment, dem ich das schreibe, fällt mir auf, dass ich oben im Code den Befehl "last_SensorVal = SensorVal;" an der falschen Stelle stehen hatte. Das passiert, wenn man "blind" Code schreibt, ohne Testmöglichkeit.

Also deswegen hat es bei mir nicht funktioniert.

Ich hätte ganz einfach dies aus den Beispielen genommen:

/*
  State change detection (edge detection)

 Often, you don't need to know the state of a digital input all the time,
 but you just need to know when the input changes from one state to another.
 For example, you want to know when a button goes from OFF to ON.  This is called
 state change detection, or edge detection.

 This example shows how to detect when a button or button changes from off to on
 and on to off.

 The circuit:
 * pushbutton attached to pin 2 from +5V
 * 10K resistor attached to pin 2 from ground
 * LED attached from pin 13 to ground (or use the built-in LED on
   most Arduino boards)

 created  27 Sep 2005
 modified 30 Aug 2011
 by Tom Igoe

This example code is in the public domain.

 http://www.arduino.cc/en/Tutorial/ButtonStateChange

 */

// this constant won't change:
const int  buttonPin = 2;    // the pin that the pushbutton is attached to
const int ledPin = 13;       // the pin that the LED is attached to

// Variables will change:
int buttonPushCounter = 0;   // counter for the number of button presses
int buttonState = 0;         // current state of the button
int lastButtonState = 0;     // previous state of the button

void setup() {
  // initialize the button pin as a input:
  pinMode(buttonPin, INPUT);
  // initialize the LED as an output:
  pinMode(ledPin, OUTPUT);
  // initialize serial communication:
  Serial.begin(9600);
}


void loop() {
  // read the pushbutton input pin:
  buttonState = digitalRead(buttonPin);

  // compare the buttonState to its previous state
  if (buttonState != lastButtonState) {
    // if the state has changed, increment the counter
    if (buttonState == HIGH) {
      // if the current state is HIGH then the button
      // wend from off to on:
      buttonPushCounter++;
      Serial.println("on");
      Serial.print("number of button pushes:  ");
      Serial.println(buttonPushCounter);
    }
    else {
      // if the current state is LOW then the button
      // wend from on to off:
      Serial.println("off");
    }
    // Delay a little bit to avoid bouncing
    delay(50);
  }
  // save the current state as the last state,
  //for next time through the loop
  lastButtonState = buttonState;


  // turns on the LED every four button pushes by
  // checking the modulo of the button push counter.
  // the modulo function gives you the remainder of
  // the division of two numbers:
  if (buttonPushCounter % 2 == 0) {           // hier habe ich 4 auf 2 geändert//////////////////////
    digitalWrite(ledPin, HIGH); //  hier wäre dann analogWrite( PWM_out_pin, 80)
  } else {
    digitalWrite(ledPin, LOW); // und hier analogWrite( PWM_out_pin, 60)
  }

}

Aber jetzt erscheint mir guntherbs Code auch nachvollziehbar

Ich kann es leider erst morgen testen und simuliere ersteinmal die 5V von dem Sensor und berichte dann.
Die Grafik ist klasse, wie Bilder einem das Verständnis erleichtern können!

Ich danke euch beiden aufjedenfall schonmal und wir lesen uns morgen

LG

So, einen wunderschönen guten Sonntag.
Ich habe das Sensor Signal simuliert und der Code funktioniert auch.
Den Sensor einzeln probiert und switched auch zwischen 4,6V und 0,3V hin und her. Das sollte ja der Arduino als High-Low Pegel erkennen oder? Also beide Komponenten funktionieren einzeln, aber nicht zusammen, auch mit einem 10k-Ohm Resi für den Pulldown, aber dass ich denke ich mal ein anderer Bereich und hat nichts mit dem Code selbst zu tun.

Vielen Dank euch beiden

LG