Radio Fm problema Sketch con lcd shield 16X2

Ragazzi sono sempre io :blush:, ho un problema con uno sketch
riguardo al funzionamento dei tasti dello shield lcd che mi permettono
di andare avanti e indietro nelle stazioni. Utilizzando il codice di sotto
pasticciato da me XD tra un codice di esempio dello shield e quello della
radio mi funziona solo il tasto Left (ricerca/indietro). Con un normale lcd 16X2
non ho avuto problemi con i tasti collegati in digitale ma questo shield
li ha collegati in analogico e non ci sto capendo pi√Ļ niente. Dove sbaglio nel codice?
Mille grazie

#include <TEA5767.h>
#include <Wire.h>
#include <LiquidCrystal.h>
int lcd_key     = 0;
int adc_key_in  = 0;
#define btnRIGHT  0
#define btnUP     1
#define btnDOWN   2
#define btnLEFT   3
#define btnSELECT 4
#define btnNONE   5

int read_LCD_buttons()
{
 adc_key_in = analogRead(0);   


 if (adc_key_in < 50)   return btnRIGHT;  
 if (adc_key_in < 650)  return btnLEFT; 

}

TEA5767 Radio;
LiquidCrystal lcd(8, 9, 4, 5, 6, 7);
double old_frequency;
double frequency;
int search_mode = 0;
int search_direction;
unsigned long last_pressed;



void setup() {  
  Wire.begin();
  Radio.init();
  Radio.set_frequency(105.4); 
  Serial.begin(9600);
  lcd.begin(16,2);
  lcd.clear();
}

void loop() {

  unsigned char buf[5];
  int stereo;
  int signal_level;
  double current_freq;
  unsigned long current_millis = millis();
  
  if (Radio.read_status(buf) == 1) {
    current_freq =  floor (Radio.frequency_available (buf) / 100000 + .5) / 10;
    stereo = Radio.stereo(buf);
    signal_level = Radio.signal_level(buf);
    lcd.setCursor(0,0);
    lcd.print("FM: "); lcd.print(current_freq);
    lcd.setCursor(0,1);
    if (stereo) lcd.print("STEREO "); else lcd.print("MONO ");
    //lcd.print(signal_level);
  }
  
  if (search_mode == 1) {
      if (Radio.process_search (buf, search_direction) == 1) {
          search_mode = 0;
      }
  }
  
  lcd_key = read_LCD_buttons(); 
  
  if (adc_key_in <50)//RIGHT 
   { last_pressed = current_millis;
    search_mode = 1;
    search_direction = TEA5767_SEARCH_DIR_UP;
    Radio.search_up(buf);
    delay(300);
  }
  
  if (adc_key_in < 650)// LEFT 
   { last_pressed = current_millis;
    search_mode = 1;
    search_direction = TEA5767_SEARCH_DIR_DOWN;
    Radio.search_down(buf);
    delay(300);
  } 
  //delay(20); 
  delay(50);
}

Si, un bel ‚Äúspaghetti code‚ÄĚ :grin:

Soprattutto questo:

lcd_key = read_LCD_buttons(); 
if (adc_key_in <50)//RIGHT

Hai un funzione che scrive in una variabile globale il valore letto da pin analogico (0-1023) ma quella funzione ti dovrebbe ‚Äúcalcolare‚ÄĚ dentro a lcd_key il tasto premuto, perch√® poi negli if successivi ‚Äúlavori‚ÄĚ con la variabile globale?
Quindi la funzione dovrebbe essere pi√Ļ complessa e la variabile globale va spostata qui dentro:

int read_LCD_buttons()
{ int adc_key_in;
  adc_key_in = analogRead(A0);   
  Serial.print("A0=");   Serial.println(adc_key_in);  // da commentare quando non serve
  if (adc_key_in < 50)   return btnRIGHT;  
  if (adc_key_in < 650)  return btnLEFT; 
  // e gli altri tasti ???  
  return(btnNONE);
}

Quindi nel codice:

lcd_key = read_LCD_buttons(); 
if (lcd_key==btnRIGHT) //RIGHT     ora commento inutile

Sei sicuro dei valori che l’analogico legge in base ai tasti premuti ?
Io ti ho messo nella funzione un serial.print per verificarli (da commentare quando li avrai verificati)

P.S. invece delle costanti define è meglio se usi la const (se n’e’ parlato nel forum, con const è come la define, non occupi memoria ma ne dichiari il tipo e non è ambiguo come define):

#define btnRIGHT  0
const int btnRIGHT = 0;

nid69ita:
Si, un bel ‚Äúspaghetti code‚ÄĚ :grin:

Ahahaha, stai parlando con uno che in programmazione è una chiavica… avevo provato
a fare un taglia e cuci dal codice di esempio
dello shield che è questo:

//Sample using LiquidCrystal library
#include <LiquidCrystal.h>

/*******************************************************

This program will test the LCD panel and the buttons
Mark Bramwell, July 2010

********************************************************/

// select the pins used on the LCD panel
LiquidCrystal lcd(8, 9, 4, 5, 6, 7);

