Quick check and critic of the sketch

Projects Programming
1

Hello Folks!

So I writing a sketch to control a winch with a dual channel motor shield remapped into a single channel for more current. The forward and reverse controlled from a switch that flicks up for forward and down for reverse. the middle position is off. Vin to the switch is either going to be 12v, if that is a usable logic signal in to the Arduino, or I can do 5v with a 12 to 5 converter. There are a couple other inputs to my shield that aren't usable with my remap so I haven't bothered to change the pinMode on those. Here is the shield i'm using: Pololu Dual VNH5019 Motor Driver Shield for Arduino . I haven't had much luck with their library and I decided to write one myself for the practice. Here is my sketch.

/*
Pololu VNH5019 Dual channel remapped into single channel mode to control SS Mast. 
We are only using one input channel to Driver Shield because the shield is remapped to each VNH5019.
pins 2 & 4 control OUTA
pins 7 & 8 control OUTB
pins 9 & 10 control PWM
Pololu VNH5019 dual channel motor driver shield resource:
User's Guide: http://www.pololu.com/docs/pdf/0J49/dual_vnh5019_motor_driver_shield.pdf
*/


int keyUp =5;     //Input from key to raise mast.
int keyDown =6;   //Input from key to lower mast.
int FWD =2;       //Raises mast.
int REV =7;       //Lowers mast.
int PWM= 9;       //Speed control of raise and lower.

void setup()
{
pinMode (keyUp, INPUT_PULLUP);    //This sets Arduino pin 5 as input from key switch (HIGH in off state).
pinMode (keyDown, INPUT_PULLUP);  //This sets Arduino pin 6 as input from key switch (HIGH in off state). 
pinMode (FWD, OUTPUT);            //This sets the Arduino pin 2 as output to Pololu pin 2 and 4.
pinMode (REV, OUTPUT);            //This sets the Arduino pin 7 as output to Pololu pin 7 and 8.
pinMode (PWM, OUTPUT);            //This sets the Arduino pin 9 as output to Pololu pin 9 and 10.
}

void loop()
{
  analogWrite (PWM, 128);            //This sets the speed between 1-255. 127/128 = 50% duty cycle.
  if (digitalRead(keyUp) == LOW)     //This reads the state of key switch and controls movement forward.
    {
      digitalWrite(FWD, HIGH);       //This sets the FWD pin HIGH if the keyUp state is LOW.
      digitalWrite(REV, LOW);        //This sets the REV pin LOW if the KeyUp state is LOW.
     }      
  else;                              //If keyUp is HIGH then FWD and REV are off.(; closes if)
    {
      digitalWrite(FWD, LOW);     
      digitalWrite(REV, LOW);
    }
  if (digitalRead(keyDown) == LOW)   //This reads the state of key switch and controls movement reverse.
    {
      digitalWrite(REV, HIGH);       //This sets the REV pin HIGH if the keyDown state is HIGH.
      digitalWrite(FWD, LOW);        //This sets the FWD pin LOW if the KeyDown state is HIGH.
    }
  else;                              //If keyDown is HIGH then FWD and REV are off.(; closes if)
    {
      digitalWrite(REV, LOW);
      digitalWrite(FWD, LOW);
    }  
}

I believe this will work as I want it to but I do have a couple questions.

  1. In the loop do I have to write an if statement for the off position of my switch?
    if(digitalRead(keyUp)==HIGH && digitalRead(keyDown)==HIGH){
    digitalWrite(FWD, LOW);
    digitalWrite(RVS, LOW);
    }
    (Can i put the ; at the end of the "};" or put it after my if();
  2. In the else statement if I put the ";" after the else does it mean the same thing if i put the ; after the ending of what I want the else to do?
  else;                              //If keyDown is HIGH then FWD and REV are off.(; closes if)
    {
      digitalWrite(REV, LOW);
      digitalWrite(FWD, LOW);
    }

the same as

  else                              //If keyDown is HIGH then FWD and REV are off.(; closes if)
    {
      digitalWrite(REV, LOW);
      digitalWrite(FWD, LOW);
    };
2

control structures (for, while, if, else) use braces, they don't terminate with a semi-colon, the statements within the loop (digitalWrite for example) do end with a semi-colon. If the program complies (the check button in the upper left of the IDE) you're syntax is correct, you'll get an error in red text in the box in the lower part of the IDE if the syntax is incorrect.

Be careful with the hardware, depending on the winch you use you'll easily draw more current than the motor shield can supply a Warn VR10000-s (10,000 lb rating) winch will draw over 500A at 12V at full load, a Warn Vantage 2000-s (2,000 lb rating) winch will draw 118A at 12V at full load. Be sure you've got fuses and wiring that are sized for the current draw, catching something on fire is a very real concern with that kind of current.

3

Do not put the semi colon after the if(), its also not needed after the closing '}'

{} define a compound statement, it has its own scope and contain multiple statements.

Without the {} on an if, you are limited to a single statement. Placing the ';' after if() is not going to work as expected:

if( false );
  delay( 500 );

Here the ';' signifies the end of the sub statement for the if, therefore the delay always runs rather than never running.

4

Alright the semi colon on my else statements aren't necessary. Awesome. Now do you think its important for me to write something in the loop for off position on switch? I don't see a reason for it because if there is nothing on the switch there should be no action on the Arduino.

thanks for help guys

5

Well this didn't work so well. My motor just starts spinning as soon as power is on to the Arduino and Pololu. Back to the drawing board =D

6

The logic is not what you want. If the switch is in the up position, the motor stops. If the key is in the down position, the motor first stops and then moves in reverse.

Try something like this...

  if (digitalRead(keyUp) == LOW) {
    // run motor forward
  }
  else if (digitalRead(keyDown) == LOW) {
    // run motor in reverse
  }
  else {
    // stop motor
  }
7

Thanks david. I did just implement the "if /else if/ else" and it worked. awesome. :grin: