RF24 Only Works Once

Projects Programming
8

if the power goes through the button, the resistor will limit the current available

one way to check if this is the cause would be to add a button to your arduino, keep the system powered and use the button to trigger the message (and wait for button release)

something like this (typed here, untested of course)

#include "Arduino.h"
#include <SPI.h>
#include <RF24.h>

// This is just the way the RF24 library works:
// Hardware configuration: Set up nRF24L01 radio on SPI bus (pins 10, 11, 12, 13) plus pins 7 & 8
RF24 radio(7, 8);

byte addresses[][6] = {"1Node", "2Node"};
const byte greenLed = 3;
const byte redLed = 4;

const byte buttonPin = 2;

// -----------------------------------------------------------------------------
// SETUP   SETUP   SETUP   SETUP   SETUP   SETUP   SETUP   SETUP   SETUP
// -----------------------------------------------------------------------------
void setup() {
  pinMode(greenLed, OUTPUT);
  pinMode(redLed, OUTPUT);
  pinMode(buttonPin, INPUT_PULLUP);

  Serial.begin(9600);
  Serial.println("THIS IS THE TRANSMITTER CODE - YOU NEED THE OTHER ARDIUNO TO SEND BACK A RESPONSE");

  // Initiate the radio object
  radio.begin();

  // Set the transmit power to lowest available to prevent power supply related issues
  radio.setPALevel(RF24_PA_MIN);

  // Set the speed of the transmission to the quickest available
  radio.setDataRate(RF24_2MBPS);

  // Use a channel unlikely to be used by Wifi, Microwave ovens etc
  radio.setChannel(124);

  // Open a writing and reading pipe on each radio, with opposite addresses
  radio.openWritingPipe(addresses[1]);
  radio.openReadingPipe(1, addresses[0]);
  // Ensure we have stopped listening (even if we're not) or we won't be able to transmit
  radio.stopListening();
}

void loop() {
  if (digitalRead(buttonPin) == LOW) { // button pressed
    delay(15); // poor's man anti-bouce
    unsigned char data = 1;
    Serial.println("About to transmit");
    // Did we manage to SUCCESSFULLY transmit that (by getting an acknowledgement back from the other Arduino)?
    // Even we didn't we'll continue with the sketch, you never know, the radio fairies may help us
    if (!radio.write( &data, sizeof(unsigned char) )) {
      Serial.println("No acknowledgement of transmission - receiving radio device connected?");
      digitalWrite(redLed, HIGH);
      delay(1000);
      digitalWrite(redLed, LOW);
    } else {
      Serial.println("Acknowledgement received");
      digitalWrite(greenLed, HIGH);
      delay(1000);
      digitalWrite(greenLed, LOW);
    }

    while (digitalRead(buttonPin) == LOW); // active wait until button is released
    delay(15); // poor's man anti-bouce
  }
}

(button would be on pin 2 set as input pull-up , wired this way: pin 2 <---> button <----> GND)