// define some values used by the panel and buttons
int lcd_key     = 0;
int adc_key_in  = 0;
#define btnRIGHT  0
#define btnUP     1
#define btnDOWN   2
#define btnLEFT   3
#define btnSELECT 4
#define btnNONE   5

// read the buttons
int read_LCD_buttons()
{
 adc_key_in = analogRead(0);      // read the value from the sensor 
 // my buttons when read are centered at these valies: 0, 144, 329, 504, 741
 // we add approx 50 to those values and check to see if we are close
 if (adc_key_in > 1000) return btnNONE; // We make this the 1st option for speed reasons since it will be the most likely result
 // For V1.1 us this threshold
 if (adc_key_in < 50)   return btnRIGHT;  
 if (adc_key_in < 250)  return btnUP; 
 if (adc_key_in < 450)  return btnDOWN; 
 if (adc_key_in < 650)  return btnLEFT; 
 if (adc_key_in < 850)  return btnSELECT;  

 // For V1.0 comment the other threshold and use the one below:
/*
 if (adc_key_in < 50)   return btnRIGHT;  
 if (adc_key_in < 195)  return btnUP; 
 if (adc_key_in < 380)  return btnDOWN; 
 if (adc_key_in < 555)  return btnLEFT; 
 if (adc_key_in < 790)  return btnSELECT;   
*/


 return btnNONE;  // when all others fail, return this...
}

void setup()
{
 lcd.begin(16, 2);              // start the library
 lcd.setCursor(0,0);
 lcd.print("Push the buttons"); // print a simple message
}
 
void loop()
{
 lcd.setCursor(9,1);            // move cursor to second line "1" and 9 spaces over
 lcd.print(millis()/1000);      // display seconds elapsed since power-up


 lcd.setCursor(0,1);            // move to the begining of the second line
 lcd_key = read_LCD_buttons();  // read the buttons

 switch (lcd_key)               // depending on which button was pushed, we perform an action
 {
   case btnRIGHT:
     {
     lcd.print("RIGHT ");
     break;
     }
   case btnLEFT:
     {
     lcd.print("LEFT   ");
     break;
     }
   case btnUP:
     {
     lcd.print("UP    ");
     break;
     }
   case btnDOWN:
     {
     lcd.print("DOWN  ");
     break;
     }
   case btnSELECT:
     {
     lcd.print("SELECT");
     break;
     }
     case btnNONE:
     {
     lcd.print("NONE  ");
     break;
     }
 }

}

Comunque adesso ho fatto come hai detto tu e funziona perfettamente. Grazie Nid Lo metto magari può servire a qualcuno:

#include <TEA5767.h>
#include <Wire.h>
#include <LiquidCrystal.h>
int lcd_key     = 0;
int adc_key_in  = 0;
const int btnRIGHT = 0;
const int btnUP = 1;
const int btnDOWN = 2;
const int btnLEFT = 3;
const int btnSELECT = 4;
const int btnNONE = 5;

int read_LCD_buttons()
{ int adc_key_in;
  adc_key_in = analogRead(A0);   
  Serial.print("A0=");   Serial.println(adc_key_in);  // da commentare quando non serve
  if (adc_key_in < 50)   return btnRIGHT;  
  if (adc_key_in < 250)  return btnUP; 
  if (adc_key_in < 450)  return btnDOWN; 
  if (adc_key_in < 650)  return btnLEFT; 
  if (adc_key_in < 850)  return btnSELECT;  

  return(btnNONE);
}
  
TEA5767 Radio;
LiquidCrystal lcd(8, 9, 4, 5, 6, 7);
double old_frequency;
double frequency;
int search_mode = 0;
int search_direction;
unsigned long last_pressed;



void setup() {  
  Wire.begin();
  Radio.init();
  Radio.set_frequency(105.4); 
  Serial.begin(9600);
  lcd.begin(16,2);
  lcd.clear();
}

void loop() {

  unsigned char buf[5];
  int stereo;
  int signal_level;
  double current_freq;
  unsigned long current_millis = millis();
  
  if (Radio.read_status(buf) == 1) {
    current_freq =  floor (Radio.frequency_available (buf) / 100000 + .5) / 10;
    stereo = Radio.stereo(buf);
    signal_level = Radio.signal_level(buf);
    lcd.setCursor(0,0);
    lcd.print("FM: "); lcd.print(current_freq);
    lcd.setCursor(0,1);
    if (stereo) lcd.print("STEREO "); else lcd.print("MONO ");
    //lcd.print(signal_level);
  }
  
  if (search_mode == 1) {
      if (Radio.process_search (buf, search_direction) == 1) {
          search_mode = 0;
      }
  }
  
lcd_key = read_LCD_buttons(); 
  
  if (lcd_key==btnRIGHT)
   { last_pressed = current_millis;
    search_mode = 1;
    search_direction = TEA5767_SEARCH_DIR_UP;
    Radio.search_up(buf);
    delay(300);
  }
  
   if (lcd_key==btnLEFT)
   { last_pressed = current_millis;
    search_mode = 1;
    search_direction = TEA5767_SEARCH_DIR_DOWN;
    Radio.search_down(buf);
    delay(300);
  } 
  //delay(20); 
  delay(50);
}

ciao, potresti elencarmi tutti i componenti che hai usato per fare questa radio? grazie mille